reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem Th26:
  for T being set, F, G being Subset-Family of T holds card UNION
  (F,G) c= card [:F,G:]
proof
  deffunc F(set) = $1`1 \/ $1`2;
  let T be set, F, G be Subset-Family of T;
  set XX = [:F,G:];
  set IN = { F(X) where X is Element of [:bool T, bool T:] : X in XX };
  set A = [:bool T, bool T:];
  set AL = F, BL = G;
  set C = UNION(AL,BL);
A1: IN = C
  proof
    thus IN c= C
    proof
      let a be object;
      assume a in IN;
      then consider X being Element of [:bool T, bool T:] such that
A2:   a = F(X) and
A3:   X in XX;
      X`1 in F & X`2 in G by A3,MCART_1:10;
      hence thesis by A2,SETFAM_1:def 4;
    end;
    let a be object;
    assume a in C;
    then consider X,Y be set such that
A4: X in AL & Y in BL and
A5: a = X \/ Y by SETFAM_1:def 4;
    reconsider X,Y as Subset of T by A4;
    set XY = [X,Y];
A6: XY`1 = X & XY`2 = Y;
    XY in XX by A4,ZFMISC_1:87;
    hence thesis by A5,A6;
  end;
  card { F(w) where w is Element of A : w in XX } c= card XX from TREES_2:
  sch 2;
  hence thesis by A1;
end;
