reserve a, b, k, n, m for Nat,
  i for Integer,
  r for Real,
  p for Rational,
  c for Complex,
  x for object,
  f for Function;

theorem Th27:
  rfs(r).n = 0 & n <= m implies rfs(r).m = 0
proof
  assume that
A1: rfs(r).n = 0 and
A2: n <= m;
  per cases by A2,XXREAL_0:1;
  suppose
    n = m;
    hence thesis by A1;
  end;
  suppose
A3: n < m;
    defpred P[Nat] means n < $1 implies rfs(r).$1 = 0;
A4: for a being Nat st P[a] holds P[a+1]
    proof
      let a be Nat;
      assume
A5:   P[a];
      assume n < a+1;
      then
A6:   n <= a by NAT_1:13;
      per cases by A6,XXREAL_0:1;
      suppose
A7:     n = a;
        thus rfs(r).(a+1) = 1 / frac(rfs(r).a) by Def3
          .= 1 / (rfs(r).a - rfs(r).a) by A1,A7
          .= 0;
      end;
      suppose
A8:     n < a;
        thus rfs(r).(a+1) = 1 / frac(rfs(r).a) by Def3
          .= 1 / (rfs(r).a - rfs(r).a) by A5,A8
          .= 0;
      end;
    end;
A9: P[0];
    for a being Nat holds P[a] from NAT_1:sch 2(A9,A4);
    hence thesis by A3;
  end;
end;
