reserve X for non empty set;
reserve e for set;
reserve x for Element of X;
reserve f,g for PartFunc of X,ExtREAL;
reserve S for SigmaField of X;
reserve F for Function of RAT,S;
reserve p,q for Rational;
reserve r for Real;
reserve n,m for Nat;
reserve A,B for Element of S;

theorem
  for f,A st f is A-measurable & A c= dom f holds |.f.| is A-measurable
proof
  let f,A;
  assume
A1: f is A-measurable & A c= dom f;
 for r be Real holds A /\ less_dom(|.f.|, r) in S
  proof
    let r be Real;
    reconsider r as R_eal by XXREAL_0:def 1;
 for x being object st x in less_dom(|.f.|, r) holds
    x in less_dom(f, r) /\ great_dom(f, -r)
    proof
      let x be object;
      assume
A2:   x in less_dom(|.f.|, r);
then A3:   x in dom |.f.| by MESFUNC1:def 11;
A4:   |.f.| .x <  r by A2,MESFUNC1:def 11;
      reconsider x as Element of X by A2;
A5:   x in dom f by A3,MESFUNC1:def 10;
A6:   |. f.x .| <  r by A3,A4,MESFUNC1:def 10;
then A7:   -( r) < f.x by EXTREAL1:21;
A8:  f.x <  r by A6,EXTREAL1:21;
A9:  x in less_dom(f, r) by A5,A8,MESFUNC1:def 11;
  x in great_dom(f, -r) by A5,A7,MESFUNC1:def 13;
      hence thesis by A9,XBOOLE_0:def 4;
    end;
    then
A10: less_dom(|.f.|, r) c= less_dom(f, r) /\ great_dom(f,
    -r);
 for x being object st x in less_dom(f, r) /\
    great_dom(f, -r) holds x in less_dom(|.f.|, r)
    proof
      let x be object;
      assume
A11:  x in less_dom(f, r) /\ great_dom(f, -r);
then A12:  x in less_dom(f, r) by XBOOLE_0:def 4;
A13:  x in great_dom(f, -r) by A11,XBOOLE_0:def 4;
A14:  x in dom f by A12,MESFUNC1:def 11;
A15:  f.x <  r by A12,MESFUNC1:def 11;
A16:   -r < f.x by A13,MESFUNC1:def 13;
      reconsider x as Element of X by A11;
A17:  x in dom |.f.| by A14,MESFUNC1:def 10;
|. f.x .| <  r by A15,A16,EXTREAL1:22;
then   |.f.| .x <  r by A17,MESFUNC1:def 10;
      hence thesis by A17,MESFUNC1:def 11;
    end;
then  less_dom(f, r) /\ great_dom(f, -r) c= less_dom(|.f.|,
     r);
then
A18: less_dom(|.f.|, r) = less_dom(f, r) /\ great_dom(f, -r) by
A10;
 A /\ great_dom(f, -r) /\ less_dom(f, r) in S by A1,MESFUNC1:32;
    hence thesis by A18,XBOOLE_1:16;
  end;
  hence thesis;
end;
