
theorem Th28:
  for C1, C2 being Coherence_Space for f,g being U-continuous
  Function of C1,C2 st graph f = graph g holds f = g
proof
  let C1, C2 be Coherence_Space;
  let f,g be U-continuous Function of C1,C2;
A1: dom f = C1 by FUNCT_2:def 1;
A2: dom g = C1 by FUNCT_2:def 1;
A3: now
    let x be finite Element of C1;
    let f,g be U-continuous Function of C1,C2;
A4: dom f = C1 by FUNCT_2:def 1;
    assume
A5: graph f = graph g;
    thus f.x c= g.x
    proof
      let z be object;
      assume
A6:     z in f.x;
       reconsider x,z as set by TARSKI:1;
       [x,z] in graph f by A4,Th24,A6;
      hence thesis by A5,Th24;
    end;
  end;
A7: now
    let a be Element of C1;
    let f,g be U-continuous Function of C1,C2;
A8: dom g = C1 by FUNCT_2:def 1;
    assume
A9: graph f = graph g;
    thus f.:Fin a c= g.:Fin a
    proof
      let y be object;
      assume y in f.:Fin a;
      then consider x being object such that
      x in dom f and
A10:   x in Fin a and
A11:  y = f.x by FUNCT_1:def 6;
      f.x c= g.x & g.x c= f.x by A3,A9,A10;
      then f.x = g.x;
      hence thesis by A8,A10,A11,FUNCT_1:def 6;
    end;
  end;
  assume
A12: graph f = graph g;
  now
    let a be Element of C1;
    f.:Fin a c= g.:Fin a & g.:Fin a c= f.:Fin a by A12,A7;
    then
A13: f.:Fin a = g.:Fin a;
    thus f.a = union (f.:Fin a) by A1,Th20
      .= g.a by A2,A13,Th20;
  end;
  hence thesis by FUNCT_2:63;
end;
