reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;

theorem Th27:
  for f being non constant standard special_circular_sequence st f
is_sequence_on G for k st 1 <= k & k+1 <= len f holds right_cell(f,k,G)\L~f c=
  RightComp f & left_cell(f,k,G)\L~f c= LeftComp f
proof
  let f be non constant standard special_circular_sequence such that
A1: f is_sequence_on G;
  let k such that
A2: 1 <= k & k+1 <= len f;
A3: Int right_cell(f,k,G) <> {} by A1,A2,Th9;
  set rc = right_cell(f,k,G)\L~f;
  rc \/ L~f = right_cell(f,k,G) \/ L~f by XBOOLE_1:39;
  then
  Int right_cell(f,k,G) c= right_cell(f,k,G) & right_cell(f,k,G) c= rc \/
  L~f by TOPS_1:16,XBOOLE_1:7;
  then
A4: Int right_cell(f,k,G) c= rc \/ L~f;
  set lc = left_cell(f,k,G)\L~f;
  rc = right_cell(f,k,G) /\ (L~f)` by SUBSET_1:13;
  then
A5: RightComp f is_a_component_of (L~f)` & rc c= (L~f)` by GOBOARD9:def 2
,XBOOLE_1:17;
  rc c= right_cell(f,k,G) & right_cell(f,k,G) c= right_cell(f,k) by A1,A2,
GOBRD13:33,XBOOLE_1:36;
  then rc c= right_cell(f,k);
  then
A6: Int rc c= Int right_cell(f,k) by TOPS_1:19;
  Int right_cell(f,k) c= RightComp f by A2,GOBOARD9:25;
  then
A7: Int rc c= RightComp f by A6;
  Int right_cell(f,k,G) misses L~f by A1,A2,Th15;
  then
A8: Int Int right_cell(f,k,G) c= Int rc by A4,TOPS_1:19,XBOOLE_1:73;
  Int right_cell(f,k,G) c= rc by A1,A2,A4,Th15,XBOOLE_1:73;
  then
A9: rc meets Int rc by A3,A8,XBOOLE_1:68;
  rc is connected by A1,A2,Th26;
  hence right_cell(f,k,G)\L~f c= RightComp f by A7,A9,A5,GOBOARD9:4;
  lc = left_cell(f,k,G) /\ (L~f)` by SUBSET_1:13;
  then
A10: LeftComp f is_a_component_of (L~f)` & lc c= (L~f)` by GOBOARD9:def 1
,XBOOLE_1:17;
  lc \/ L~f = left_cell(f,k,G) \/ L~f by XBOOLE_1:39;
  then
  Int left_cell(f,k,G) c= left_cell(f,k,G) & left_cell(f,k,G) c= lc \/ L~
  f by TOPS_1:16,XBOOLE_1:7;
  then
A11: Int left_cell(f,k,G) c= lc \/ L~f;
  lc c= left_cell(f,k,G) & left_cell(f,k,G) c= left_cell(f,k) by A1,A2,
GOBRD13:33,XBOOLE_1:36;
  then lc c= left_cell(f,k);
  then
A12: Int lc c= Int left_cell(f,k) by TOPS_1:19;
  Int left_cell(f,k) c= LeftComp f by A2,GOBOARD9:21;
  then
A13: Int lc c= LeftComp f by A12;
A14: Int left_cell(f,k,G) <> {} by A1,A2,Th9;
  Int left_cell(f,k,G) misses L~f by A1,A2,Th15;
  then
A15: Int Int left_cell(f,k,G) c= Int lc by A11,TOPS_1:19,XBOOLE_1:73;
  Int left_cell(f,k,G) c= lc by A1,A2,A11,Th15,XBOOLE_1:73;
  then
A16: lc meets Int lc by A14,A15,XBOOLE_1:68;
  lc is connected by A1,A2,Th26;
  hence thesis by A13,A16,A10,GOBOARD9:4;
end;
