
theorem
  for V be non empty VectSp of F_Complex for p be Semi-Norm of V for M
be Subspace of V for l be linear-Functional of M st for e be Vector of M for v
be Vector of V st v=e holds |.l.e.| <= p.v ex L be linear-Functional of V st L|
  the carrier of M = l & for e be Vector of V holds |.L.e.| <= p.e
proof
  let V be non empty VectSp of F_Complex;
  let p be Semi-Norm of V;
  reconsider p1=p as Banach-Functional of RealVS(V) by Th22;
  let M be Subspace of V;
  reconsider tcM = the carrier of M as Subset of V by VECTSP_4:def 2;
  reconsider RVSM = RealVS(M) as Subspace of RealVS(V) by Th20;
  let l be linear-Functional of M;
  reconsider prRl = projRe(l) as linear-Functional of RVSM by Th23;
A1: the addLoopStr of V = the addLoopStr of RealVS(V) by Def17;
A2: the addLoopStr of M = the addLoopStr of RealVS(M) by Def17;
  assume
A3: for e be Vector of M for v be Vector of V st v=e holds |.l.e.| <= p. v;
  for x be VECTOR of RVSM for v be VECTOR of RealVS(V) st x=v holds prRl.x
  <= p1.v
  proof
    let x be VECTOR of RVSM;
    reconsider x1=x as Vector of M by A2;
    let v be VECTOR of RealVS(V);
    reconsider v1=v as Vector of V by A1;
    prRl.x = Re(l.x1) by Def18;
    then
A4: prRl.x <= |.l.x1.| by COMPLEX1:54;
    assume x=v;
    then |.l.x1.| <= p.v1 by A3;
    hence thesis by A4,XXREAL_0:2;
  end;
  then consider L1 be linear-Functional of RealVS(V) such that
A5: L1|the carrier of RVSM=prRl and
A6: for e be VECTOR of RealVS(V) holds L1.e <= p1.e by HAHNBAN:22;
  reconsider L=prodReIm(L1) as linear-Functional of V by Th25;
  take L;
  now
    let x be Element of M;
    the carrier of M c= the carrier of V by VECTSP_4:def 2;
    then reconsider x2=x as Element of V;
    reconsider x1=x2,ix1=i_FC*x2 as Element of RealVS(V) by A1;
    reconsider lx=l.x as Element of COMPLEX by COMPLFLD:def 1;
    lx = Re lx+(Im lx)*<i> by COMPLEX1:13;
    then
A7: i_FC*l.x = 0*Re lx-1*Im lx + (0*Im lx+1*Re lx)*<i>;
A8: i_FC*x = i_FC*x2 by VECTSP_4:14;
    then
A9: L1.ix1 = (projRe(l)).ix1 by A2,A5,FUNCT_1:49
      .= Re(l.(i_FC*x)) by A8,Def18
      .= Re((-Im lx)+Re lx*<i>) by A7,Def8
      .= -Im(l.x) by COMPLEX1:12;
A10: L1.x1 = (projRe(l)).x1 by A2,A5,FUNCT_1:49
      .= Re(l.x) by Def18;
    thus (L|tcM).x = L.x by FUNCT_1:49
      .= [**(RtoC L1).x2,-(i-shift(RtoC L1)).x2**] by Def23
      .= [**Re(l.x),-(RtoC L1).(i_FC*x2)**] by A10,Def22
      .= l.x by A9,COMPLEX1:13;
  end;
  hence L|the carrier of M = l by FUNCT_2:63;
  let e be Vector of V;
  reconsider Le = L.e as Element of COMPLEX by COMPLFLD:def 1;
  Le*'/|.Le.| in COMPLEX by XCMPLX_0:def 2;
  then reconsider Ledz = Le*'/|.Le.| as Element of F_Complex
          by COMPLFLD:def 1;
  reconsider e1=e,Ledze=Ledz*e as VECTOR of RealVS(V) by A1;
  per cases;
  suppose
A11: |.Le.| <> 0;
A12: |.Ledz.| = |.Le*'.|/|.|.Le.|.| by COMPLEX1:67
      .= |.Le.|/|.Le.| by COMPLEX1:53
      .= 1 by A11,XCMPLX_1:60;
    |.Le.|+0*<i> = Ledz*L.e by Th2
      .= L.(Ledz*e) by Def8
      .= [**(RtoC L1).(Ledz*e),-(i-shift(RtoC L1)).(Ledz*e)**] by Def23
      .= L1.Ledze+(-(i-shift(RtoC L1)).(Ledz*e))*<i>;
    then
A13: L1.Ledze = |.L.e.| by COMPLEX1:77;
    p1.Ledze = |.Ledz.|*p.e by Def14
      .= p.e by A12;
    hence thesis by A6,A13;
  end;
  suppose
A14: |.Le.| = 0;
    |.L.e.| = |.[**(RtoC L1).e,-(i-shift(RtoC L1)).e**].| by Def23
      .= |.(RtoC L1).e+(-(i-shift(RtoC L1)).e)*<i>.|;
    then (RtoC L1).e+(-(i-shift(RtoC L1)).e)*<i> = 0+0*<i> by A14,COMPLEX1:45;
    then L1.e1 = 0 by COMPLEX1:77;
    hence thesis by A6,A14;
  end;
end;
