reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th28:
  for Kb,Cb being Subset of TOP-REAL 2 st
  Kb={p: not(-1 <p`1 & p`1< 1 & -1 <p`2 & p`2< 1)}&
  Cb={p2 where p2 is Point of TOP-REAL 2: |.p2.|>=1} holds Sq_Circ.:Kb=Cb
proof
  let Kb,Cb be Subset of TOP-REAL 2;
  assume
A1: Kb={p: not(-1 <p`1 & p`1< 1 & -1 <p`2 & p`2< 1)}&
  Cb={p2 where p2 is Point of TOP-REAL 2: |.p2.|>=1};
  thus Sq_Circ.:Kb c= Cb
  proof
    let y be object;
    assume y in Sq_Circ.:Kb;
    then consider x being object such that
    x in dom Sq_Circ and
A2: x in Kb and
A3: y=Sq_Circ.x by FUNCT_1:def 6;
    consider q being Point of TOP-REAL 2 such that
A4: q=x and
A5: not(-1 <q`1 & q`1< 1 & -1 <q`2 & q`2< 1) by A1,A2;
    now per cases;
      case
A6:     q=0.TOP-REAL 2;
        then
A7:     q`1=0 by EUCLID:52,54;
        q`2=0 by A6,EUCLID:52,54;
        hence contradiction by A5,A7;
      end;
      case
A8:     q<>0.TOP-REAL 2 & (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
        then
        A9:     Sq_Circ.q=|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2 )]|
        by JGRAPH_3:def 1;
A10:    not(-1 <q`2 & q`2< 1) implies -1>=q`1 or q`1>=1
        proof
          assume
A11:      not(-1 <q`2 & q`2< 1);
          now per cases by A11;
            case
A12:          -1>=q`2;
              then -q`1<= -1 or q`2>=q`1 & q`2<= -q`1 by A8,XXREAL_0:2;
              hence thesis by A12,XREAL_1:24,XXREAL_0:2;
            end;
            case q`2>=1;
              then 1<=q`1 or 1<= -q`1 by A8,XXREAL_0:2;
              then 1<=q`1 or --q`1<= -1 by XREAL_1:24;
              hence thesis;
            end;
          end;
          hence thesis;
        end;
A13:    (|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|)`1 = q`1/sqrt(1+(q
        `2/q`1)^2) by EUCLID:52;
A14:    (|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|)`2 = q`2/sqrt(1+(q
        `2/q`1)^2) by EUCLID:52;
A15:    1+(q`2/q`1)^2>0 by XREAL_1:34,63;
A16:    now
          assume
A17:      q`1=0;
          then q`2=0 by A8;
          hence contradiction by A8,A17,EUCLID:53,54;
        end;
        then
A18:    (q`1)^2>0 by SQUARE_1:12;
        (q`1)^2>=1^2 by A5,A10,SQUARE_1:48;
        then
A19:    sqrt((q`1)^2)>=1 by SQUARE_1:18,26;
        |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|^2
        =((q`1)/sqrt(1+(q`2/(q`1))^2))^2+(q`2/sqrt(1+(q`2/(q`1))^2))^2
        by A13,A14,JGRAPH_3:1
          .=(q`1)^2/(sqrt(1+(q`2/(q`1))^2))^2+(q`2/sqrt(1+(q`2/(q`1))^2))^2
        by XCMPLX_1:76
          .=(q`1)^2/(sqrt(1+(q`2/(q`1))^2))^2
        +(q`2)^2/(sqrt(1+(q`2/(q`1))^2))^2 by XCMPLX_1:76
          .=(q`1)^2/(1+(q`2/q`1)^2)+(q`2)^2/(sqrt(1+(q`2/q`1)^2))^2
        by A15,SQUARE_1:def 2
          .=(q`1)^2/(1+(q`2/q`1)^2)+(q`2)^2/(1+(q`2/q`1)^2)
        by A15,SQUARE_1:def 2
          .=((q`1)^2+(q`2)^2)/(1+(q`2/q`1)^2) by XCMPLX_1:62
          .=((q`1)^2+(q`2)^2)/(1+(q`2)^2/(q`1)^2) by XCMPLX_1:76
          .=((q`1)^2+(q`2)^2)/((q`1)^2/(q`1)^2+(q`2)^2/(q`1)^2)
        by A18,XCMPLX_1:60
          .=((q`1)^2+(q`2)^2)/(((q`1)^2+(q`2)^2)/(q`1)^2)
        by XCMPLX_1:62
          .=(q`1)^2*(((q`1)^2+(q`2)^2)/((q`1)^2+(q`2)^2))
        by XCMPLX_1:81
          .=(q`1)^2*1 by A16,COMPLEX1:1,XCMPLX_1:60
          .=(q`1)^2;
        then |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|>=1
        by A19,SQUARE_1:22;
        hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|>=1 by A3,A4,A9;
      end;
      case
A20:    q<>0.TOP-REAL 2 & not(q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
        then
        A21:    Sq_Circ.q=|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2 )]|
        by JGRAPH_3:def 1;
A22:    (|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|)`1 = q`1/sqrt(1+(q
        `1/q`2)^2) by EUCLID:52;
A23:    (|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|)`2 = q`2/sqrt(1+(q
        `1/q`2)^2) by EUCLID:52;
A24:    1+(q`1/q`2)^2>0 by XREAL_1:34,63;
A25:    q`2 <> 0 by A20;
        then
A26:    (q`2)^2>0 by SQUARE_1:12;
        not(-1 <q`1 & q`1< 1) implies -1>=q`2 or q`2>=1
        proof
          assume
