reserve X for set,
        n,m,k for Nat,
        K for Field,
        f for n-element real-valued FinSequence,
        M for Matrix of n,m,F_Real;

theorem
  for A be affinely-independent Subset of TOP-REAL m st the_rank_of M = n
  holds (Mx2Tran M)"A is affinely-independent
proof
  set MT=Mx2Tran M;
  set TRn=TOP-REAL n,TRm=TOP-REAL m;
  let A be affinely-independent Subset of TRm such that
   A1: the_rank_of M=n;
  reconsider R=A/\rng MT as affinely-independent Subset of TRm by RLAFFIN1:43
,XBOOLE_1:17;
  A2: MT"A=MT"(A/\rng MT) by RELAT_1:133;
  per cases;
  suppose R is empty;
   then MT"A is empty by A2;
   hence thesis;
  end;
  suppose R is non empty;
   then consider v be Element of TRm such that
    A3: v in R and
    A4: (-v+R)\{0.TRm} is linearly-independent by RLAFFIN1:def 4;
   v in rng MT by A3,XBOOLE_0:def 4;
   then consider x be object such that
    A5: x in dom MT and
    A6: MT.x=v by FUNCT_1:def 3;
   reconsider x as Element of TRn by A5;
   -x=0.TRn-x by RLVECT_1:14;
   then A7: MT.(-x)=(MT.(0.TRn))-(MT.x) by MATRTOP1:28
    .=(0.TRm)-(MT.x) by MATRTOP1:29
    .=-v by A6,RLVECT_1:14;
   A8: dom MT=[#]TRn by FUNCT_2:def 1;
   MT.0.TRn=0.TRm by MATRTOP1:29;
   then A9: {0.TRm}=Im(MT,0.TRn) by A8,FUNCT_1:59
    .=MT.:{0.TRn} by RELAT_1:def 16;
   MT is one-to-one by A1,MATRTOP1:39;
   then A10: MT"{0.TRm}c={0.TRn} by A9,FUNCT_1:82;
   {0.TRn}c=[#]TRn by ZFMISC_1:31;
   then {0.TRn}c=MT"{0.TRm} by A8,A9,FUNCT_1:76;
   then MT"{0.TRm}={0.TRn} by A10;
   then MT"((-v+R)\{0.TRm})=MT"(-v+R)\{0.TRn} by FUNCT_1:69
    .=-x+(MT"R)\{0.TRn} by A7,MATRTOP1:31;
   then A11: -x+(MT"R)\{0.TRn} is linearly-independent by A1,A4,Th26;
   x in MT"R by A3,A5,A6,FUNCT_1:def 7;
   hence thesis by A2,A11,RLAFFIN1:def 4;
  end;
end;
