reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th27:
  for sn being Real, K0,B0 being Subset of TOP-REAL 2, f being
Function of (TOP-REAL 2)|K0,(TOP-REAL 2)|B0 st -1<sn & sn<1 & f=(sn-FanMorphW)|
  K0 & B0=NonZero TOP-REAL 2 & K0={p: p`1<=0 & p<>0.TOP-REAL 2} holds f is
  continuous
proof
  let sn be Real,K0,B0 be Subset of TOP-REAL 2,
      f be Function of (TOP-REAL 2)|
  K0,(TOP-REAL 2)|B0;
  set cn=sqrt(1-sn^2);
  set p0=|[-cn,sn]|;
A1: p0`1=-cn by EUCLID:52;
  p0`2=sn by EUCLID:52;
  then
A2: |.p0.|=sqrt((-cn)^2+sn^2) by A1,JGRAPH_3:1
    .=sqrt((cn)^2+sn^2);
  assume
A3: -1<sn & sn<1 & f=(sn-FanMorphW)|K0 & B0=NonZero TOP-REAL 2 & K0={p:
  p`1<=0 & p<>0.TOP-REAL 2};
  then sn^2<1^2 by SQUARE_1:50;
  then
A4: 1-sn^2>0 by XREAL_1:50;
  then
A5: --cn>0 by SQUARE_1:25;
A6: now
    assume p0=0.TOP-REAL 2;
    then --cn=-0 by EUCLID:52,JGRAPH_2:3;
    hence contradiction by A4,SQUARE_1:25;
  end;
  then p0 in K0 by A3,A1,A5;
  then reconsider K1=K0 as non empty Subset of TOP-REAL 2;
  cn^2=1-sn^2 by A4,SQUARE_1:def 2;
  then
A7: p0`2/|.p0.|=sn by A2,EUCLID:52;
  then
A8: p0 in {p: p`2/|.p.|>=sn & p`1<=0 & p<>0.TOP-REAL 2} by A1,A6,A5;
  not p0 in {0.TOP-REAL 2} by A6,TARSKI:def 1;
  then reconsider D=B0 as non empty Subset of TOP-REAL 2 by A3,XBOOLE_0:def 5;
  K1 c= D
  proof
    let x be object;
    assume
A9: x in K1;
    then ex p6 being Point of TOP-REAL 2 st p6=x & p6`1<=0 & p6 <>0.TOP-REAL 2
    by A3;
    then not x in {0.TOP-REAL 2} by TARSKI:def 1;
    hence thesis by A3,A9,XBOOLE_0:def 5;
  end;
  then D=K1 \/ D by XBOOLE_1:12;
  then
A10: (TOP-REAL 2)|K1 is SubSpace of (TOP-REAL 2)|D by TOPMETR:4;
A11: {p: p`2/|.p.|<=sn & p`1<=0 & p<>0.TOP-REAL 2} c= K1
  proof
    let x be object;
    assume x in {p: p`2/|.p.|<=sn & p`1<=0 & p<>0.TOP-REAL 2};
    then ex p st p=x & p`2/|.p.|<=sn & p`1<=0 & p<>0.TOP-REAL 2;
    hence thesis by A3;
  end;
A12: {p: p`2/|.p.|>=sn & p`1<=0 & p<>0.TOP-REAL 2} c= K1
  proof
    let x be object;
    assume x in {p: p`2/|.p.|>=sn & p`1<=0 & p<>0.TOP-REAL 2};
    then ex p st p=x & p`2/|.p.|>=sn & p`1<=0 & p<>0.TOP-REAL 2;
    hence thesis by A3;
  end;
  then reconsider
  K00={p: p`2/|.p.|>=sn & p`1<=0 & p<>0.TOP-REAL 2} as non empty
  Subset of ((TOP-REAL 2)|K1) by A8,PRE_TOPC:8;
  the carrier of (TOP-REAL 2)|D=D by PRE_TOPC:8;
  then
