
theorem Th26: :: 1.5. REMARK, (2) => (2'), p. 181
  for S,T being complete LATTICE, g being infs-preserving Function of S,T
  for X being Scott TopAugmentation of T
  for Y being Scott TopAugmentation of S st for V being open Subset of X holds
  uparrow ((LowerAdj g).:V) is open Subset of Y holds
  for d being Function of X, Y st d = LowerAdj g holds d is relatively_open
proof
  let S,T be complete LATTICE, g be infs-preserving Function of S,T;
  let X be Scott TopAugmentation of T;
  let Y be Scott TopAugmentation of S such that
A1: for V being open Subset of X holds
  uparrow ((LowerAdj g).:V) is open Subset of Y;
  let d be Function of X, Y such that
A2: d = LowerAdj g;
  let V be open Subset of X;
  reconsider A = uparrow ((LowerAdj g).:V) as open Subset of Y by A1;
  d.:V = A /\ rng d by A2,Th25;
  then
A3: d.:V = [#](Y|rng d) /\ A by PRE_TOPC:def 5;
A4: A in the topology of Y by PRE_TOPC:def 2;
  reconsider B = d.:V as Subset of Y|rng d by A3,XBOOLE_1:17;
  B in the topology of Y|rng d by A3,A4,PRE_TOPC:def 4;
  hence thesis by PRE_TOPC:def 2;
end;
