
theorem
  for o being infinite Ordinal holds GrLexOrder o is non well-ordering
proof
  let o be infinite Ordinal;
  set R = GrLexOrder o;
  set r = RelStr(# Bags o, R#);
  set ir = the InternalRel of r, cr = the carrier of r;
  assume R is well-ordering;
  then
A1: R is well_founded;
  cr = field ir by ORDERS_1:15;
  then ir is_well_founded_in cr by A1,WELLORD1:3;
  then
A2: r is well_founded;
  defpred P[Nat, set] means $2 = (o-->0)+*($1,1);
A3: now
    let n be Element of NAT;
    set y = (o-->0)+*(n,1);
A4: dom (o-->0) = o by FUNCOP_1:13;
    reconsider y as ManySortedSet of o;
A5: omega c= o by CARD_3:85;
    now
      let x be object;
      hereby
        assume x in {n};
        then x = n by TARSKI:def 1;
        hence y.x <> 0 by A4,A5,FUNCT_7:31;
      end;
      assume that
A6:   y.x <> 0 and
A7:   not x in {n};
      x <> n by A7,TARSKI:def 1;
      then
A8:   y.x = (o-->0).x by FUNCT_7:32;
      per cases;
      suppose x in dom (o-->0);
        hence contradiction by A6,A8,FUNCOP_1:7;
      end;
      suppose not x in dom (o-->0);
        hence contradiction by A6,A8,FUNCT_1:def 2;
      end;
    end;
    then support y = {n} by PRE_POLY:def 7;
    then y is finite-support by PRE_POLY:def 8;
    then reconsider y as Element of cr by PRE_POLY:def 12;
    take y;
    thus P[n,y];
  end;
  consider f being sequence of  cr such that
A9: for n being Element of NAT holds P[n,f.n] from FUNCT_2:sch 3(A3);
  reconsider f as sequence of r;
  f is descending
  proof
    let n be Nat;
     reconsider n0=n as Element of NAT by ORDINAL1:def 12;
    set fn1 = f.(n0+1), fn = f.n0;
A10: fn1 = (o-->0)+*((n+1),1) by A9;
A11: fn = (o-->0)+*(n,1) by A9;
    reconsider fn1 as bag of o;
    reconsider fn as bag of o;
A12: n0 in omega;
A13: omega c= o by CARD_3:85;
    n <> n+1;
    then
A14: fn1.n = (o-->0).n by A10,FUNCT_7:32
      .= 0 by A12,A13,FUNCOP_1:7;
A15: dom (o-->0) = o by FUNCOP_1:13;
    then
A16: fn.n = 1 by A11,A13,FUNCT_7:31;
    now
      let l be Ordinal;
      assume
A17:  l in n;
      then
A18:  l <> n;
      n < n+1 by NAT_1:13;
      then n in {i where i is Nat : i < n0+1};
      then n in n+1 by AXIOMS:4;
      then n c= n+1 by ORDINAL1:def 2;
      then l in n+1 by A17;
      then l <> n+1;
      hence fn1.l = (o-->0).l by A10,FUNCT_7:32
        .= fn.l by A11,A18,FUNCT_7:32;
    end;
    then
A19: fn1 < fn by A14,A16,PRE_POLY:def 9;
    thus f.(n+1) <> f.n by A11,A13,A14,A15,FUNCT_7:31;
    fn1 <=' fn by A19,PRE_POLY:def 10;
    then
A20: [f.(n+1), f.n] in LexOrder o by PRE_POLY:def 14;
    consider tn being FinSequence of NAT such that
A21: TotDegree fn = Sum tn and
A22: tn = fn*SgmX(RelIncl o, support fn) by Def4;
    consider tn1 being FinSequence of NAT such that
A23: TotDegree fn1 = Sum tn1 and
A24: tn1 = fn1*SgmX(RelIncl o, support fn1) by Def4;
    omega c= o by CARD_3:85;
    then reconsider nn=n, n1n = n+1 as Element of o by A12;
    now
      let x be object;
      hereby
        assume
A27:    x in support fn1;
        now
          assume x <> n1n;
          then fn1.x = (o-->0).x by A10,FUNCT_7:32;
          then fn1.x = 0 by A27,FUNCOP_1:7;
          hence contradiction by A27,PRE_POLY:def 7;
        end;
        hence x in {n1n} by TARSKI:def 1;
      end;
      assume x in {n1n};
      then x = n1n by TARSKI:def 1;
      then fn1.x = 1 by A10,A15,FUNCT_7:31;
      hence x in support fn1 by PRE_POLY:def 7;
    end;
    then support fn1 = {n1n} by TARSKI:2;
    then
A28: SgmX(RelIncl o, support fn1) = <*n1n*> by Th10;
A29: dom fn = o by A11,A15,FUNCT_7:30;
A30: dom fn1 = o by A10,A15,FUNCT_7:30;
    now
      let x be object;
      hereby
        assume
A31:    x in support fn;
        now
          assume x <> nn;
          then fn.x = (o-->0).x by A11,FUNCT_7:32;
          then fn.x = 0 by A31,FUNCOP_1:7;
          hence contradiction by A31,PRE_POLY:def 7;
        end;
        hence x in {nn} by TARSKI:def 1;
      end;
      assume x in {nn};
      then x = nn by TARSKI:def 1;
      then fn.x = 1 by A11,A15,FUNCT_7:31;
      hence x in support fn by PRE_POLY:def 7;
    end;
    then support fn = {nn} by TARSKI:2;
    then SgmX(RelIncl o, support fn) = <*nn*> by Th10;
    then
A32: tn = <*fn.n*> by A22,A29,FINSEQ_2:34
      .= <*1*> by A11,A13,A15,FUNCT_7:31
      .= <*fn1.n1n*> by A10,A15,FUNCT_7:31
      .= tn1 by A24,A28,A30,FINSEQ_2:34;
    for a,b,c being bag of o st [a,b] in LexOrder o
    holds [a+c, b+c] in LexOrder o by Def5;
    hence [f.(n+1), f.n] in ir by A20,A21,A23,A32,Def7;
  end;
  hence contradiction by A2,WELLFND1:14;
end;