A13: rng (f|K00) c=D;
  p0 in {p: p`2/|.p.|<=sn & p`1<=0 & p<>0.TOP-REAL 2} by A1,A6,A5,A7;
  then reconsider
  K11={p: p`2/|.p.|<=sn & p`1<=0 & p<>0.TOP-REAL 2} as non empty
  Subset of ((TOP-REAL 2)|K1) by A11,PRE_TOPC:8;
  the carrier of (TOP-REAL 2)|D=D by PRE_TOPC:8;
  then
A14: rng (f|K11) c=D;
  the carrier of (TOP-REAL 2)|B0=the carrier of (TOP-REAL 2)|D;
  then
A15: dom f=the carrier of (TOP-REAL 2)|K1 by FUNCT_2:def 1
    .=K1 by PRE_TOPC:8;
  then dom (f|K00)=K00 by A12,RELAT_1:62
    .= the carrier of ((TOP-REAL 2)|K1)|K00 by PRE_TOPC:8;
  then reconsider
  f1=f|K00 as Function of ((TOP-REAL 2)|K1)|K00,(TOP-REAL 2)|D by A13,FUNCT_2:2
;
  dom (f|K11)=K11 by A11,A15,RELAT_1:62
    .= the carrier of ((TOP-REAL 2)|K1)|K11 by PRE_TOPC:8;
  then reconsider
  f2=f|K11 as Function of ((TOP-REAL 2)|K1)|K11,(TOP-REAL 2)|D by A14,FUNCT_2:2
;
A16: the carrier of (TOP-REAL 2)|K1=K1 by PRE_TOPC:8;
  defpred P[Point of TOP-REAL 2] means $1`2/|.$1.|>=sn & $1`1<=0 & $1<>0.
  TOP-REAL 2;
A17: dom f2=the carrier of ((TOP-REAL 2)|K1)|K11 by FUNCT_2:def 1
    .=K11 by PRE_TOPC:8;
  {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider
  K001={p: p`2/|.p.|>=sn & p`1<=0 & p<>0.TOP-REAL 2} as non empty
  Subset of TOP-REAL 2 by A8;
A18: the carrier of (TOP-REAL 2)|K1 = K1 by PRE_TOPC:8;
  defpred P[Point of TOP-REAL 2] means $1`2>=(sn)*(|.$1.|) & $1`1<=0;
  {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider
  K003={p: p`2>=(sn)*(|.p.|) & p`1<=0} as Subset of TOP-REAL 2;
  defpred P[Point of TOP-REAL 2] means $1`2/|.$1.|<=sn & $1`1<=0 & $1<>0.
  TOP-REAL 2;
A19: {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
A20: rng ((sn-FanMorphW)|K001) c= K1
  proof
    let y be object;
    assume y in rng ((sn-FanMorphW)|K001);
    then consider x being object such that
A21: x in dom ((sn-FanMorphW)|K001) and
A22: y=((sn-FanMorphW)|K001).x by FUNCT_1:def 3;
    x in dom (sn-FanMorphW) by A21,RELAT_1:57;
    then reconsider q=x as Point of TOP-REAL 2;
A23: y=(sn-FanMorphW).q by A21,A22,FUNCT_1:47;
    dom ((sn-FanMorphW)|K001)=(dom (sn-FanMorphW))/\ K001 by RELAT_1:61
      .=(the carrier of TOP-REAL 2)/\ K001 by FUNCT_2:def 1
      .=K001 by XBOOLE_1:28;
    then
A24: ex p2 being Point of TOP-REAL 2 st p2=q & p2`2/|.p2.|>= sn & p2`1<=0 &
    p2<>0.TOP-REAL 2 by A21;
    then
A25: (q`2/|.q.|-sn)>= 0 by XREAL_1:48;
    |.q.|<>0 by A24,TOPRNS_1:24;
    then
A26: (|.q.|)^2>0^2 by SQUARE_1:12;
    set q4= |[ |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2)), |.q.|* ((q`2/|.q.|-
    sn)/(1-sn))]|;
A27: q4`2= |.q.|*((q`2/|.q.|-sn)/(1-sn)) by EUCLID:52;
A28: 1-sn>0 by A3,XREAL_1:149;
    0<=(q`1)^2 by XREAL_1:63;
    then 0+(q`2)^2<=(q`1)^2+(q`2)^2 by XREAL_1:7;
    then (q`2)^2 <= (|.q.|)^2 by JGRAPH_3:1;
    then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
    then (q`2)^2/(|.q.|)^2 <= 1 by A26,XCMPLX_1:60;
    then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
    then 1>=q`2/|.q.| by SQUARE_1:51;
    then 1-sn>=q`2/|.q.|-sn by XREAL_1:9;
    then -(1-sn)<= -( q`2/|.q.|-sn) by XREAL_1:24;
    then (-(1-sn))/(1-sn)<=(-( q`2/|.q.|-sn))/(1-sn) by A28,XREAL_1:72;
    then -1<=(-( q`2/|.q.|-sn))/(1-sn) by A28,XCMPLX_1:197;
    then ((-(q`2/|.q.|-sn))/(1-sn))^2<=1^2 by A28,A25,SQUARE_1:49;
    then
