reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem Th27:
  for A,B,C,D,E being set, h being Function, A9,B9,C9,D9,E9 being
set st h = (B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (E .--> E9) +* (A .-->
  A9) holds dom h = {A,B,C,D,E}
proof
  let A,B,C,D,E be set;
  let h be Function;
  let A9,B9,C9,D9,E9 be set;
  assume
A1: h = (B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (E .--> E9) +* (A
  .--> A9);
  dom ((B .--> B9) +* (C .--> C9)) = dom (B .--> B9) \/ dom (C .--> C9) by
FUNCT_4:def 1;
  then
  dom ((B .--> B9) +* (C .--> C9) +* (D .--> D9)) = dom (B .--> B9) \/ dom
  (C .--> C9) \/ dom (D .--> D9) by FUNCT_4:def 1;
  then
  dom ((B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (E .--> E9)) = dom (B
  .--> B9) \/ dom (C .--> C9) \/ dom (D .--> D9) \/ dom (E .--> E9) by
FUNCT_4:def 1;
  then
A3: dom ((B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (E .--> E9) +* (A .-->
A9)) = dom (B .--> B9) \/ dom (C .--> C9) \/ dom (D .--> D9) \/ dom (E .--> E9)
  \/ dom (A .--> A9) by FUNCT_4:def 1;
  dom ((B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (E .--> E9) +* (A
  .--> A9)) = {A} \/ (({B} \/ {C}) \/ {D} \/ {E}) by A3
    .= {A} \/ ({B,C} \/ {D} \/ {E}) by ENUMSET1:1
    .= {A} \/ ({B,C,D} \/ {E}) by ENUMSET1:3
    .= {A} \/ {B,C,D,E} by ENUMSET1:6
    .= {A,B,C,D,E} by ENUMSET1:7;
  hence thesis by A1;
end;
