reserve G for Graph,
  v, v1, v2 for Vertex of G,
  c for Chain of G,
  p, p1, p2 for Path of G,
  vs, vs1, vs2 for FinSequence of the carrier of G,
  e, X for set,
  n, m for Nat;
reserve G for finite Graph,
  v for Vertex of G,
  c for Chain of G,
  vs for FinSequence of the carrier of G,
  X1, X2 for set;

theorem Th27:
  X2 c= X1 implies card Edges_In(v, X1\X2) = card Edges_In(v, X1)
  - card Edges_In(v, X2)
proof
  assume
A1: X2 c= X1;
  then
A2: X1 = X2 \/ (X1\X2) by XBOOLE_1:45;
  now
    let x be object;
    hereby
      assume
A3:   x in Edges_In(v,X1);
      then x in X1 by Def1;
      then
A4:   x in X2 or x in X1\X2 by A2,XBOOLE_0:def 3;
      (the Target of G).x = v by A3,Def1;
      then x in Edges_In(v,X2) or x in Edges_In(v, X1\X2) by A3,A4,Def1;
      hence x in Edges_In(v,X2) \/ Edges_In(v, X1\X2) by XBOOLE_0:def 3;
    end;
    assume
A5: x in Edges_In(v,X2) \/ Edges_In(v, X1\X2);
    then
A6: x in Edges_In(v,X2) or x in Edges_In(v, X1\X2) by XBOOLE_0:def 3;
    then
A7: x in X2 or x in X1\X2 by Def1;
    (the Target of G).x = v by A6,Def1;
    hence x in Edges_In(v,X1) by A1,A5,A7,Def1;
  end;
  then
A8: Edges_In(v,X1) = Edges_In(v,X2) \/ Edges_In(v, X1\X2) by TARSKI:2;
  Edges_In(v, X2) misses Edges_In(v, X1\X2)
  proof
    assume not thesis;
    then consider x being object such that
A9: x in Edges_In(v, X2) /\ Edges_In(v, X1\X2) by XBOOLE_0:4;
    x in Edges_In(v, X1\X2) by A9,XBOOLE_0:def 4;
    then
A10: x in X1\X2 by Def1;
    x in Edges_In(v, X2) by A9,XBOOLE_0:def 4;
    then x in X2 by Def1;
    hence contradiction by A10,XBOOLE_0:def 5;
  end;
  then card Edges_In(v,X1) = card Edges_In(v,X2) + card Edges_In(v, X1\X2) by
A8,CARD_2:40;
  hence thesis;
end;
