reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem Th28:
  for A,B,C,D,E being set, h being Function, A9,B9,C9,D9,E9 being
set st h = (B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (E .--> E9) +* (A .-->
  A9) holds rng h = {h.A,h.B,h.C,h.D,h.E}
proof
  let A,B,C,D,E be set;
  let h be Function;
  let A9,B9,C9,D9,E9 be set;
  assume
  h = (B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (E .--> E9) +* (A .--> A9 );
  then
A1: dom h = {A,B,C,D,E} by Th27;
  then
A2: B in dom h by ENUMSET1:def 3;
A3: D in dom h by A1,ENUMSET1:def 3;
A4: C in dom h by A1,ENUMSET1:def 3;
A5: rng h c= {h.A,h.B,h.C,h.D,h.E}
  proof
    let t be object;
    assume t in rng h;
    then consider x1 being object such that
A6: x1 in dom h and
A7: t = h.x1 by FUNCT_1:def 3;
    now
      per cases by A1,A6,ENUMSET1:def 3;
      case
        x1=A;
        hence thesis by A7,ENUMSET1:def 3;
      end;
      case
        x1=B;
        hence thesis by A7,ENUMSET1:def 3;
      end;
      case
        x1=C;
        hence thesis by A7,ENUMSET1:def 3;
      end;
      case
        x1=D;
        hence thesis by A7,ENUMSET1:def 3;
      end;
      case
        x1=E;
        hence thesis by A7,ENUMSET1:def 3;
      end;
    end;
    hence thesis;
  end;
A8: E in dom h by A1,ENUMSET1:def 3;
A9: A in dom h by A1,ENUMSET1:def 3;
  {h.A,h.B,h.C,h.D,h.E} c= rng h
  proof
    let t be object;
    assume
A10: t in {h.A,h.B,h.C,h.D,h.E};
    now
      per cases by A10,ENUMSET1:def 3;
      case
        t=h.A;
        hence thesis by A9,FUNCT_1:def 3;
      end;
      case
        t=h.B;
        hence thesis by A2,FUNCT_1:def 3;
      end;
      case
        t=h.C;
        hence thesis by A4,FUNCT_1:def 3;
      end;
      case
        t=h.D;
        hence thesis by A3,FUNCT_1:def 3;
      end;
      case
        t=h.E;
        hence thesis by A8,FUNCT_1:def 3;
      end;
    end;
    hence thesis;
  end;
  hence thesis by A5,XBOOLE_0:def 10;
end;
