reserve i, i1, i2, j, j1, j2, k, m, n, t for Nat,
  D for non empty Subset of TOP-REAL 2,
  E for compact non vertical non horizontal Subset of TOP-REAL 2,
  C for compact connected non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p, q, x for Point of TOP-REAL 2,
  r, s for Real;

theorem Th27:
  i <= len G implies cell(G,i,width G) is not bounded
proof
  assume
A1: i <= len G;
  per cases by A1,NAT_1:14,XXREAL_0:1;
  suppose
A2: i = 0;
A3: cell(G,0,width G) = { |[r,s]| where r is Real, s is Real:
     r <= G*(1,1)`1 & G*(1,width G)`2 <= s } by GOBRD11:25;
    not ex r being Real st
     for q being Point of TOP-REAL 2 st q in cell(G,0,width G) holds |.q.| < r
    proof
      let r be Real;
      take q = |[min(-r,G*(1,1)`1),G*(1,width G)`2]|;
A4:   |.q`1.|<=|.q.| by JGRAPH_1:33;
      min(-r,G*(1,1)`1) <= G*(1,1)`1 by XXREAL_0:17;
      hence q in cell(G,0,width G) by A3;
      per cases;
      suppose
        r <= 0;
        hence thesis;
      end;
      suppose
A5:     r > 0;
        q`1 = min(-r,G*(1,1)`1) by EUCLID:52;
        then
A6:     |.-r.| <= |.q`1.| by A5,TOPREAL6:3,XXREAL_0:17;
        --r > 0 by A5;
        then -r < 0;
        then --r <= |.q`1.| by A6,ABSVALUE:def 1;
        hence thesis by A4,XXREAL_0:2;
      end;
    end;
    hence thesis by A2,JORDAN2C:34;
  end;
  suppose
A7: i >= 1 & i < len G;
    then
A8: cell(G,i,width G) = { |[r,s]| where r is Real, s is Real:
     G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*(1,width G)`2 <= s } by
GOBRD11:31;
    not ex r being Real st
     for q being Point of TOP-REAL 2 st q in cell(G,i,width G) holds |.q.| < r
    proof
      let r be Real;
      take q = |[G*(i,1)`1,max(r,G*(1,width G)`2)]|;
A9:   max(r,G*(1,width G)`2) >= G*(1,width G)`2 by XXREAL_0:25;
      width G <> 0 by MATRIX_0:def 10;
      then
A10:  1 <= width G by NAT_1:14;
      i < i+1 & i+1 <= len G by A7,NAT_1:13;
      then G*(i,1)`1 <= G*(i+1,1)`1 by A7,A10,GOBOARD5:3;
      hence q in cell(G,i,width G) by A8,A9;
A11:  |.q`2.|<=|.q.| by JGRAPH_1:33;
      per cases;
      suppose
        r <= 0;
        hence thesis;
      end;
      suppose
A12:    r > 0;
        q`2 = max(r,G*(1,width G)`2) by EUCLID:52;
        then q`2 >= r by XXREAL_0:25;
        then r <= |.q`2.| by A12,ABSVALUE:def 1;
        hence thesis by A11,XXREAL_0:2;
      end;
    end;
    hence thesis by JORDAN2C:34;
  end;
  suppose
A13: i = len G;
A14: cell(G,len G,width G) = { |[r,s]| where r, s is Real:
    G*(len G,1)`1 <= r & G*(1,width G)`2 <= s } by GOBRD11:28;
    not ex r being Real st
     for q being Point of TOP-REAL 2 st q in cell(G,i,width G) holds |.q.| < r
    proof
      let r be Real;
      take q = |[max(r,G*(len G,1)`1),G*(1,width G)`2]|;
A15:  |.q`1.|<=|.q.| by JGRAPH_1:33;
      G*(len G,1)`1 <= max(r,G*(len G,1)`1) by XXREAL_0:25;
      hence q in cell(G,i,width G) by A13,A14;
      per cases;
      suppose
        r <= 0;
        hence thesis;
      end;
      suppose
A16:    r > 0;
        q`1 = max(r,G*(len G,1)`1) by EUCLID:52;
        then r <= q`1 by XXREAL_0:25;
        then r <= |.q`1.| by A16,ABSVALUE:def 1;
        hence thesis by A15,XXREAL_0:2;
      end;
    end;
    hence thesis by JORDAN2C:34;
  end;
end;