A27:      not(-1 <q`1 & q`1< 1);
          now per cases by A27;
            case
A28:          -1>=q`1;
then q`2<= -1 or q`1<q`2 & -q`2<= --q`1 by A20,XREAL_1:24,XXREAL_0:2;
              then -q`2<= -1 or -1>=q`2 by A28,XXREAL_0:2;
              hence thesis by XREAL_1:24;
            end;
            case
A29:          q`1>=1;
              --q`1<= -q`2 & q`2<=q`1 or q`2>=q`1 & q`2>= -q`1
              by A20,XREAL_1:24;
              then 1<= -q`2 or q`2>=q`1 & q`2>= -q`1 by A29,XXREAL_0:2;
              then -1>= --q`2 or 1<=q`2 by A29,XREAL_1:24,XXREAL_0:2;
              hence thesis;
            end;
          end;
          hence thesis;
        end;
        then (q`2)^2>=1^2 by A5,SQUARE_1:48;
        then
A30:    sqrt((q`2)^2)>=1 by SQUARE_1:18,26;
        |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).|^2
        =((q`1)/sqrt(1+(q`1/(q`2))^2))^2+(q`2/sqrt(1+(q`1/(q`2))^2))^2
        by A22,A23,JGRAPH_3:1
          .=(q`1)^2/(sqrt(1+(q`1/(q`2))^2))^2+(q`2/sqrt(1+(q`1/(q`2))^2))^2
        by XCMPLX_1:76
          .=(q`1)^2/(sqrt(1+(q`1/(q`2))^2))^2
        +(q`2)^2/(sqrt(1+(q`1/(q`2))^2))^2 by XCMPLX_1:76
          .=(q`1)^2/(1+(q`1/q`2)^2)+(q`2)^2/(sqrt(1+(q`1/q`2)^2))^2
        by A24,SQUARE_1:def 2
          .=(q`1)^2/(1+(q`1/q`2)^2)+(q`2)^2/(1+(q`1/q`2)^2)
        by A24,SQUARE_1:def 2
          .=((q`1)^2+(q`2)^2)/(1+(q`1/q`2)^2) by XCMPLX_1:62
          .=((q`1)^2+(q`2)^2)/(1+(q`1)^2/(q`2)^2) by XCMPLX_1:76
          .=((q`1)^2+(q`2)^2)/((q`1)^2/(q`2)^2+(q`2)^2/(q`2)^2)
        by A26,XCMPLX_1:60
          .=((q`1)^2+(q`2)^2)/(((q`1)^2+(q`2)^2)/(q`2)^2) by XCMPLX_1:62
          .=(q`2)^2*(((q`1)^2+(q`2)^2)/((q`1)^2+(q`2)^2)) by XCMPLX_1:81
          .=(q`2)^2*1 by A25,COMPLEX1:1,XCMPLX_1:60
          .=(q`2)^2;
        then |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).|>=1
        by A30,SQUARE_1:22;
        hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|>=1 by A3,A4,A21;
      end;
    end;
    hence thesis by A1;
  end;
  let y be object;
  assume y in Cb;
  then consider p2 being Point of TOP-REAL 2 such that
A31: p2=y and
A32: |.p2.|>=1 by A1;
  set q=p2;
  now per cases;
    case q=0.TOP-REAL 2;
      hence contradiction by A32,TOPRNS_1:23;
    end;
    case
A33:  q<>0.TOP-REAL 2 & (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
      set px=|[q`1*sqrt(1+(q`2/q`1)^2),q`2*sqrt(1+(q`2/q`1)^2)]|;
A34:  px`1 = q`1*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
A35:  px`2 = q`2*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
      1+(q`2/q`1)^2>0 by XREAL_1:34,63;
      then
A36:  sqrt(1+(q`2/q`1)^2)>0 by SQUARE_1:25;
A37:  1+(px`2/px`1)^2>0 by XREAL_1:34,63;
A38:  px`2/px`1=q`2/q`1 by A34,A35,A36,XCMPLX_1:91;
A39:  q`1=q`1*sqrt(1+(q`2/q`1)^2)/(sqrt(1+(q`2/q`1)^2))by A36,XCMPLX_1:89
        .=px`1/(sqrt(1+(q`2/q`1)^2)) by EUCLID:52;
A40:  q`2=q`2*sqrt(1+(q`2/q`1)^2)/(sqrt(1+(q`2/q`1)^2))by A36,XCMPLX_1:89
        .=px`2/(sqrt(1+(q`2/q`1)^2)) by EUCLID:52;
A41:  |.q.|^2=q`1^2+q`2^2 by JGRAPH_3:1;
A42:  |.q.|^2>=1^2 by A32,SQUARE_1:15;
A43:  now
        assume that
A44:    px`1=0 and
A45:    px`2=0;
A46:    q`1*sqrt(1+(q`2/q`1)^2)=0 by A44,EUCLID:52;
A47:    q`2*sqrt(1+(q`2/q`1)^2)=0 by A45,EUCLID:52;
A48:    q`1=0 by A36,A46,XCMPLX_1:6;
        q`2=0 by A36,A47,XCMPLX_1:6;
        hence contradiction by A33,A48,EUCLID:53,54;
      end;
      q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 &
      q`2*sqrt(1+(q`2/q`1)^2) <= (-q`1)*sqrt(1+(q`2/q`1)^2)
      by A33,A36,XREAL_1:64;
      then
A49:  q`2<=q`1 & (-q`1)*sqrt(1+(q`2/q`1)^2) <= q`2*sqrt(1+(q`2/q`1) ^2)
      or px`2>=px`1 & px`2<=-px`1 by A34,A35,A36,XREAL_1:64;
      then px`2<=px`1 & -px`1<=px`2 or px`2>=px`1 & px`2<=-px`1
      by A34,A35,A36,XREAL_1:64;
      then
      A50:  Sq_Circ
.px=|[px`1/sqrt(1+(px`2/px`1)^2),px`2/sqrt(1+(px`2/px`1 )^2) ]|
      by A43,JGRAPH_2:3,JGRAPH_3:def 1;
A51:  px`1/sqrt(1+(px`2/px`1)^2)=q`1 by A34,A36,A38,XCMPLX_1:89;
A52:  px`2/sqrt(1+(px`2/px`1)^2)=q`2 by A35,A36,A38,XCMPLX_1:89;
A53:  dom Sq_Circ=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
      not px`1=0 by A34,A35,A36,A43,A49,XREAL_1:64;
      then
A54:  (px`1)^2>0 by SQUARE_1:12;
      then
A55:  (px`1)^2+(px`2)^2>0 by XREAL_1:34,63;
      (px`1)^2/(sqrt(1+(px`2/px`1)^2))^2+(px`2/sqrt(1+(px`2/px`1)^2)) ^2 >= 1
      by A38,A39,A40,A41,A42,XCMPLX_1:76;
      then
      (px`1)^2/(sqrt(1+(px`2/px`1)^2))^2+(px`2)^2/(sqrt(1+(px`2/px`1)^2))
      ^2>=1 by XCMPLX_1:76;
      then (px`1)^2/(1+(px`2/px`1)^2)+(px`2)^2/(sqrt(1+(px`2/px`1)^2))^2>=1
      by A37,SQUARE_1:def 2;
      then (px`1)^2/(1+(px`2/px`1)^2)+(px`2)^2/(1+(px`2/px`1)^2)>=1
      by A37,SQUARE_1:def 2;
      then ((px`1)^2/(1+(px`2/px`1)^2)
      +(px`2)^2/(1+(px`2/px`1)^2))*(1+(px`2/px`1)^2)>=1 *(1+(px`2/px`1)^2)
      by A37,XREAL_1:64;
      then (px`1)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2)
      +(px`2)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2)>=1 *(1+(px`2/px`1)^2);
      then (px`1)^2+(px`2)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2)
      >=1 *(1+(px`2/px`1)^2) by A37,XCMPLX_1:87;
      then
