reserve x for object;
reserve x0,r,r1,r2,g,g1,g2,p,y0 for Real;
reserve n,m,k,l for Element of NAT;
reserve a,b,d for Real_Sequence;
reserve h,h1,h2 for non-zero 0-convergent Real_Sequence;
reserve c,c1 for constant Real_Sequence;
reserve A for open Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;
reserve L for LinearFunc;
reserve R for RestFunc;

theorem
  right_open_halfline(r) c= dom f & (for r1,r2 st r1 in
right_open_halfline(r) & r2 in right_open_halfline(r) holds |.f.r1 - f.r2.| <=
  (r1 - r2)^2) implies f is_differentiable_on right_open_halfline(r) & f|
  right_open_halfline r is constant
proof
  assume that
A1: right_open_halfline(r) c= dom f and
A2: for r1,r2 st r1 in right_open_halfline(r) & r2 in
  right_open_halfline(r) holds |.f.r1 - f.r2.| <= (r1 - r2)^2;
  now
    let r1,r2 be Element of REAL;
    assume that
A3: r1 in right_open_halfline(r) /\ dom f and
A4: r2 in right_open_halfline(r) /\ dom f;
    set rr = max(r1,r2);
A5: ].r, rr + 1.[ c= right_open_halfline(r) by XXREAL_1:247;
    then
A6: for g1,g2 st g1 in ].r, rr + 1 .[ & g2 in ].r, rr + 1.[ holds |.f.
    g1 - f.g2.| <= (g1 - g2)^2 by A2;
    r2 in right_open_halfline(r) by A4,XBOOLE_0:def 4;
    then r2 in {p: r < p} by XXREAL_1:230;
    then
A7: ex g2 st g2 = r2 & r < g2;
    r2 + 0 < rr + 1 by XREAL_1:8,XXREAL_0:25;
    then r2 in {g2: r < g2 & g2 < rr + 1} by A7;
    then
A8: r2 in ].r, rr + 1.[ by RCOMP_1:def 2;
    r2 in dom f by A4,XBOOLE_0:def 4;
    then
A9: r2 in ].r, rr + 1.[ /\ dom f by A8,XBOOLE_0:def 4;
    r1 in right_open_halfline(r) by A3,XBOOLE_0:def 4;
    then r1 in {g: r < g} by XXREAL_1:230;
    then
A10: ex g1 st g1 = r1 & r < g1;
    r1 + 0 < rr + 1 by XREAL_1:8,XXREAL_0:25;
    then r1 in {g1: r < g1 & g1 < rr + 1} by A10;
    then
A11: r1 in ].r, rr + 1.[ by RCOMP_1:def 2;
    r1 in dom f by A3,XBOOLE_0:def 4;
    then
A12: r1 in ].r, rr + 1.[ /\ dom f by A11,XBOOLE_0:def 4;
    ].r, rr + 1 .[ c= dom f by A1,A5;
    then f|].r,rr+1.[ is constant by A6,Th25;
    hence f.r1 = f.r2 by A12,A9,PARTFUN2:58;
  end;
  hence thesis by A1,A2,Th24,PARTFUN2:58;
end;
