reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;

theorem Th27:
  the carrier of the_stable_subgroup_of A = meet{B where B is
Subset of G: ex H being strict StableSubgroup of G st B = the carrier of H & A
  c= carr H}
proof
  defpred P[StableSubgroup of G] means A c= carr $1;
  set X = {B where B is Subset of G :ex H being strict StableSubgroup of G st
  B = the carrier of H & A c= carr H};
A1: now
    let Y be set;
    assume Y in X;
    then
    ex B being Subset of G st Y = B & ex H being strict StableSubgroup of
    G st B = the carrier of H & A c= carr H;
    hence A c= Y;
  end;
  the carrier of (Omega).G = carr (Omega).G;
  then
A2: ex H being strict StableSubgroup of G st P[H];
  consider H being strict StableSubgroup of G such that
A3: the carrier of H = meet{B where B is Subset of G: ex H being strict
  StableSubgroup of G st B = the carrier of H & P[H]} from MeetSbgWOpEx(A2);
A4: now
    let H1 be strict StableSubgroup of G;
A5: the carrier of H1 = carr H1;
    assume A c= the carrier of H1;
    then the carrier of H1 in X by A5;
    hence H is StableSubgroup of H1 by A3,Lm20,SETFAM_1:3;
  end;
  carr (Omega).G in X;
  then A c= the carrier of H by A3,A1,SETFAM_1:5;
  hence thesis by A3,A4,Def26;
end;