A56:  (px`1)^2+(px`2)^2>=1 *(1+(px`2/px`1)^2) by A37,XCMPLX_1:87;
      1 *(1+(px`2/px`1)^2) =1+(px`2)^2/(px`1)^2 by XCMPLX_1:76;
      then (px`1)^2+(px`2)^2-1>=1+(px`2)^2/(px`1)^2-1 by A56,XREAL_1:9;
      then ((px`1)^2+(px`2)^2-1)*(px`1)^2>=((px`2)^2/(px`1)^2)*(px`1)^2
      by A54,XREAL_1:64;
      then ((px`1)^2+((px`2)^2-1))*(px`1)^2>=(px`2)^2 by A54,XCMPLX_1:87;
      then
A57:  (px`1)^2*(px`1)^2+(px`1)^2*((px`2)^2-1)-(px`2)^2>=0 by XREAL_1:48;
      (px`1)^2*(px`1)^2+((px`1)^2*(px`2)^2-(px`1)^2*1)-(px`2)^2
      = ((px`1)^2-1)*((px`1)^2+(px`2)^2);
      then (px`1)^2-1>=0 by A55,A57,XREAL_1:132;
      then (px`1)^2-1+1>=0+1 by XREAL_1:7;
      then px`1>=1^2 or px`1<= -1 by SQUARE_1:50;
      then px in Kb by A1;
      hence ex x being set st x in dom Sq_Circ & x in Kb & y=Sq_Circ.x
      by A31,A50,A51,A52,A53,EUCLID:53;
    end;
    case
