reserve a,b,c for set;
reserve r for Real,
  X for set,
  n for Element of NAT;

theorem Th27:
  for X,Y being infinite Subset of NAT st Sum (X-powers (1/2)) =
  Sum (Y-powers (1/2)) holds X = Y
proof
  set r = 1/2;
  let X,Y be infinite Subset of NAT such that
A1: Sum (X-powers (1/2)) = Sum (Y-powers (1/2)) and
A2: X <> Y;
  defpred P[Nat] means not ($1 in X iff $1 in Y);
  ex a being object st not (a in X iff a in Y) by A2,TARSKI:2;
  then
A3: ex i being Nat st P[i];
  consider i being Nat such that
A4: P[i] & for n being Nat st P[n] holds i <= n from NAT_1:sch 5(A3);
  reconsider i as Element of NAT by ORDINAL1:def 12;
  consider A,B being infinite Subset of NAT such that
A5: A = X & B = Y or A = Y & B = X and
A6: i in A and
A7: not i in B by A4;
A8: (A-powers r).i = r|^i by A6,Def5;
  defpred P[Nat] means
$1 < i implies (Partial_Sums (A-powers r)).
  $1 = (Partial_Sums (B-powers r)).$1;
A9: now
    let j be Nat;
    assume
A10: P[j];
    thus P[j+1]
    proof
A11:  j+1 in B & (B-powers r).(j+1) = r|^(j+1) or not j+1 in B & (B
      -powers r ).(j+1) = 0 by Def5;
A12:  j+1 in A & (A-powers r).(j+1) = r|^(j+1) or not j+1 in A & (A
      -powers r ).(j+1) = 0 by Def5;
      assume
A13:  j+1 < i;
      hence
      (Partial_Sums (A-powers r)).(j+1) = (Partial_Sums (B-powers r)).j +
      (A-powers r).(j+1) by A10,NAT_1:13,SERIES_1:def 1
        .= (Partial_Sums (B-powers r)).(j+1) by A12,A11,A13,A4,A5,
SERIES_1:def 1;
    end;
  end;
  (Partial_Sums (A-powers r)).0 = (A-powers r).0 by SERIES_1:def 1;
  then
A14: 0 in A & (Partial_Sums (A-powers r)).0 = r|^0 or not 0 in A & (
  Partial_Sums (A-powers r)).0 = 0 by Def5;
A15: (B-powers r).i = 0 by A7,Def5;
A16: (Partial_Sums (B-powers r)).0 = (B-powers r).0 by SERIES_1:def 1;
  then 0 in B & (Partial_Sums (B-powers r)).0 = r|^0 or not 0 in B & (
  Partial_Sums (B-powers r)).0 = 0 by Def5;
  then
A17: P[ 0 ] by A14,A4,A5;
A18: for j being Nat holds P[j] from NAT_1:sch 2(A17,A9);
A19: (Partial_Sums (A-powers r)).i = (Partial_Sums (B-powers r)).i + r|^i
  proof
    per cases by NAT_1:6;
    suppose
      i = 0;
      hence thesis by A8,A15,A16,SERIES_1:def 1;
    end;
    suppose
      ex j being Nat st i = j+1;
      then consider j being Nat such that
A20:  i = j+1;
      reconsider j as Element of NAT by ORDINAL1:def 12;
      j < i by A20,NAT_1:13;
      then (Partial_Sums (A-powers r)).j = (Partial_Sums (B-powers r)).j by A18
;
      hence
      (Partial_Sums (A-powers r)).i = (Partial_Sums (B-powers r)).j+0 + r
      |^i by A8,A20,SERIES_1:def 1
        .= (Partial_Sums (B-powers r)).i + r|^i by A15,A20,SERIES_1:def 1;
    end;
  end;
A21: (Partial_Sums (A-powers r)).i < Sum (A-powers r) by Th26;
A22: Sum ((B-powers r)^\(i+1)) <= r|^i by Th25;
  Sum (B-powers r) = (Partial_Sums (B-powers r)).i + Sum ((B-powers r)^\(
  i +1)) by Th21,SERIES_1:15;
  hence thesis by A19,A1,A5,A21,A22,XREAL_1:6;
end;
