reserve n,m,k for Element of NAT,
  x,X for set,
  A1 for SetSequence of X,
  Si for SigmaField of X,
  XSeq for SetSequence of Si;
reserve Omega for non empty set,
  Sigma for SigmaField of Omega,
  ASeq for SetSequence of Sigma,
  P for Probability of Sigma;

theorem Th27:
  COM(Sigma,P) = COM(Sigma,P2M P)
proof
A1: COM( Sigma,P2M P) c= COM(Sigma,P)
  proof
    let x be object;
    assume x in COM( Sigma,P2M P);
    then consider B being set such that
A2: B in Sigma and
A3: ex C being thin of P2M(P) st x = B \/ C by MEASURE3:def 3;
    consider C being thin of P2M(P) such that
A4: x = B \/ C by A3;
    reconsider C1=C as thin of P by Th23;
    x = B \/ C1 by A4;
    hence thesis by A2,Def5;
  end;
  COM(Sigma,P) c= COM(Sigma,P2M P)
  proof
    let x be object;
    assume x in COM(Sigma,P);
    then consider B being set such that
A5: B in Sigma and
A6: ex C being thin of P st x = B \/ C by Def5;
    consider C being thin of P such that
A7: x = B \/ C by A6;
    reconsider C1=C as thin of P2M(P) by Th23;
    x = B \/ C1 by A7;
    hence thesis by A5,MEASURE3:def 3;
  end;
  hence thesis by A1;
end;