A29: 1-((-(q`2/|.q.|-sn))/(1-sn))^2>=0 by XREAL_1:48;
    then
A30: 1-(-((q`2/|.q.|-sn))/(1-sn))^2>=0 by XCMPLX_1:187;
    sqrt(1-((-(q`2/|.q.|-sn))/(1-sn))^2)>=0 by A29,SQUARE_1:def 2;
    then sqrt(1-(-(q`2/|.q.|-sn))^2/(1-sn)^2)>=0 by XCMPLX_1:76;
    then sqrt(1-(q`2/|.q.|-sn)^2/(1-sn)^2)>=0;
    then
A31: sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2)>=0 by XCMPLX_1:76;
A32: q4`1= |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2)) by EUCLID:52;
    then
A33: (q4`1)^2= (|.q.|)^2*(sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2))^2
      .= (|.q.|)^2*(1-((q`2/|.q.|-sn)/(1-sn))^2) by A30,SQUARE_1:def 2;
    (|.q4.|)^2=(q4`1)^2+(q4`2)^2 by JGRAPH_3:1
      .=(|.q.|)^2 by A27,A33;
    then
A34: q4<>0.TOP-REAL 2 by A26,TOPRNS_1:23;
    sn-FanMorphW.q= |[ |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2)), |.q.|*
    ((q`2/|.q.|-sn)/(1-sn))]| by A3,A24,Th18;
    hence thesis by A3,A23,A32,A31,A34;
  end;
A35: dom (sn-FanMorphW)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
  then dom ((sn-FanMorphW)|K001)=K001 by RELAT_1:62
    .= the carrier of (TOP-REAL 2)|K001 by PRE_TOPC:8;
  then reconsider
  f3=(sn-FanMorphW)|K001 as Function of (TOP-REAL 2)|K001,(TOP-REAL
  2)|K1 by A18,A20,FUNCT_2:2;
A36: K003 is closed by Th25;
  defpred P[Point of TOP-REAL 2] means $1`2<=(sn)*(|.$1.|) & $1`1<=0;
  {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider
  K004={p: p`2<=(sn)*(|.p.|) & p`1<=0} as Subset of TOP-REAL 2;
A37: K004 /\ K1 c= K11
  proof
    let x be object;
    assume
A38: x in K004 /\ K1;
    then x in K004 by XBOOLE_0:def 4;
    then consider q1 being Point of TOP-REAL 2 such that
A39: q1=x and
A40: q1`2<=(sn)*(|.q1.|) and
    q1`1<=0;
    x in K1 by A38,XBOOLE_0:def 4;
    then
A41: ex q2 being Point of TOP-REAL 2 st q2=x & q2`1<=0 & q2 <>0.TOP-REAL 2
    by A3;
    q1`2/|.q1.|<=(sn)*(|.q1.|)/|.q1.| by A40,XREAL_1:72;
    then q1`2/|.q1.|<=(sn) by A39,A41,TOPRNS_1:24,XCMPLX_1:89;
    hence thesis by A39,A41;
  end;
A42: K004 is closed by Th26;
  the carrier of (TOP-REAL 2)|K1=K1 by PRE_TOPC:8;
  then ((TOP-REAL 2)|K1)|K00=(TOP-REAL 2)|K001 & f1= f3 by A3,FUNCT_1:51
,GOBOARD9:2;
  then
A43: f1 is continuous by A3,A10,Th23,PRE_TOPC:26;
A44: [#]((TOP-REAL 2)|K1)=K1 by PRE_TOPC:def 5;
  p0 in {p: p`2/|.p.|<=sn & p`1<=0 & p<>0.TOP-REAL 2} by A1,A6,A5,A7;
  then reconsider
  K111={p: p`2/|.p.|<=sn & p`1<=0 & p<>0.TOP-REAL 2} as non empty
  Subset of TOP-REAL 2 by A19;
A45: rng ((sn-FanMorphW)|K111) c= K1
  proof
    let y be object;
    assume y in rng ((sn-FanMorphW)|K111);
    then consider x being object such that
A46: x in dom ((sn-FanMorphW)|K111) and
A47: y=((sn-FanMorphW)|K111).x by FUNCT_1:def 3;
    x in dom (sn-FanMorphW) by A46,RELAT_1:57;
    then reconsider q=x as Point of TOP-REAL 2;
A48: y=(sn-FanMorphW).q by A46,A47,FUNCT_1:47;
    dom ((sn-FanMorphW)|K111)=(dom (sn-FanMorphW))/\ K111 by RELAT_1:61
      .=(the carrier of TOP-REAL 2)/\ K111 by FUNCT_2:def 1
      .=K111 by XBOOLE_1:28;
    then
A49: ex p2 being Point of TOP-REAL 2 st p2=q & p2`2/|.p2.|<= sn & p2`1<=0 &
    p2<>0.TOP-REAL 2 by A46;
    then
A50: (q`2/|.q.|-sn)<=0 by XREAL_1:47;
    |.q.|<>0 by A49,TOPRNS_1:24;
    then
A51: (|.q.|)^2>0^2 by SQUARE_1:12;
    set q4= |[ |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2)), |.q.|* ((q`2/|.q.|-
    sn)/(1+sn))]|;
A52: q4`2= |.q.|* ((q`2/|.q.|-sn)/(1+sn)) by EUCLID:52;
A53: 1+sn>0 by A3,XREAL_1:148;
    0<=(q`1)^2 by XREAL_1:63;
    then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`2)^2<=(q`1)^2+(q`2)^2 by JGRAPH_3:1
