
theorem Th26: :: Lemma 4:40
  for R being non empty RelStr
  st R\~ is well_founded & R is connected holds R is Dickson
proof
  let R be non empty RelStr such that
A1: R\~ is well_founded and
A2: R is connected;
  set IR9 = the InternalRel of R\~, CR9 = the carrier of R\~;
  set IR = the InternalRel of R, CR = the carrier of R;
  let N be Subset of CR;
  per cases;
  suppose
A3: N = {} CR;
    take B = {};
    thus B is_Dickson-basis_of N,R by A3;
    thus thesis;
  end;
  suppose
A4: N <> {} CR;
    IR9 is_well_founded_in CR9 by A1,WELLFND1:def 2;
    then consider b being object such that
A5: b in N and
A6: IR9-Seg(b) misses N by A4,WELLORD1:def 3;
A7: IR9-Seg(b) /\ N = {} by A6,XBOOLE_0:def 7;
    take B = {b};
    reconsider b as Element of N by A5;
    thus B is_Dickson-basis_of N,R
    proof
      {b} is Subset of N by A4,SUBSET_1:33;
      hence B c= N;
      let a be Element of R such that
A8:   a in N;
      reconsider b as Element of R by A5;
      take b;
      thus b in B by TARSKI:def 1;
      per cases by A2,WAYBEL_0:def 29;
      suppose b <= a;
        hence thesis;
      end;
      suppose
A9:     a <= b;
        then
A10:    [a,b] in IR;
        now per cases;
          suppose a = b;
            hence thesis by A9;
          end;
          suppose
A11:        not a = b;
            now per cases;
              suppose [a,b] in IR9;
                then a in IR9-Seg(b) by A11,WELLORD1:1;
                hence thesis by A7,A8,XBOOLE_0:def 4;
              end;
              suppose not [a,b] in IR9;
                then [a,b] in IR~ by A10,XBOOLE_0:def 5;
                then [b,a] in IR by RELAT_1:def 7;
                hence thesis;
              end;
            end;
            hence thesis;
          end;
        end;
        hence thesis;
      end;
    end;
    thus thesis;
  end;
end;
