reserve X for ComplexUnitarySpace;
reserve g for Point of X;
reserve seq, seq1, seq2 for sequence of X;
reserve Rseq for Real_Sequence;
reserve Cseq,Cseq1,Cseq2 for Complex_Sequence;
reserve z,z1,z2 for Complex;
reserve r for Real;
reserve k,n,m for Nat;

theorem
  ( for n holds seq.n <> 0.X & Rseq.n = ||.seq.(n+1).||/||.seq.n.|| ) &
  Rseq is convergent & lim Rseq < 1 implies seq is absolutely_summable
proof
  assume that
A1: for n holds seq.n <> 09(X) & Rseq.n = ||.seq.(n+1).||/||.seq.n.|| and
A2: Rseq is convergent & lim Rseq < 1;
  for n holds ||.seq.||.n > 0 & Rseq.n = ||.seq.||.(n+1)/||.seq.||.n
  proof
    let n;
    seq.n <> 09(X) by A1;
    then
A3: ||.seq.n.|| <> 0 by CSSPACE:42;
    ||.seq.n.|| >= 0 by CSSPACE:44;
    hence ||.seq.||.n > 0 by A3,CLVECT_2:def 3;
    Rseq.n = ||.seq.(n+1).||/||.seq.n.|| by A1
      .= ||.seq.||.(n+1)/||.seq.n.|| by CLVECT_2:def 3;
    hence Rseq.n = ||.seq.||.(n+1)/||.seq.||.n by CLVECT_2:def 3;
  end;
  then ||.seq.|| is summable by A2,SERIES_1:26;
  hence thesis;
end;
