reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence,
  p,p1,p2,q for Point of TOP-REAL 2;
reserve G for Go-board;

theorem Th28:
  for p,p1,p2,q st not q in LSeg(p1,p2) & p in LSeg(p1,p2) & p <>
p1 & p <> p2 & (p1`1 = p2`1 & p2`1 = q`1 or p1`2 = p2`2 & p2`2 = q`2) holds p1
  in LSeg(q,p) or p2 in LSeg(q,p)
proof
  let p,p1,p2,q such that
A1: not q in LSeg(p1,p2) and
A2: p in LSeg(p1,p2) and
A3: p <> p1 & p <> p2 and
A4: p1`1 = p2`1 & p2`1 = q`1 or p1`2 = p2`2 & p2`2 = q`2;
A5: not p1 in LSeg(p,p2) by A2,A3,Th27;
A6: not p2 in LSeg(p,p1) by A2,A3,Th27;
  per cases by A1,A4,Th25,Th26;
  suppose
A7: p1 in LSeg(q,p2);
A8: p in LSeg(q,p1) \/ LSeg(p1,p2) by A2,XBOOLE_0:def 3;
    LSeg(q,p1) \/ LSeg(p1,p2) = LSeg(q,p2) by A7,TOPREAL1:5;
    then LSeg(q,p) \/ LSeg(p,p2) = LSeg(q,p2) by A8,TOPREAL1:5;
    hence thesis by A5,A7,XBOOLE_0:def 3;
  end;
  suppose
A9: p2 in LSeg(q,p1);
A10: p in LSeg(q,p2) \/ LSeg(p1,p2) by A2,XBOOLE_0:def 3;
    LSeg(q,p2) \/ LSeg(p1,p2) = LSeg(q,p1) by A9,TOPREAL1:5;
    then LSeg(q,p) \/ LSeg(p,p1) = LSeg(q,p1) by A10,TOPREAL1:5;
    hence thesis by A6,A9,XBOOLE_0:def 3;
  end;
end;
