reserve P,P1,P2,R for Subset of TOP-REAL 2,
  p,p1,p2,p3,p11,p22,q,q1,q2,q3,q4 for Point of TOP-REAL 2,
  f,h for FinSequence of TOP-REAL 2,
  r for Real,
  u for Point of Euclid 2,
  n,m,i,j,k for Nat,
  x,y for set;
reserve P, R for Subset of TOP-REAL 2;

theorem Th27:
  R is being_Region & p in R & P={q: q=p or ex P1 be Subset of
  TOP-REAL 2 st P1 is_S-P_arc_joining p,q & P1 c=R} implies R c= P
proof
  assume that
A1: R is being_Region and
A2: p in R and
A3: P = {q: q=p or ex P1 be Subset of TOP-REAL 2 st P1
  is_S-P_arc_joining p,q & P1 c=R};
A4: p in P by A3;
  set P2 = R \ P;
  reconsider P22=P2 as Subset of TOP-REAL 2;
A5: [#]((TOP-REAL 2)|R) = R by PRE_TOPC:def 5;
  then reconsider P11 = P, P12 = P22 as Subset of (TOP-REAL 2)|R by A2,A3,Th26,
XBOOLE_1:36;
  P \/ (R \ P) = P \/ R by XBOOLE_1:39;
  then
A6: [#]((TOP-REAL 2)|R) = P11 \/ P12 by A5,XBOOLE_1:12;
  now
    let x be object;
A7: now
      assume
A8:   x in P2;
      then reconsider q2=x as Point of TOP-REAL 2;
      not x in P by A8,XBOOLE_0:def 5;
      then
A9:   q2<>p & not ex P1 being Subset of TOP-REAL 2 st P1
      is_S-P_arc_joining p,q2 & P1 c=R by A3;
      q2 in R by A8,XBOOLE_0:def 5;
      hence
      x in {q: q<>p & q in R & not ex P1 being Subset of TOP-REAL 2 st P1
      is_S-P_arc_joining p,q & P1 c= R} by A9;
    end;
    now
      assume x in {q: q<>p & q in R & not ex P1 being Subset of TOP-REAL 2
      st P1 is_S-P_arc_joining p,q & P1 c=R};
      then
A10:  ex q3 st q3=x & q3<>p & q3 in R & not ex P1 being Subset of
      TOP-REAL 2 st P1 is_S-P_arc_joining p,q3 & P1 c=R;
      then not ex q st q=x & (q=p or ex P1 being Subset of TOP-REAL 2 st P1
      is_S-P_arc_joining p,q & P1 c=R);
      then not x in P by A3;
      hence x in P2 by A10,XBOOLE_0:def 5;
    end;
    hence x in P2 iff x in {q: q<>p & q in R & not ex P1 being Subset of
    TOP-REAL 2 st P1 is_S-P_arc_joining p,q & P1 c=R} by A7;
  end;
  then P2={q: q<>p & q in R & not ex P1 being Subset of TOP-REAL 2 st P1
  is_S-P_arc_joining p,q & P1 c=R} by TARSKI:2;
  then P22 is open by A1,Th24;
  then
A11: P22 in the topology of TOP-REAL 2 by PRE_TOPC:def 2;
  reconsider R9 = R as non empty Subset of TOP-REAL 2 by A2;
  R is connected by A1;
  then
A12: (TOP-REAL 2)|R9 is connected by CONNSP_1:def 3;
  P is open by A1,A2,A3,Th25;
  then
A13: P in the topology of TOP-REAL 2 by PRE_TOPC:def 2;
  P11 = P /\ [#]((TOP-REAL 2)|R) by XBOOLE_1:28;
  then P11 in the topology of (TOP-REAL 2)|R by A13,PRE_TOPC:def 4;
  then
A14: P11 is open by PRE_TOPC:def 2;
  P12 = P22 /\ [#]((TOP-REAL 2)|R) by XBOOLE_1:28;
  then P12 in the topology of ( TOP-REAL 2)|R by A11,PRE_TOPC:def 4;
  then
A15: P12 is open by PRE_TOPC:def 2;
A16: P11 misses P12 by XBOOLE_1:79;
  then P11 /\ P12 = {}((TOP-REAL 2)|R);
  then P2 = {} by A4,A12,A16,A6,A14,A15,CONNSP_1:11;
  hence thesis by XBOOLE_1:37;
end;
