
theorem :: 1.5. REMARK, (2') => (2''), p. 181
  for S,T being complete LATTICE, g being infs-preserving Function of S,T
  for X being Scott TopAugmentation of T
  for Y being Scott TopAugmentation of S
  for Z being Scott TopAugmentation of Image LowerAdj g
  for d being Function of X, Y, d9 being Function
  of X, Z st d = LowerAdj g & d9 = d
  holds d is relatively_open implies d9 is open
proof
  let S,T be complete LATTICE, g be infs-preserving Function of S,T;
  let X be Scott TopAugmentation of T;
  let Y be Scott TopAugmentation of S;
  let Z be Scott TopAugmentation of Image LowerAdj g;
  let d be Function of X, Y, d9 be Function of X, Z such that
A1: d = LowerAdj g and
A2: d9 = d and
A3: for V being open Subset of X holds d.:V is open Subset of Y|rng d;
  let V be Subset of X;
  assume V is open;
  then reconsider A = d.:V as open Subset of Y|rng d by A3;
A4: Image LowerAdj g = subrelstr rng LowerAdj g by YELLOW_2:def 2;
  then
A5: the carrier of Image LowerAdj g = rng d by A1,YELLOW_0:def 15;
A6: [#](Y|rng d) = rng d by PRE_TOPC:def 5;
A7: the RelStr of Z = Image LowerAdj g by YELLOW_9:def 4;
A8: the RelStr of Y = the RelStr of S by YELLOW_9:def 4;
  reconsider B = A as Subset of Z by A1,A4,A6,A7,YELLOW_0:def 15;
  A in the topology of Y|rng d by PRE_TOPC:def 2;
  then consider C being Subset of Y such that
A9: C in the topology of Y and
A10: A = C /\ [#](Y|rng d) by PRE_TOPC:def 4;
  C is open by A9;
  then
A11: C is upper inaccessible by WAYBEL11:def 4;
A12: B is upper
  proof
    let x,y be Element of Z;
    reconsider x9 = x, y9 = y as Element of Image LowerAdj g by A7;
    reconsider a = x9, b = y9 as Element of S by YELLOW_0:58;
    reconsider a9 = a, b9 = b as Element of Y by A8;
    assume that
A13: x in B and
A14: x <= y;
A15: x9 <= y9 by A7,A14,YELLOW_0:1;
A16: a in C by A10,A13,XBOOLE_0:def 4;
    a <= b by A15,YELLOW_0:59;
    then a9 <= b9 by A8,YELLOW_0:1;
    then b9 in C by A11,A16;
    hence thesis by A5,A6,A10,XBOOLE_0:def 4;
  end;
  B is inaccessible
  proof
    let D be directed non empty Subset of Z such that
A17: sup D in B;
    reconsider D9 = D as non empty Subset of Image LowerAdj g by A7;
    reconsider E = D9 as non empty Subset of S by A5,A8,XBOOLE_1:1;
    reconsider E9 = E as non empty Subset of Y by A8;
    D9 is directed by A7,WAYBEL_0:3;
    then E is directed by YELLOW_2:7;
    then
A18: E9 is directed by A8,WAYBEL_0:3;
A19: ex_sup_of D9,S by YELLOW_0:17;
    Image LowerAdj g is sups-inheriting by YELLOW_2:32;
    then "\/"(D9,S) in the carrier of Image LowerAdj g by A19;
    then sup E = sup D9 by YELLOW_0:68
      .= sup D by A7,YELLOW_0:17,26;
    then sup E9 = sup D by A8,YELLOW_0:17,26;
    then sup E9 in C by A10,A17,XBOOLE_0:def 4;
    then C meets E by A11,A18;
    hence thesis by A5,A6,A10,XBOOLE_1:77;
  end;
  hence thesis by A2,A12,WAYBEL11:def 4;
end;
