reserve n for Nat;
reserve i for Integer;
reserve r,s,t for Real;
reserve An,Bn,Cn,Dn for Point of TOP-REAL n;
reserve L1,L2 for Element of line_of_REAL n;
reserve A,B,C for Point of TOP-REAL 2;

theorem
  angle(B,A,C) <> angle(C,B,A) implies
  sin ((angle(B,A,C) - angle(C,B,A))/2) <> 0
  proof
    assume
A1: angle(B,A,C) <> angle(C,B,A);
    assume
A2: sin ((angle(B,A,C) - angle(C,B,A))/2) = 0;
    then
    consider i0 be Integer such that
A3: (angle(B,A,C) - angle(C,B,A))/2 = PI * i0 by BORSUK_7:7;
    set a = angle(B,A,C) - angle(C,B,A);
A4: 0 <= angle(B,A,C) < 2 * PI & 0 <= angle(C,B,A) < 2 * PI by EUCLID11:2;
A5: 0 - (2*PI) < 0 - angle(C,B,A) by EUCLID11:2,XREAL_1:10;
    per cases;
    suppose i0 = 0;
      hence contradiction by A3,A1;
    end;
    suppose
A6:   i0 < 0;
      PI in ]. 0, 4 .[ by SIN_COS:def 28;
      then 0 < PI by XXREAL_1:4;
      then
A7:   a < 0 by A3,A6;
      - 2 * PI < a by A5,EUCLID11:2,XREAL_1:8;
      hence contradiction by A2,A7,Th5;
    end;
    suppose
A8:   i0 > 0;
      0 < a < 2 * PI
      proof
        thus 0 < a by A3,A8,COMPTRIG:5;
        angle(B,A,C) - angle(C,B,A) < 2 * PI - 0 by A4,XREAL_1:14;
        hence a < 2 * PI;
      end;
      hence contradiction by A2,Th4;
    end;
  end;