A58:  q<>0.TOP-REAL 2 & not(q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
      set px=|[q`1*sqrt(1+(q`1/q`2)^2),q`2*sqrt(1+(q`1/q`2)^2)]|;
A59:  q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 & q`1<=-q`2 by A58,JGRAPH_2:13;
A60:  px`2 = q`2*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
A61:  px`1 = q`1*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
      1+(q`1/q`2)^2>0 by XREAL_1:34,63;
      then
A62:  sqrt(1+(q`1/q`2)^2)>0 by SQUARE_1:25;
A63:  1+(px`1/px`2)^2>0 by XREAL_1:34,63;
A64:  px`1/px`2=q`1/q`2 by A60,A61,A62,XCMPLX_1:91;
A65:  q`2=q`2*sqrt(1+(q`1/q`2)^2)/(sqrt(1+(q`1/q`2)^2))by A62,XCMPLX_1:89
        .=px`2/(sqrt(1+(q`1/q`2)^2)) by EUCLID:52;
A66:  q`1=q`1*sqrt(1+(q`1/q`2)^2)/(sqrt(1+(q`1/q`2)^2))by A62,XCMPLX_1:89
        .=px`1/(sqrt(1+(q`1/q`2)^2)) by EUCLID:52;
A67:  |.q.|^2=q`2^2+q`1^2 by JGRAPH_3:1;
A68:  |.q.|^2>=1^2 by A32,SQUARE_1:15;
A69:  now
        assume that
A70:    px`2=0 and
A71:    px`1=0;
A72:    q`2*sqrt(1+(q`1/q`2)^2)=0 by A70,EUCLID:52;
        q`1*sqrt(1+(q`1/q`2)^2)=0 by A71,EUCLID:52;
        then q`1=0 by A62,XCMPLX_1:6;
        hence contradiction by A58,A72;
      end;
      q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 &
      q`1*sqrt(1+(q`1/q`2)^2) <= (-q`2)*sqrt(1+(q`1/q`2)^2)
      by A59,A62,XREAL_1:64;
      then
A73:  q`1<=q`2 & (-q`2)*sqrt(1+(q`1/q`2)^2) <= q`1*sqrt(1+(q`1/q`2) ^2)
      or px`1>=px`2 & px`1<=-px`2 by A60,A61,A62,XREAL_1:64;
      then px`1<=px`2 & -px`2<=px`1 or px`1>=px`2 & px`1<=-px`2
      by A60,A61,A62,XREAL_1:64;
      then
      A74:  Sq_Circ
.px=|[px`1/sqrt(1+(px`1/px`2)^2),px`2/sqrt(1+(px`1/px`2 )^2) ]|
      by A69,JGRAPH_2:3,JGRAPH_3:4;
A75:  px`2/sqrt(1+(px`1/px`2)^2)=q`2 by A60,A62,A64,XCMPLX_1:89;
A76:  px`1/sqrt(1+(px`1/px`2)^2)=q`1 by A61,A62,A64,XCMPLX_1:89;
A77:  dom Sq_Circ=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
      not px`2=0 by A60,A61,A62,A69,A73,XREAL_1:64;
      then
A78:  (px`2)^2>0 by SQUARE_1:12;
A79:  (px`1)^2>=0 by XREAL_1:63;
      (px`2)^2/(sqrt(1+(px`1/px`2)^2))^2+(px`1/sqrt(1+(px`1/px`2)^2)) ^2 >= 1
      by A64,A65,A66,A67,A68,XCMPLX_1:76;
      then
      (px`2)^2/(sqrt(1+(px`1/px`2)^2))^2+(px`1)^2/(sqrt(1+(px`1/px`2)^2))
      ^2>=1 by XCMPLX_1:76;
      then (px`2)^2/(1+(px`1/px`2)^2)+(px`1)^2/(sqrt(1+(px`1/px`2)^2))^2>=1
      by A63,SQUARE_1:def 2;
      then (px`2)^2/(1+(px`1/px`2)^2)+(px`1)^2/(1+(px`1/px`2)^2)>=1
      by A63,SQUARE_1:def 2;
      then ((px`2)^2/(1+(px`1/px`2)^2)
      +(px`1)^2/(1+(px`1/px`2)^2))*(1+(px`1/px`2)^2)>=1 *(1+(px`1/px`2)^2)
      by A63,XREAL_1:64;
      then (px`2)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2)
      +(px`1)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2)>=1 *(1+(px`1/px`2)^2);
      then (px`2)^2+(px`1)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2)
      >=1 *(1+(px`1/px`2)^2) by A63,XCMPLX_1:87;
      then