,XREAL_1:7;
    then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
    then (q`2)^2/(|.q.|)^2 <= 1 by A51,XCMPLX_1:60;
    then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
    then -1<=q`2/|.q.| by SQUARE_1:51;
    then -1-sn<=q`2/|.q.|-sn by XREAL_1:9;
    then (-(1+sn))/(1+sn)<=(( q`2/|.q.|-sn))/(1+sn) by A53,XREAL_1:72;
    then -1<=(( q`2/|.q.|-sn))/(1+sn) by A53,XCMPLX_1:197;
    then
A54: ( (q`2/|.q.|-sn) /(1+sn))^2<=1^2 by A53,A50,SQUARE_1:49;
    then
A55: 1-((q`2/|.q.|-sn)/(1+sn))^2>=0 by XREAL_1:48;
    1-(-((q`2/|.q.|-sn)/(1+sn)))^2>=0 by A54,XREAL_1:48;
    then 1-((-(q`2/|.q.|-sn))/(1+sn))^2>=0 by XCMPLX_1:187;
    then sqrt(1-((-(q`2/|.q.|-sn))/(1+sn))^2)>=0 by SQUARE_1:def 2;
    then sqrt(1-(-(q`2/|.q.|-sn))^2/(1+sn)^2)>=0 by XCMPLX_1:76;
    then sqrt(1-(q`2/|.q.|-sn)^2/(1+sn)^2)>=0;
    then
A56: sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2)>=0 by XCMPLX_1:76;
A57: q4`1= |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2)) by EUCLID:52;
    then
A58: (q4`1)^2= (|.q.|)^2*(sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2))^2
      .= (|.q.|)^2*(1-((q`2/|.q.|-sn)/(1+sn))^2) by A55,SQUARE_1:def 2;
    (|.q4.|)^2=(q4`1)^2+(q4`2)^2 by JGRAPH_3:1
      .=(|.q.|)^2 by A52,A58;
    then
A59: q4<>0.TOP-REAL 2 by A51,TOPRNS_1:23;
    sn-FanMorphW.q= |[ |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2)), |.q.|*
    ((q`2/|.q.|-sn)/(1+sn))]| by A3,A49,Th18;
    hence thesis by A3,A48,A57,A56,A59;
  end;
  dom ((sn-FanMorphW)|K111)=K111 by A35,RELAT_1:62
    .= the carrier of (TOP-REAL 2)|K111 by PRE_TOPC:8;
  then reconsider
  f4=(sn-FanMorphW)|K111 as Function of (TOP-REAL 2)|K111,(TOP-REAL
  2)|K1 by A16,A45,FUNCT_2:2;
  the carrier of (TOP-REAL 2)|K1=K1 by PRE_TOPC:8;
  then ((TOP-REAL 2)|K1)|K11=(TOP-REAL 2)|K111 & f2= f4 by A3,FUNCT_1:51
