reserve X for non empty set,
  Y for set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  f,g for PartFunc of X,COMPLEX,
  r for Real,
  k for Real,
  n for Nat,
  E for Element of S;

theorem
  for f be with_the_same_dom Functional_Sequence of X,COMPLEX, g be
  PartFunc of X,COMPLEX, E be Element of S st dom(f.0) = E & (for n be Nat
  holds f.n is E-measurable) & dom g = E & for x be Element of X st x
  in E holds f#x is convergent & g.x = lim(f#x) holds g is E-measurable
proof
  let f be with_the_same_dom Functional_Sequence of X,COMPLEX, g be PartFunc
  of X,COMPLEX, E be Element of S;
  assume that
A1: dom (f.0) = E and
A2: for n be Nat holds f.n is E-measurable and
A3: dom g = E and
A4: for x be Element of X st x in E holds f#x is convergent & g.x = lim( f#x);
A5: now
    let n be Nat;
    f.n is E-measurable by A2;
    then Im(f.n) is E-measurable by MESFUN6C:def 1;
    hence (Im f).n is E-measurable by Th24;
  end;
A6: dom Im g = E by A3,COMSEQ_3:def 4;
A7: now
    let x be Element of X;
    assume
A8: x in E;
    then
A9: f#x is convergent by A4;
    then Im(f#x) is convergent;
    hence (Im f)#x is convergent by A1,A8,Th23;
    g.x = lim(f#x) by A4,A8;
    then Im(g.x) = lim Im(f#x) by A9,COMSEQ_3:41;
    then Im(g.x) = lim((Im f)#x) by A1,A8,Th23;
    hence (Im g).x = lim((Im f)#x) by A6,A8,COMSEQ_3:def 4;
  end;
  dom((Im f).0) = E by A1,Def12;
  then R_EAL Im g is E-measurable by A5,A6,A7,Th22;
  then
A10: Im g is E-measurable by MESFUNC6:def 1;
A11: now
    let n be Nat;
    f.n is E-measurable by A2;
    then Re(f.n) is E-measurable by MESFUN6C:def 1;
    hence (Re f).n is E-measurable by Th24;
  end;
A12: dom Re g = E by A3,COMSEQ_3:def 3;
A13: now
    let x be Element of X;
    assume
A14: x in E;
    then
A15: f#x is convergent by A4;
    then Re(f#x) is convergent;
    hence (Re f)#x is convergent by A1,A14,Th23;
    g.x = lim(f#x) by A4,A14;
    then Re(g.x) = lim Re(f#x) by A15,COMSEQ_3:41;
    then Re(g.x) = lim((Re f)#x) by A1,A14,Th23;
    hence (Re g).x = lim((Re f)#x) by A12,A14,COMSEQ_3:def 3;
  end;
  dom((Re f).0) = E by A1,Def11;
  then R_EAL Re g is E-measurable by A11,A12,A13,Th22;
  then Re g is E-measurable by MESFUNC6:def 1;
  hence thesis by A10,MESFUN6C:def 1;
end;