A80:  (px`2)^2+(px`1)^2>=1 *(1+(px`1/px`2)^2) by A63,XCMPLX_1:87;
      1 *(1+(px`1/px`2)^2) =1+(px`1)^2/(px`2)^2 by XCMPLX_1:76;
      then (px`2)^2+(px`1)^2-1>=1+(px`1)^2/(px`2)^2-1 by A80,XREAL_1:9;
      then ((px`2)^2+(px`1)^2-1)*(px`2)^2>=((px`1)^2/(px`2)^2)*(px`2)^2
      by A78,XREAL_1:64;
      then ((px`2)^2+((px`1)^2-1))*(px`2)^2>=(px`1)^2 by A78,XCMPLX_1:87;
      then
A81:  (px`2)^2*(px`2)^2+(px`2)^2*((px`1)^2-1)-(px`1)^2>=0 by XREAL_1:48;
      (px`2)^2*(px`2)^2+((px`2)^2*(px`1)^2-(px`2)^2*1)-(px`1)^2
      = ((px`2)^2-1)*((px`2)^2+(px`1)^2);
      then (px`2)^2-1>=0 & (px`1)^2+(px`2)^2>=0 or
      (px`2)^2-1<=0 & (px`1)^2+(px`2)^2<=0 by A81,XREAL_1:132;
      then (px`2)^2-1+1>=0+1 by A78,A79,XREAL_1:7;
      then px`2>=1^2 or px`2<= -1 by SQUARE_1:50;
      then px in Kb by A1;
      hence ex x being set st x in dom Sq_Circ & x in Kb & y=Sq_Circ.x
      by A31,A74,A75,A76,A77,EUCLID:53;
    end;
  end;
  hence thesis by FUNCT_1:def 6;
end;
