reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;
reserve f for clockwise_oriented non constant standard
  special_circular_sequence;

theorem Th28:
  Cl RightComp SpStSeq C = product((1,2)-->([.W-bound L~SpStSeq C,
  E-bound L~SpStSeq C.], [.S-bound L~SpStSeq C,N-bound L~SpStSeq C.]))
proof
  set g = (1,2)-->([.W-bound L~SpStSeq C,E-bound L~SpStSeq C.], [.S-bound L~
  SpStSeq C,N-bound L~SpStSeq C.]);
A1: dom g = {1,2} by FUNCT_4:62;
A2: Cl RightComp SpStSeq C = (RightComp SpStSeq C) \/ L~SpStSeq C by Th21;
  hereby
    let a be object;
    assume
A3: a in Cl RightComp SpStSeq C;
    then reconsider b = a as Point of TOP-REAL 2;
    reconsider h = a as FinSequence by A3;
A4: for x being object st x in {1,2} holds h.x in g.x
    proof
      let x be object such that
A5:   x in {1,2};
      per cases by A5,TARSKI:def 2;
      suppose
A6:     x = 1;
        then
A7:     g.x = [.W-bound L~SpStSeq C,E-bound L~SpStSeq C.] by FUNCT_4:63;
        now
          per cases by A2,A3,XBOOLE_0:def 3;
          case
            a in RightComp SpStSeq C;
            then W-bound L~SpStSeq C < b`1 & E-bound L~SpStSeq C > b`1 by Th23
,Th24;
            hence thesis by A6,A7,XXREAL_1:1;
          end;
          case
            a in L~SpStSeq C;
            then W-bound L~SpStSeq C <= b`1 & b`1 <= E-bound L~SpStSeq C by
PSCOMP_1:24;
            hence thesis by A6,A7,XXREAL_1:1;
          end;
        end;
        hence thesis;
      end;
      suppose
A8:     x = 2;
        then
A9:     g.x = [.S-bound L~SpStSeq C,N-bound L~SpStSeq C.] by FUNCT_4:63;
        now
          per cases by A2,A3,XBOOLE_0:def 3;
          case
            a in RightComp SpStSeq C;
            then S-bound L~SpStSeq C < b`2 & N-bound L~SpStSeq C > b`2 by Th25
,Th26;
            hence thesis by A8,A9,XXREAL_1:1;
          end;
          case
            a in L~SpStSeq C;
            then S-bound L~SpStSeq C <= b`2 & b`2 <= N-bound L~SpStSeq C by
PSCOMP_1:24;
            hence thesis by A8,A9,XXREAL_1:1;
          end;
        end;
        hence thesis;
      end;
    end;
    a is Tuple of 2,REAL by A3,Lm1,FINSEQ_2:131;
    then ex r, s being Element of REAL st a = <*r,s*> by FINSEQ_2:100;
    then dom h = {1,2} by FINSEQ_1:2,89;
    hence a in product g by A1,A4,CARD_3:9;
  end;
  let a be object;
  assume a in product g;
  then consider h being Function such that
A10: a = h and
A11: dom h = dom g and
A12: for x being object st x in dom g holds h.x in g.x by CARD_3:def 5;
A13: [.S-bound L~SpStSeq C,N-bound L~SpStSeq C.]
   = {s where s is Real:
  S-bound L~SpStSeq C <= s & s <= N-bound L~SpStSeq C} by RCOMP_1:def 1;
  2 in dom g by A1,TARSKI:def 2;
  then h.2 in g.2 by A12;
  then h.2 in [.S-bound L~SpStSeq C,N-bound L~SpStSeq C.] by FUNCT_4:63;
  then consider s being Real such that
A14: h.2 = s and
A15: S-bound L~SpStSeq C <= s & s <= N-bound L~SpStSeq C by A13;
A16: [.W-bound L~SpStSeq C,E-bound L~SpStSeq C.]
  = {r where r is Real :
  W-bound L~SpStSeq C <= r & r <= E-bound L~SpStSeq C} by RCOMP_1:def 1;
  1 in dom g by A1,TARSKI:def 2;
  then h.1 in g.1 by A12;
  then h.1 in [.W-bound L~SpStSeq C,E-bound L~SpStSeq C.] by FUNCT_4:63;
  then consider r being Real such that
A17: h.1 = r and
A18: W-bound L~SpStSeq C <= r & r <= E-bound L~SpStSeq C by A16;
A19: LeftComp SpStSeq C = {q: not(W-bound L~SpStSeq C <= q`1 & q`1 <=
E-bound L~SpStSeq C & S-bound L~SpStSeq C <= q`2 & q`2 <= N-bound L~SpStSeq C)}
  by SPRECT_3:37;
A20: for k being object st k in dom h holds h.k = <*r,s*>.k
  proof
    let k be object;
    assume k in dom h;
    then k = 1 or k = 2 by A11,TARSKI:def 2;
    hence thesis by A17,A14;
  end;
  dom <*r,s*> = {1,2} by FINSEQ_1:2,89;
  then
A21: a = |[r,s]| by A10,A11,A20,FUNCT_1:2,FUNCT_4:62;
  assume not a in Cl RightComp SpStSeq C;
  then ( not a in RightComp SpStSeq C)& not a in L~SpStSeq C by A2,
XBOOLE_0:def 3;
  then a in LeftComp SpStSeq C by A21,Th16;
  then ex q st q = a & not(W-bound L~SpStSeq C <= q`1 & q`1 <= E-bound L~
  SpStSeq C & S-bound L~SpStSeq C <= q`2 & q`2 <= N-bound L~SpStSeq C) by A19;
  hence contradiction by A18,A15,A21;
end;
