reserve Y for non empty set;

theorem Th28:
  for a,b being Function of Y,BOOLEAN holds 'not'( a 'or' b)
  'imp' ('not' a '&' 'not' b)=I_el(Y)
proof
  let a,b be Function of Y,BOOLEAN;
  for x being Element of Y holds ('not'( a 'or' b) 'imp' ('not' a '&'
  'not' b)).x=TRUE
  proof
    let x be Element of Y;
    ('not'( a 'or' b) 'imp' ('not' a '&' 'not' b)).x ='not' ('not'( a 'or'
    b)).x 'or' ('not' a '&' 'not' b).x by BVFUNC_1:def 8
      .=(a 'or' b).x 'or' ('not' a '&' 'not' b).x by MARGREL1:def 19
      .=(a.x 'or' b.x) 'or' ('not' a '&' 'not' b).x by BVFUNC_1:def 4
      .=(a.x 'or' b.x) 'or' (('not' a).x '&' ('not' b).x) by
MARGREL1:def 20
      .=(a.x 'or' b.x) 'or' ('not' a.x '&' ('not' b).x) by
MARGREL1:def 19
      .=(a.x 'or' b.x) 'or' ('not' a.x '&' 'not' b.x) by
MARGREL1:def 19
      .=((a.x 'or' b.x) 'or' 'not' a.x) '&' ((a.x 'or' b.x) 'or'
    'not' b.x) by XBOOLEAN:9
      .=((a.x 'or' 'not' a.x) 'or' b.x) '&' (a.x 'or' (b.x 'or'
    'not' b.x))
      .=(TRUE 'or' b.x) '&' (a.x 'or' (b.x 'or' 'not' b.x)) by
XBOOLEAN:102
      .=TRUE '&' (a.x 'or' TRUE) by XBOOLEAN:102
      .=TRUE;
    hence thesis;
  end;
  hence thesis by BVFUNC_1:def 11;
end;
