reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem Th27:
  for u being Point of Euclid 1,r,u1 being Real st <*u1*>=u
  holds Ball(u,r)={<*s*>:u1-r<s & s<u1+r}
proof
  let u be Point of Euclid 1,r,u1 be Real;
  assume
A1: <*u1*>=u;
  reconsider u1 as Element of REAL by XREAL_0:def 1;
  {<*s*>:u1-r<s & s<u1+r} ={q where q is Element of Euclid 1: dist(u,q)<r}
  proof
A2: {q where q is Element of Euclid 1: dist(u,q)<r} c= {<*s*>:u1-r<s & s< u1+r}
    proof
      let x be object;
      assume x in {q where q is Element of Euclid 1: dist(u,q)<r};
      then consider q being Element of Euclid 1 such that
A3:   x=q and
A4:   dist(u,q)<r;
      reconsider eu=u, eq=q as Element of REAL 1;
      q is Tuple of 1,REAL by FINSEQ_2:131;
      then consider s1 be Element of REAL such that
A5:   q=<*s1*> by FINSEQ_2:97;
      reconsider us = (u1-s1)^2 as Element of REAL by XREAL_0:def 1;
      <*u1*>-<*s1*> =<*u1-s1*> by RVSUM_1:29;
      then sqr (<*u1*>-<*s1*>)=<*us*> by RVSUM_1:55;
      then Sum sqr (<*u1*>-<*s1*>)=(u1-s1)^2 by FINSOP_1:11;
      then
A6:   sqrt Sum sqr (<*u1*>-<*s1*>)=|.u1-s1.| by COMPLEX1:72;
      (Pitag_dist 1).(eu,eq)<r by A4,METRIC_1:def 1;
      then
A7:   |.<*u1*>-<*s1*>.| < r by A1,A5,EUCLID:def 6;
      then u1-s1 < r by A6,SEQ_2:1;
      then u1-s1+s1<r+s1 by XREAL_1:6;
      then
A8:   u1-r<r+s1-r by XREAL_1:9;
      -r < u1-s1 by A7,A6,SEQ_2:1;
      then -r+s1 < u1-s1+s1 by XREAL_1:6;
      then s1-r+r < u1+r by XREAL_1:6;
      hence thesis by A3,A5,A8;
    end;
    {<*s*>:u1-r<s & s<u1+r} c= {q where q is Element of Euclid 1: dist(u,q )<r}
    proof
      reconsider eu1=<*u1*> as Element of REAL 1 by FINSEQ_2:98;
      let x be object;
      assume x in {<*s*>:u1-r<s & s<u1+r};
      then consider s such that
A9:   x=<*s*> and
A10:  u1-r<s and
A11:  s<u1+r;
      s-r<u1+r-r by A11,XREAL_1:9;
      then
A12:  s+-r-s<u1-s by XREAL_1:9;
      reconsider ss=s as Element of REAL by XREAL_0:def 1;
      reconsider es=<*ss*> as Element of REAL 1 by FINSEQ_2:98;
      reconsider q1=<*ss*> as Element of Euclid 1 by FINSEQ_2:98;
      reconsider uss = (u1-ss)^2 as Element of REAL by XREAL_0:def 1;
      <*u1*>-<*ss*> =<*u1-ss*> by RVSUM_1:29;
      then sqr (<*u1*>-<*ss*>) =<*uss*> by RVSUM_1:55;
      then
A13:  Sum sqr (<*u1*>-<*ss*>)=(u1-s)^2 by FINSOP_1:11;
      u1-r+r<s+r by A10,XREAL_1:6;
      then u1-s<s+r-s by XREAL_1:9;
      then |.u1-s.| < r by A12,SEQ_2:1;
      then |.<*u1*>-<*ss*>.| < r by A13,COMPLEX1:72;
      then
      (the distance of Euclid 1).(u,q1)=dist(u,q1) & (Pitag_dist 1).(eu1,
      es)<r by EUCLID:def 6,METRIC_1:def 1;
      hence thesis by A1,A9;
    end;
    hence thesis by A2,XBOOLE_0:def 10;
  end;
  hence thesis by METRIC_1:17;
end;
