reserve i,j,k,n for Nat;

theorem
  for f being non constant standard special_circular_sequence holds f is
  clockwise_oriented iff Rotate(f,S-max L~f)/.2 in S-most L~f
proof
  set j = 1;
  let f be non constant standard special_circular_sequence;
  set r = Rotate(f,S-max L~f);
A1: r is_sequence_on GoB r by GOBOARD5:def 5;
  len r > 2 by TOPREAL8:3;
  then
A2: 1+1 in dom r by FINSEQ_3:25;
  then consider i2,j2 being Nat such that
A3: [i2,j2] in Indices GoB r and
A4: r/.(1+1) = (GoB r)*(i2,j2) by A1,GOBOARD1:def 9;
A5: i2 <= len GoB r by A3,MATRIX_0:32;
  set i = i_e_s r;
A6: S-max L~f in rng f by SPRECT_2:42;
  then
A7: r/.1 = S-max L~f by FINSEQ_6:92;
A8: 2 <= len f by TOPREAL8:3;
  thus f is clockwise_oriented implies r/.2 in S-most L~f
  proof
    set k = (S-max L~f)..f;
    k < len f by SPRECT_5:14;
    then
A9: k+1 <= len f by NAT_1:13;
    1 <= k+1 by NAT_1:11;
    then
A10: k+1 in dom f by A9,FINSEQ_3:25;
    then f/.(k+1) = f.(k+1) by PARTFUN1:def 6;
    then
A11: f/.(k+1) in rng f by A10,FUNCT_1:3;
A12: rng f c= L~f by A8,SPPOL_2:18;
A13: f/.k = S-max L~f by A6,FINSEQ_5:38;
    k <= k+1 by NAT_1:13;
    then