,GOBOARD9:2;
  then
A60: f2 is continuous by A3,A10,Th24,PRE_TOPC:26;
  set T1= ((TOP-REAL 2)|K1)|K00,T2=((TOP-REAL 2)|K1)|K11;
A61: [#](((TOP-REAL 2)|K1)|K11)=K11 by PRE_TOPC:def 5;
  K11 c= K004 /\ K1
  proof
    let x be object;
    assume x in K11;
    then consider p such that
A62: p=x and
A63: p`2/|.p.|<=sn and
A64: p`1<=0 and
A65: p<>0.TOP-REAL 2;
    p`2/|.p.|*|.p.|<=(sn)*(|.p.|) by A63,XREAL_1:64;
    then p`2<=(sn)*(|.p.|) by A65,TOPRNS_1:24,XCMPLX_1:87;
    then
A66: x in K004 by A62,A64;
    x in K1 by A3,A62,A64,A65;
    hence thesis by A66,XBOOLE_0:def 4;
  end;
  then K11=K004 /\ [#]((TOP-REAL 2)|K1) by A44,A37,XBOOLE_0:def 10;
  then
A67: K11 is closed by A42,PRE_TOPC:13;
A68: K003 /\ K1 c= K00
  proof
    let x be object;
    assume
A69: x in K003 /\ K1;
    then x in K003 by XBOOLE_0:def 4;
    then consider q1 being Point of TOP-REAL 2 such that
A70: q1=x and
A71: q1`2>=(sn)*(|.q1.|) and
    q1`1<=0;
    x in K1 by A69,XBOOLE_0:def 4;
    then
A72: ex q2 being Point of TOP-REAL 2 st q2=x & q2`1<=0 & q2 <>0.TOP-REAL 2
    by A3;
    q1`2/|.q1.|>=(sn)*(|.q1.|)/|.q1.| by A71,XREAL_1:72;
    then q1`2/|.q1.|>=(sn) by A70,A72,TOPRNS_1:24,XCMPLX_1:89;
    hence thesis by A70,A72;
  end;
A73: the carrier of ((TOP-REAL 2)|K1)=K0 by PRE_TOPC:8;
A74: D<>{};
A75: [#](((TOP-REAL 2)|K1)|K00)=K00 by PRE_TOPC:def 5;
A76: for p being object st p in ([#]T1)/\([#]T2) holds f1.p = f2.p
  proof
    let p be object;
    assume
A77: p in ([#]T1)/\([#]T2);
    then p in K00 by A75,XBOOLE_0:def 4;
    hence f1.p=f.p by FUNCT_1:49
      .=f2.p by A61,A77,FUNCT_1:49;
  end;
  K00 c= K003 /\ K1
  proof
    let x be object;
    assume x in K00;
    then consider p such that
A78: p=x and
A79: p`2/|.p.|>=sn and
A80: p`1<=0 and
A81: p<>0.TOP-REAL 2;
    p`2/|.p.|*|.p.|>=(sn)*(|.p.|) by A79,XREAL_1:64;
    then p`2>=(sn)*(|.p.|) by A81,TOPRNS_1:24,XCMPLX_1:87;
    then
A82: x in K003 by A78,A80;
    x in K1 by A3,A78,A80,A81;
    hence thesis by A82,XBOOLE_0:def 4;
  end;
  then K00=K003 /\ [#]((TOP-REAL 2)|K1) by A44,A68,XBOOLE_0:def 10;
  then
A83: K00 is closed by A36,PRE_TOPC:13;
A84: K1 c= K00 \/ K11
  proof
    let x be object;
    assume x in K1;
    then consider p such that
A85: p=x & p`1<=0 & p<>0.TOP-REAL 2 by A3;
    per cases;
    suppose
      p`2/|.p.|>=sn;
      then x in K00 by A85;
      hence thesis by XBOOLE_0:def 3;
    end;
    suppose
      p`2/|.p.|<sn;
      then x in K11 by A85;
      hence thesis by XBOOLE_0:def 3;
    end;
  end;
  then [#](((TOP-REAL 2)|K1)|K00) \/ [#](((TOP-REAL 2)|K1)|K11) =[#]((
  TOP-REAL 2)|K1) by A75,A61,A44,XBOOLE_0:def 10;
  then consider h being Function of (TOP-REAL 2)|K1,(TOP-REAL 2)|D such that
A86: h=f1+*f2 and
A87: h is continuous by A75,A61,A83,A67,A43,A60,A76,JGRAPH_2:1;
A88: dom h=the carrier of ((TOP-REAL 2)|K1) by FUNCT_2:def 1;
A89: dom f1=the carrier of ((TOP-REAL 2)|K1)|K00 by FUNCT_2:def 1
    .=K00 by PRE_TOPC:8;
A90: for y being object st y in dom h holds h.y=f.y
  proof
    let y be object;
    assume
A91: y in dom h;
    now
      per cases by A84,A88,A73,A91,XBOOLE_0:def 3;
      case
A92:    y in K00 & not y in K11;
        then y in dom f1 \/ dom f2 by A89,XBOOLE_0:def 3;
        hence h.y=f1.y by A17,A86,A92,FUNCT_4:def 1
          .=f.y by A92,FUNCT_1:49;
      end;
      case
A93:    y in K11;
        then y in dom f1 \/ dom f2 by A17,XBOOLE_0:def 3;
        hence h.y=f2.y by A17,A86,A93,FUNCT_4:def 1
          .=f.y by A93,FUNCT_1:49;
      end;
    end;
    hence thesis;
  end;
  K0=the carrier of ((TOP-REAL 2)|K0) by PRE_TOPC:8
    .=dom f by A74,FUNCT_2:def 1;
  hence thesis by A87,A88,A90,FUNCT_1:2,PRE_TOPC:8;
end;
