
theorem Th25:
  for V be non empty VectSp of F_Complex for l be
  linear-Functional of RealVS(V) holds prodReIm(l) is linear-Functional of V
proof
  let V be non empty VectSp of F_Complex;
  let l be linear-Functional of RealVS(V);
A1: prodReIm(l) is homogeneous
  proof
    let x be Vector of V;
    let r be Scalar of V;
    reconsider r1=r as Element of COMPLEX by COMPLFLD:def 1;
    set a=Re r1,b=Im r1;
A2: r1 = a+b*<i> by COMPLEX1:13;
A3: -1_F_Complex = [**-1,0**] by COMPLFLD:2,8;
    x = i_FC*(i_FC*(-1_F_Complex))*x by Th3,Th4
      .= i_FC*((-1_F_Complex)*i_FC*x) by VECTSP_1:def 16;
    then
A4: a*(-(RtoC l).(i_FC*x))+((RtoC l).x)*b = -a*(RtoC l).(i_FC*x)+b*(RtoC l
    ).(i_FC*((-1_F_Complex)*i_FC*x))
      .= -(RtoC l).([**a,0**]*(i_FC*x))+ -(-b)*(RtoC l).(i_FC*((-1_F_Complex
    )*i_FC*x)) by Def13
      .= -(RtoC l).([**a,0**]*(i_FC*x))+ -(RtoC l).([**0,-b**]*((-
    1_F_Complex)*i_FC*x)) by Th19
      .= -(RtoC l).([**a,0**]*(i_FC*x))+ -(RtoC l).([**0,-b**]*((-
    1_F_Complex)*(i_FC*x))) by VECTSP_1:def 16
      .= -(RtoC l).([**a,0**]*(i_FC*x))+ -(RtoC l).([**0,-b**]*(-1_F_Complex
    )*(i_FC*x)) by VECTSP_1:def 16
      .= -((RtoC l).([**a,0**]*(i_FC*x))+(RtoC l).([**0,b**]*(i_FC*x))) by A3
      .= -(RtoC l).([**a,0**]*(i_FC*x)+[**0,b**]*(i_FC*x)) by Def12
      .= -(RtoC l).(([**a,0**]+[**0,b**])*(i_FC*x)) by VECTSP_1:def 15
      .= -(RtoC l).(i_FC*r*x) by A2,VECTSP_1:def 16;
A5: a*((RtoC l).x)-b*(-(RtoC l).(i_FC*x)) = a*((RtoC l).x)+b*(RtoC l).( i_FC*x)
      .= (RtoC l).([**a,0**]*x)+b*(RtoC l).(i_FC*x) by Def13
      .= (RtoC l).([**a,0**]*x)+(RtoC l).([**0,b**]*x) by Th19
      .= (RtoC l).([**a,0**]*x+[**0,b**]*x) by Def12
      .= (RtoC l).(([**a,0**]+[**0,b**])*x) by VECTSP_1:def 15
      .= (RtoC l).(r*x) by COMPLEX1:13;
    thus (prodReIm(l)).(r*x) = [**(RtoC l).(r*x),-(i-shift(RtoC l)).(r*x)**]
    by Def23
      .= [**(RtoC l).(r*x),-(RtoC l).(i_FC*(r*x))**] by Def22
      .= (RtoC l).(r*x)+(a*(-(RtoC l).(i_FC*x))+((RtoC l).x)*b)*<i> by A4,
VECTSP_1:def 16
      .= r*[**(RtoC l).x,-(RtoC l).(i_FC*x)**] by A2,A5
      .= r*[**(RtoC l).x,-(i-shift(RtoC l)).x**] by Def22
      .= r*(prodReIm(l)).x by Def23;
  end;
  prodReIm(l) is additive
  proof
    let x,y be Vector of V;
    thus (prodReIm(l)).(x+y) = [**(RtoC l).(x+y),-(i-shift(RtoC l)).(x+y)**]
    by Def23
      .= [**(RtoC l).(x+y),-(RtoC l).(i_FC*(x+y))**] by Def22
      .= [**(RtoC l).x+(RtoC l).y,-(RtoC l).(i_FC*(x+y))**] by Def12
      .= [**(RtoC l).x+(RtoC l).y, -(RtoC l).(i_FC*x+i_FC*y)**] by
VECTSP_1:def 14
      .= [**(RtoC l).x+(RtoC l).y, -((RtoC l).(i_FC*x)+(RtoC l).(i_FC*y))**]
    by Def12
      .= [**(RtoC l).x,-(RtoC l).(i_FC*x)**] + [**(RtoC l).y,-(RtoC l).(i_FC
    *y)**]
      .= [**(RtoC l).x,-(i-shift(RtoC l)).x**] + [**(RtoC l).y,-(RtoC l).(
    i_FC*y)**] by Def22
      .= [**(RtoC l).x,-(i-shift(RtoC l)).x**] + [**(RtoC l).y,-(i-shift(
    RtoC l)).y**] by Def22
      .= (prodReIm(l)).x + [**(RtoC l).y,-(i-shift(RtoC l)).y**] by Def23
      .= (prodReIm(l)).x + (prodReIm(l)).y by Def23;
  end;
  hence thesis by A1;
end;