A14: f/.(k+1) = r/.(k+1+1 -' k) by A6,A9,FINSEQ_6:175
      .= r/.(k+(1+1) -' k)
      .= r/.2 by NAT_D:34;
    f is_sequence_on GoB f by GOBOARD5:def 5;
    then
A15: f is_sequence_on GoB r by REVROT_1:28;
    assume f is clockwise_oriented;
    then consider i,j being Nat such that
A16: [i+1,j] in Indices GoB r and
A17: [i,j] in Indices GoB r and
A18: f/.k = (GoB r)*(i+1,j) and
A19: f/.(k+1) = (GoB r)*(i,j) by A6,A9,A13,A15,Th24,FINSEQ_4:21;
A20: 1 <= i+1 & i+1 <= len GoB r by A16,MATRIX_0:32;
A21: 1 <= j & j <= width GoB r by A16,MATRIX_0:32;
A22: 1 <= j & j <= width GoB r by A16,MATRIX_0:32;
    1 <= i & i <= len GoB r by A17,MATRIX_0:32;
    then (f/.(k+1))`2 = (GoB r)*(1,j)`2 by A19,A21,GOBOARD5:1
      .= (f/.k)`2 by A18,A20,A22,GOBOARD5:1
      .= S-bound L~f by A13,EUCLID:52;
    hence thesis by A14,A11,A12,SPRECT_2:11;
  end;
  assume
A23: r/.2 in S-most L~f;
A24: [i,j] in Indices GoB r by JORDAN5D:def 6;
  then
A25: 1 <= i by MATRIX_0:32;
A26: L~r = L~f by REVROT_1:33;
  then
A27: (GoB r)*(i,j) = r/.1 by A7,JORDAN5D:def 6;
  then (GoB r)*(i,1)`2 = S-bound L~f by A7,EUCLID:52
    .= (S-min L~f)`2 by EUCLID:52;
  then (GoB r)*(i2,j2)`2 = (GoB r)*(i,1)`2 by A23,A4,PSCOMP_1:55;
  then
A28: j2 = 1 by A24,A3,JORDAN1G:6;
A29: j <= width GoB r by A24,MATRIX_0:32;
  rng r = rng f by FINSEQ_6:90,SPRECT_2:42;
  then 1 in dom r by FINSEQ_3:31,SPRECT_2:42;
  then |.1-1.|+|.i-i2.| = 1 by A1,A24,A27,A2,A3,A4,A28,GOBOARD1:def 9;
  then
A30: 0+|.i-i2.| = 1 by ABSVALUE:2;
  (GoB r)*(i2,j2)`1 <= (GoB r)*(i,1)`1 by A7,A27,A23,A4,PSCOMP_1:55;
  then i - i2 >= 0 by A25,A29,A28,A5,GOBOARD5:3,XREAL_1:48;
  then
A31: i - i2 = 1 by A30,ABSVALUE:def 1;
  then i2 = i-1;
  then
A32: i2 = i-'1 by A25,XREAL_1:233;
  then
A33: 1 <= i-'1 by A3,MATRIX_0:32;
A34: i <= len GoB r by A24,MATRIX_0:32;
A35: 1+1 <= len r by TOPREAL8:3;
  then
A36: Int left_cell(r,1) c= LeftComp r by GOBOARD9:21;
  Int left_cell(r,1) <> {} by A35,GOBOARD9:15;
  then consider p being object such that
A37: p in Int left_cell(r,1) by XBOOLE_0:def 1;
  [i-'1+1,j] in Indices GoB r by A24,A25,XREAL_1:235;
  then
  j-'1 = 1-1 & left_cell(r,1,GoB r) = cell(GoB r,i-'1,j-'1) by A35,A1,A27,A3,A4
,A28,A31,A32,GOBRD13:25,XREAL_1:233;
  then
A38: left_cell(r,1) = cell(GoB r,i-'1,0) by A35,JORDAN1H:21;
  i - 1 < i by XREAL_1:146;
  then i-'1 < len GoB r by A34,A31,A32,XXREAL_0:2;
  then
A39: Int left_cell(r,1) = { |[t,s]| where t,s is Real:
(GoB r)*(i-'1,1)`1 <
  t & t < (GoB r)*(i-'1+1,1)`1 & s < (GoB r)*(1,1)`2} by A33,A38,GOBOARD6:24;
  reconsider p as Point of TOP-REAL2 by A37;
A40: LeftComp r is_a_component_of (L~r)` & UBD L~r is_a_component_of (L~r)`
  by GOBOARD9:def 1,JORDAN2C:124;
  consider t,s being Real such that
A41: p = |[t,s]| and
  (GoB r)*(i-'1,1)`1 < t and
  t < (GoB r)*(i-'1+1,1)`1 and
A42: s < (GoB r)*(1,1)`2 by A39,A37;
  now
    assume south_halfline p meets L~r;
    then (south_halfline p) /\ L~r <> {} by XBOOLE_0:def 7;
    then consider a being object such that
A43: a in (south_halfline p) /\ L~r by XBOOLE_0:def 1;
A44: a in L~r by A43,XBOOLE_0:def 4;
A45: a in (south_halfline p) by A43,XBOOLE_0:def 4;
    reconsider a as Point of TOP-REAL2 by A43;
    a`2 <= p`2 by A45,TOPREAL1:def 12;
    then a`2 <= s by A41,EUCLID:52;
    then
A46: a`2 < (GoB r)*(1,1)`2 by A42,XXREAL_0:2;
    (GoB r)*(i,1)`2 = (GoB r)*(1,1)`2 by A25,A34,A29,GOBOARD5:1;
    then a`2 < S-bound L~r by A26,A7,A27,A46,EUCLID:52;
    hence contradiction by A44,PSCOMP_1:24;
  end;
  then
A47: south_halfline p c= UBD L~r by JORDAN2C:128;
  p in south_halfline p by TOPREAL1:38;
  then LeftComp r meets UBD L~r by A36,A37,A47,XBOOLE_0:3;
  then r is clockwise_oriented by A40,GOBOARD9:1,JORDAN1H:41;
  hence thesis by JORDAN1H:40;
end;
