reserve n for Nat;

theorem Th28:
  for C be Simple_closed_curve for i,j,k be Nat st 1 <
j & j <= k & k < len Gauge(C,n) & 1 <= i & i <= width Gauge(C,n) & LSeg(Gauge(C
  ,n)*(j,i),Gauge(C,n)*(k,i)) /\ L~Upper_Seq(C,n) = {Gauge(C,n)*(k,i)} & LSeg(
  Gauge(C,n)*(j,i),Gauge(C,n)*(k,i)) /\ L~Lower_Seq(C,n) = {Gauge(C,n)*(j,i)}
  holds LSeg(Gauge(C,n)*(j,i),Gauge(C,n)*(k,i)) meets Lower_Arc C
proof
  let C be Simple_closed_curve;
  let i,j,k be Nat;
  set Ga = Gauge(C,n);
  set US = Upper_Seq(C,n);
  set LS = Lower_Seq(C,n);
  set LA = Lower_Arc C;
  set Wmin = W-min L~Cage(C,n);
  set Emax = E-max L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Ebo = E-bound L~Cage(C,n);
  set Gij = Ga*(j,i);
  set Gik = Ga*(k,i);
  assume that
A1: 1 < j and
A2: j <= k and
A3: k < len Ga and
A4: 1 <= i and
A5: i <= width Ga and
A6: LSeg(Gij,Gik) /\ L~US = {Gik} and
A7: LSeg(Gij,Gik) /\ L~LS = {Gij} and
A8: LSeg(Gij,Gik) misses LA;
  Gij in {Gij} by TARSKI:def 1;
  then
A9: Gij in L~LS by A7,XBOOLE_0:def 4;
  Gik in {Gik} by TARSKI:def 1;
  then
A10: Gik in L~US by A6,XBOOLE_0:def 4;
A11: len Ga = width Ga by JORDAN8:def 1;
A12: j <> k by A1,A3,A4,A5,A9,A10,Th27;
A13: j <= width Ga by A2,A3,A11,XXREAL_0:2;
A14: 1 <= k by A1,A2,XXREAL_0:2;
A15: k <= width Ga by A3,JORDAN8:def 1;
A16: [j,i] in Indices Ga by A1,A4,A5,A11,A13,MATRIX_0:30;
A17: [k,i] in Indices Ga by A3,A4,A5,A14,MATRIX_0:30;
  set go = R_Cut(US,Gik);
  set co = L_Cut(LS,Gij);
A18: len US >= 3 by JORDAN1E:15;
  then len US >= 1 by XXREAL_0:2;
  then 1 in dom US by FINSEQ_3:25;
  then
A19: US.1 = US/.1 by PARTFUN1:def 6
    .= Wmin by JORDAN1F:5;
A20: Wmin`1 = Wbo by EUCLID:52
    .= Ga*(1,k)`1 by A3,A14,JORDAN1A:73;
  len Ga >= 4 by JORDAN8:10;
  then
A21: len Ga >= 1 by XXREAL_0:2;
  then
A22: [1,k] in Indices Ga by A14,A15,MATRIX_0:30;
  then
A23: Gik <> US.1 by A1,A2,A17,A19,A20,JORDAN1G:7;
  then reconsider go as being_S-Seq FinSequence of TOP-REAL 2 by A10,JORDAN3:35
;
A24: [1,j] in Indices Ga by A1,A13,A21,MATRIX_0:30;
A25: len LS >= 1+2 by JORDAN1E:15;
  then
A26: len LS >= 1 by XXREAL_0:2;
  then
A27: 1 in dom LS by FINSEQ_3:25;
  len LS in dom LS by A26,FINSEQ_3:25;
  then
A28: LS.len LS = LS/.len LS by PARTFUN1:def 6
    .= Wmin by JORDAN1F:8;
A29: Wmin`1 = Wbo by EUCLID:52
    .= Ga*(1,k)`1 by A3,A14,JORDAN1A:73;
A30: [j,i] in Indices Ga by A1,A4,A5,A11,A13,MATRIX_0:30;
  then
A31: Gij <> LS.len LS by A1,A22,A28,A29,JORDAN1G:7;
  then reconsider co as being_S-Seq FinSequence of TOP-REAL 2 by A9,JORDAN3:34;
A32: [len Ga,k] in Indices Ga by A14,A15,A21,MATRIX_0:30;
A33: LS.1 = LS/.1 by A27,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
  Emax`1 = Ebo by EUCLID:52
    .= Ga*(len Ga,k)`1 by A3,A14,JORDAN1A:71;
  then
A34: Gij <> LS.1 by A2,A3,A30,A32,A33,JORDAN1G:7;
A35: len go >= 1+1 by TOPREAL1:def 8;
A36: Gik in rng US by A4,A5,A10,A11,A14,A15,JORDAN1G:4,JORDAN1J:40;
  then
A37: go is_sequence_on Ga by JORDAN1G:4,JORDAN1J:38;
A38: len co >= 1+1 by TOPREAL1:def 8;
A39: Gij in rng LS by A1,A4,A5,A9,A11,A13,JORDAN1G:5,JORDAN1J:40;
  then
A40: co is_sequence_on Ga by JORDAN1G:5,JORDAN1J:39;
  reconsider go as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A35,A37,JGRAPH_1:12,JORDAN8:5;
  reconsider co as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A38,A40,JGRAPH_1:12,JORDAN8:5;
A41: len go > 1 by A35,NAT_1:13;
  then
A42: len go in dom go by FINSEQ_3:25;
  then
A43: go/.len go = go.len go by PARTFUN1:def 6
    .= Gik by A10,JORDAN3:24;
  len co >= 1 by A38,XXREAL_0:2;
  then 1 in dom co by FINSEQ_3:25;
  then
A44: co/.1 = co.1 by PARTFUN1:def 6
    .= Gij by A9,JORDAN3:23;
  reconsider m = len go - 1 as Nat by A42,FINSEQ_3:26;
A45: m+1 = len go;
  then
A46: len go-'1 = m by NAT_D:34;
A47: LSeg(go,m) c= L~go by TOPREAL3:19;
A48: L~go c= L~US by A10,JORDAN3:41;
  then LSeg(go,m) c= L~US by A47;
  then
A49: LSeg(go,m) /\ LSeg(Gik,Gij) c= {Gik} by A6,XBOOLE_1:26;
  m >= 1 by A35,XREAL_1:19;
  then
A50: LSeg(go,m) = LSeg(go/.m,Gik) by A43,A45,TOPREAL1:def 3;
  {Gik} c= LSeg(go,m) /\ LSeg(Gik,Gij)
  proof
    let x be object;
A51: Gik in LSeg(Gik,Gij) by RLTOPSP1:68;
    assume x in {Gik};
    then
A52: x = Gik by TARSKI:def 1;
    Gik in LSeg(go,m) by A50,RLTOPSP1:68;
    hence thesis by A52,A51,XBOOLE_0:def 4;
  end;
  then
A53: LSeg(go,m) /\ LSeg(Gik,Gij) = {Gik} by A49;
A54: LSeg(co,1) c= L~co by TOPREAL3:19;
A55: L~co c= L~LS by A9,JORDAN3:42;
  then LSeg(co,1) c= L~LS by A54;
  then
A56: LSeg(co,1) /\ LSeg(Gik,Gij) c= {Gij} by A7,XBOOLE_1:26;
A57: LSeg(co,1) = LSeg(Gij,co/.(1+1)) by A38,A44,TOPREAL1:def 3;
  {Gij} c= LSeg(co,1) /\ LSeg(Gik,Gij)
  proof
    let x be object;
A58: Gij in LSeg(Gik,Gij) by RLTOPSP1:68;
    assume x in {Gij};
    then
A59: x = Gij by TARSKI:def 1;
    Gij in LSeg(co,1) by A57,RLTOPSP1:68;
    hence thesis by A59,A58,XBOOLE_0:def 4;
  end;
  then
A60: LSeg(Gik,Gij) /\ LSeg(co,1) = {Gij} by A56;
A61: go/.1 = US/.1 by A10,SPRECT_3:22
    .= Wmin by JORDAN1F:5;
  then
A62: go/.1 = LS/.len LS by JORDAN1F:8
    .= co/.len co by A9,JORDAN1J:35;
A63: rng go c= L~go by A35,SPPOL_2:18;
A64: rng co c= L~co by A38,SPPOL_2:18;
A65: {go/.1} c= L~go /\ L~co
  proof
    let x be object;
    assume x in {go/.1};
    then
A66: x = go/.1 by TARSKI:def 1;
    then
A67: x in rng go by FINSEQ_6:42;
    x in rng co by A62,A66,FINSEQ_6:168;
    hence thesis by A63,A64,A67,XBOOLE_0:def 4;
  end;
A68: LS.1 = LS/.1 by A27,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
A69: [len Ga,j] in Indices Ga by A1,A13,A21,MATRIX_0:30;
  L~go /\ L~co c= {go/.1}
  proof
    let x be object;
    assume
A70: x in L~go /\ L~co;
    then
A71: x in L~co by XBOOLE_0:def 4;
A72: now
      assume x = Emax;
      then
A73:  Emax = Gij by A9,A68,A71,JORDAN1E:7;
      Ga*(len Ga,j)`1 = Ebo by A1,A11,A13,JORDAN1A:71;
      then Emax`1 <> Ebo by A2,A3,A16,A69,A73,JORDAN1G:7;
      hence contradiction by EUCLID:52;
    end;
    x in L~go by A70,XBOOLE_0:def 4;
    then x in L~US /\ L~LS by A48,A55,A71,XBOOLE_0:def 4;
    then x in {Wmin,Emax} by JORDAN1E:16;
    then x = Wmin or x = Emax by TARSKI:def 2;
    hence thesis by A61,A72,TARSKI:def 1;
  end;
  then
A74: L~go /\ L~co = {go/.1} by A65;
  set W2 = go/.2;
A75: 2 in dom go by A35,FINSEQ_3:25;
A76: now
    assume Gij`1 = Wbo;
    then Ga*(1,j)`1 = Ga*(j,i)`1 by A1,A11,A13,JORDAN1A:73;
    hence contradiction by A1,A16,A24,JORDAN1G:7;
  end;
  go = mid(US,1,Gik..US) by A36,JORDAN1G:49
    .= US|(Gik..US) by A36,FINSEQ_4:21,FINSEQ_6:116;
  then
A77: W2 = US/.2 by A75,FINSEQ_4:70;
A78: Wmin in rng go by A61,FINSEQ_6:42;
  set pion = <*Gik,Gij*>;
A79: now
    let n be Nat;
    assume n in dom pion;
    then n in {1,2} by FINSEQ_1:2,89;
    then n = 1 or n = 2 by TARSKI:def 2;
    hence ex j,i be Nat st [j,i] in Indices Ga & pion/.n = Ga*(j,i)
    by A16,A17,FINSEQ_4:17;
  end;
A80: Gik <> Gij by A12,A16,A17,GOBOARD1:5;
  Gik`2 = Ga*(1,i)`2 by A3,A4,A5,A14,GOBOARD5:1
    .= Gij`2 by A1,A4,A5,A11,A13,GOBOARD5:1;
  then LSeg(Gik,Gij) is horizontal by SPPOL_1:15;
  then pion is being_S-Seq by A80,JORDAN1B:8;
  then consider pion1 be FinSequence of TOP-REAL 2 such that
A81: pion1 is_sequence_on Ga and
A82: pion1 is being_S-Seq and
A83: L~pion = L~pion1 and
A84: pion/.1 = pion1/.1 and
A85: pion/.len pion = pion1/.len pion1 and
A86: len pion <= len pion1 by A79,GOBOARD3:2;
  reconsider pion1 as being_S-Seq FinSequence of TOP-REAL 2 by A82;
  set godo = go^'pion1^'co;
A87: 1+1 <= len Cage(C,n) by GOBOARD7:34,XXREAL_0:2;
A88: 1+1 <= len Rotate(Cage(C,n),Wmin) by GOBOARD7:34,XXREAL_0:2;
  len (go^'pion1) >= len go by TOPREAL8:7;
  then
A89: len (go^'pion1) >= 1+1 by A35,XXREAL_0:2;
  then
A90: len (go^'pion1) > 1+0 by NAT_1:13;
A91: len godo >= len (go^'pion1) by TOPREAL8:7;
  then
A92: 1+1 <= len godo by A89,XXREAL_0:2;
A93: US is_sequence_on Ga by JORDAN1G:4;
A94: go/.len go = pion1/.1 by A43,A84,FINSEQ_4:17;
  then
A95: go^'pion1 is_sequence_on Ga by A37,A81,TOPREAL8:12;
A96: (go^'pion1)/.len (go^'pion1) = pion/.len pion by A85,FINSEQ_6:156
    .= pion/.2 by FINSEQ_1:44
    .= co/.1 by A44,FINSEQ_4:17;
  then
A97: godo is_sequence_on Ga by A40,A95,TOPREAL8:12;
  LSeg(pion1,1) c= L~<*Gik,Gij*> by A83,TOPREAL3:19;
  then LSeg(pion1,1) c= LSeg(Gik,Gij) by SPPOL_2:21;
  then
A98: LSeg(go,len go-'1) /\ LSeg(pion1,1) c= {Gik} by A46,A53,XBOOLE_1:27;
A99: len pion1 >= 1+1 by A86,FINSEQ_1:44;
  {Gik} c= LSeg(go,m) /\ LSeg(pion1,1)
  proof
    let x be object;
    assume x in {Gik};
    then
A100: x = Gik by TARSKI:def 1;
A101: Gik in LSeg(go,m) by A50,RLTOPSP1:68;
    Gik in LSeg(pion1,1) by A43,A94,A99,TOPREAL1:21;
    hence thesis by A100,A101,XBOOLE_0:def 4;
  end;
  then LSeg(go,len go-'1) /\ LSeg(pion1,1) = { go/.len go } by A43,A46,A98;
  then
A102: go^'pion1 is unfolded by A94,TOPREAL8:34;
  len pion1 >= 2+0 by A86,FINSEQ_1:44;
  then
A103: len pion1-2 >= 0 by XREAL_1:19;
  len (go^'pion1)+1-1 = len go+len pion1-1 by FINSEQ_6:139;
  then len (go^'pion1)-1 = len go + (len pion1-2)
    .= len go + (len pion1-'2) by A103,XREAL_0:def 2;
  then
A104: len (go^'pion1)-'1 = len go + (len pion1-'2) by XREAL_0:def 2;
A105: len pion1-1 >= 1 by A99,XREAL_1:19;
  then
A106: len pion1-'1 = len pion1-1 by XREAL_0:def 2;
A107: len pion1-'2+1 = len pion1-2+1 by A103,XREAL_0:def 2
    .= len pion1-'1 by A105,XREAL_0:def 2;
  len pion1-1+1 <= len pion1;
  then
A108: len pion1-'1 < len pion1 by A106,NAT_1:13;
  LSeg(pion1,len pion1-'1) c= L~<*Gik,Gij*> by A83,TOPREAL3:19;
  then LSeg(pion1,len pion1-'1) c= LSeg(Gik,Gij) by SPPOL_2:21;
  then
A109: LSeg(pion1,len pion1-'1) /\ LSeg(co,1) c= {Gij} by A60,XBOOLE_1:27;
  {Gij} c= LSeg(pion1,len pion1-'1) /\ LSeg(co,1)
  proof
    let x be object;
    assume x in {Gij};
    then
A110: x = Gij by TARSKI:def 1;
    pion1/.(len pion1-'1+1) = pion/.2 by A85,A106,FINSEQ_1:44
      .= Gij by FINSEQ_4:17;
    then
A111: Gij in LSeg(pion1,len pion1-'1) by A105,A106,TOPREAL1:21;
    Gij in LSeg(co,1) by A57,RLTOPSP1:68;
    hence thesis by A110,A111,XBOOLE_0:def 4;
  end;
  then LSeg(pion1,len pion1-'1) /\ LSeg(co,1) = {Gij} by A109;
  then
A112: LSeg(go^'pion1,len go+(len pion1-'2)) /\ LSeg(co,1) = {(go^'pion1)/.
  len (go^'pion1)} by A44,A94,A96,A107,A108,TOPREAL8:31;
A113: (go^'pion1) is non trivial by A89,NAT_D:60;
A114: rng pion1 c= L~pion1 by A99,SPPOL_2:18;
A115: {pion1/.1} c= L~go /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.1};
    then
A116: x = pion1/.1 by TARSKI:def 1;
    then
A117: x in rng pion1 by FINSEQ_6:42;
    x in rng go by A94,A116,FINSEQ_6:168;
    hence thesis by A63,A114,A117,XBOOLE_0:def 4;
  end;
  L~go /\ L~pion1 c= {pion1/.1}
  proof
    let x be object;
    assume
A118: x in L~go /\ L~pion1;
    then
A119: x in L~pion1 by XBOOLE_0:def 4;
    x in L~go by A118,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~US by A48,A119,XBOOLE_0:def 4;
    hence thesis by A6,A43,A83,A94,SPPOL_2:21;
  end;
  then
A120: L~go /\ L~pion1 = {pion1/.1} by A115;
  then
A121: (go^'pion1) is s.n.c. by A94,JORDAN1J:54;
  rng go /\ rng pion1 c= {pion1/.1} by A63,A114,A120,XBOOLE_1:27;
  then
A122: go^'pion1 is one-to-one by JORDAN1J:55;
A123: pion/.len pion = pion/.2 by FINSEQ_1:44
    .= co/.1 by A44,FINSEQ_4:17;
A124: {pion1/.len pion1} c= L~co /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.len pion1};
    then
A125: x = pion1/.len pion1 by TARSKI:def 1;
    then
A126: x in rng pion1 by FINSEQ_6:168;
    x in rng co by A85,A123,A125,FINSEQ_6:42;
    hence thesis by A64,A114,A126,XBOOLE_0:def 4;
  end;
  L~co /\ L~pion1 c= {pion1/.len pion1}
  proof
    let x be object;
    assume
A127: x in L~co /\ L~pion1;
    then
A128: x in L~pion1 by XBOOLE_0:def 4;
    x in L~co by A127,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~LS by A55,A128,XBOOLE_0:def 4;
    hence thesis by A7,A44,A83,A85,A123,SPPOL_2:21;
  end;
  then
A129: L~co /\ L~pion1 = {pion1/.len pion1} by A124;
A130: L~(go^'pion1) /\ L~co = (L~go \/ L~pion1) /\ L~co by A94,TOPREAL8:35
    .= {go/.1} \/ {co/.1} by A74,A85,A123,A129,XBOOLE_1:23
    .= {(go^'pion1)/.1} \/ {co/.1} by FINSEQ_6:155
    .= {(go^'pion1)/.1,co/.1} by ENUMSET1:1;
  co/.len co = (go^'pion1)/.1 by A62,FINSEQ_6:155;
  then reconsider
  godo as non constant standard special_circular_sequence by A92,A96,A97,A102
,A104,A112,A113,A121,A122,A130,JORDAN8:4,5,TOPREAL8:11,33,34;
A131: LA is_an_arc_of E-max C,W-min C by JORDAN6:def 9;
  then
A132: LA is connected by JORDAN6:10;
A133: W-min C in LA by A131,TOPREAL1:1;
A134: E-max C in LA by A131,TOPREAL1:1;
  set ff = Rotate(Cage(C,n),Wmin);
  Wmin in rng Cage(C,n) by SPRECT_2:43;
  then
A135: ff/.1 = Wmin by FINSEQ_6:92;
A136: L~ff = L~Cage(C,n) by REVROT_1:33;
  then (W-max L~ff)..ff > 1 by A135,SPRECT_5:22;
  then (N-min L~ff)..ff > 1 by A135,A136,SPRECT_5:23,XXREAL_0:2;
  then (N-max L~ff)..ff > 1 by A135,A136,SPRECT_5:24,XXREAL_0:2;
  then
A137: Emax..ff > 1 by A135,A136,SPRECT_5:25,XXREAL_0:2;
A138: now
    assume
A139: Gik..US <= 1;
    Gik..US >= 1 by A36,FINSEQ_4:21;
    then Gik..US = 1 by A139,XXREAL_0:1;
    then Gik = US/.1 by A36,FINSEQ_5:38;
    hence contradiction by A19,A23,JORDAN1F:5;
  end;
A140: Cage(C,n) is_sequence_on Ga by JORDAN9:def 1;
  then
A141: ff is_sequence_on Ga by REVROT_1:34;
A142: right_cell(godo,1,Ga)\L~godo c= RightComp godo by A92,A97,JORDAN9:27;
A143: L~godo = L~(go^'pion1) \/ L~co by A96,TOPREAL8:35
    .= L~go \/ L~pion1 \/ L~co by A94,TOPREAL8:35;
A144: L~Cage(C,n) = L~US \/ L~LS by JORDAN1E:13;
  then
A145: L~US c= L~Cage(C,n) by XBOOLE_1:7;
A146: L~LS c= L~Cage(C,n) by A144,XBOOLE_1:7;
A147: L~go c= L~Cage(C,n) by A48,A145;
A148: L~co c= L~Cage(C,n) by A55,A146;
A149: W-min C in C by SPRECT_1:13;
A150: L~pion = LSeg(Gik,Gij) by SPPOL_2:21;
A151: now
    assume W-min C in L~godo;
    then
A152: W-min C in L~go \/ L~pion1 or W-min C in L~co by A143,XBOOLE_0:def 3;
    per cases by A152,XBOOLE_0:def 3;
    suppose
      W-min C in L~go;
      then C meets L~Cage(C,n) by A147,A149,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
    suppose
      W-min C in L~pion1;
      hence contradiction by A8,A83,A133,A150,XBOOLE_0:3;
    end;
    suppose
      W-min C in L~co;
      then C meets L~Cage(C,n) by A148,A149,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
  end;
  right_cell(Rotate(Cage(C,n),Wmin),1) = right_cell(ff,1,GoB ff) by A88,
JORDAN1H:23
    .= right_cell(ff,1,GoB Cage(C,n)) by REVROT_1:28
    .= right_cell(ff,1,Ga) by JORDAN1H:44
    .= right_cell(ff-:Emax,1,Ga) by A137,A141,JORDAN1J:53
    .= right_cell(US,1,Ga) by JORDAN1E:def 1
    .= right_cell(R_Cut(US,Gik),1,Ga) by A36,A93,A138,JORDAN1J:52
    .= right_cell(go^'pion1,1,Ga) by A41,A95,JORDAN1J:51
    .= right_cell(godo,1,Ga) by A90,A97,JORDAN1J:51;
  then W-min C in right_cell(godo,1,Ga) by JORDAN1I:6;
  then
A153: W-min C in right_cell(godo,1,Ga)\L~godo by A151,XBOOLE_0:def 5;
A154: godo/.1 = (go^'pion1)/.1 by FINSEQ_6:155
    .= Wmin by A61,FINSEQ_6:155;
A155: len US >= 2 by A18,XXREAL_0:2;
A156: godo/.2 = (go^'pion1)/.2 by A89,FINSEQ_6:159
    .= US/.2 by A35,A77,FINSEQ_6:159
    .= (US^'LS)/.2 by A155,FINSEQ_6:159
    .= Rotate(Cage(C,n),Wmin)/.2 by JORDAN1E:11;
A157: L~go \/ L~co is compact by COMPTS_1:10;
  Wmin in L~go \/ L~co by A63,A78,XBOOLE_0:def 3;
  then
A158: W-min (L~go \/ L~co) = Wmin by A147,A148,A157,JORDAN1J:21,XBOOLE_1:8;
A159: (W-min (L~go \/ L~co))`1 = W-bound (L~go \/ L~co) by EUCLID:52;
A160: Wmin`1 = Wbo by EUCLID:52;
A161: Gij`1 <= Gik`1 by A1,A2,A3,A4,A5,SPRECT_3:13;
  then W-bound LSeg(Gik,Gij) = Gij`1 by SPRECT_1:54;
  then
A162: W-bound L~pion1 = Gij`1 by A83,SPPOL_2:21;
  Gij`1 >= Wbo by A9,A146,PSCOMP_1:24;
  then Gij`1 > Wbo by A76,XXREAL_0:1;
  then W-min (L~go\/L~co\/L~pion1) = W-min (L~go \/ L~co) by A157,A158,A159
,A160,A162,JORDAN1J:33;
  then
A163: W-min L~godo = Wmin by A143,A158,XBOOLE_1:4;
A164: rng godo c= L~godo by A89,A91,SPPOL_2:18,XXREAL_0:2;
  2 in dom godo by A92,FINSEQ_3:25;
  then
A165: godo/.2 in rng godo by PARTFUN2:2;
  godo/.2 in W-most L~Cage(C,n) by A156,JORDAN1I:25;
  then (godo/.2)`1 = (W-min L~godo)`1 by A163,PSCOMP_1:31
    .= W-bound L~godo by EUCLID:52;
  then godo/.2 in W-most L~godo by A164,A165,SPRECT_2:12;
  then Rotate(godo,W-min L~godo)/.2 in W-most L~godo by A154,A163,FINSEQ_6:89;
  then reconsider godo as clockwise_oriented non constant standard
  special_circular_sequence by JORDAN1I:25;
  len US in dom US by FINSEQ_5:6;
  then
A166: US.len US = US/.len US by PARTFUN1:def 6
    .= Emax by JORDAN1F:7;
A167: east_halfline E-max C misses L~go
  proof
    assume east_halfline E-max C meets L~go;
    then consider p be object such that
A168: p in east_halfline E-max C and
A169: p in L~go by XBOOLE_0:3;
    reconsider p as Point of TOP-REAL 2 by A168;
    p in L~US by A48,A169;
    then p in east_halfline E-max C /\ L~Cage(C,n) by A145,A168,XBOOLE_0:def 4;
    then
A170: p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
    then
A171: p = Emax by A48,A169,JORDAN1J:46;
    then Emax = Gik by A10,A166,A169,JORDAN1J:43;
    then Gik`1 = Ga*(len Ga,k)`1 by A3,A14,A170,A171,JORDAN1A:71;
    hence contradiction by A3,A17,A32,JORDAN1G:7;
  end;
  now
    assume east_halfline E-max C meets L~godo;
    then
A172: east_halfline E-max C meets (L~go \/ L~pion1) or east_halfline E-max
    C meets L~co by A143,XBOOLE_1:70;
    per cases by A172,XBOOLE_1:70;
    suppose
      east_halfline E-max C meets L~go;
      hence contradiction by A167;
    end;
    suppose
      east_halfline E-max C meets L~pion1;
      then consider p be object such that
A173: p in east_halfline E-max C and
A174: p in L~pion1 by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A173;
A175: p`2 = (E-max C)`2 by A173,TOPREAL1:def 11;
      k+1 <= len Ga by A3,NAT_1:13;
      then k+1-1 <= len Ga-1 by XREAL_1:9;
      then
A176: k <= len Ga-'1 by XREAL_0:def 2;
      len Ga-'1 <= len Ga by NAT_D:35;
      then
A177: Gik`1 <= Ga*(len Ga-'1,1)`1 by A4,A5,A11,A14,A21,A176,JORDAN1A:18;
      p`1 <= Gik`1 by A83,A150,A161,A174,TOPREAL1:3;
      then p`1 <= Ga*(len Ga-'1,1)`1 by A177,XXREAL_0:2;
      then p`1 <= E-bound C by A21,JORDAN8:12;
      then
A178: p`1 <= (E-max C)`1 by EUCLID:52;
      p`1 >= (E-max C)`1 by A173,TOPREAL1:def 11;
      then p`1 = (E-max C)`1 by A178,XXREAL_0:1;
      then p = E-max C by A175,TOPREAL3:6;
      hence contradiction by A8,A83,A134,A150,A174,XBOOLE_0:3;
    end;
    suppose
      east_halfline E-max C meets L~co;
      then consider p be object such that
A179: p in east_halfline E-max C and
A180: p in L~co by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A179;
A181: p in LSeg(co,Index(p,co)) by A180,JORDAN3:9;
      consider t be Nat such that
A182: t in dom LS and
A183: LS.t = Gij by A39,FINSEQ_2:10;
      1 <= t by A182,FINSEQ_3:25;
      then
A184: 1 < t by A34,A183,XXREAL_0:1;
      t <= len LS by A182,FINSEQ_3:25;
      then Index(Gij,LS)+1 = t by A183,A184,JORDAN3:12;
      then
A185: len L_Cut(LS,Gij) = len LS-Index(Gij,LS) by A9,A183,JORDAN3:26;
      Index(p,co) < len co by A180,JORDAN3:8;
      then Index(p,co) < len LS-'Index(Gij,LS) by A185,XREAL_0:def 2;
      then Index(p,co)+1 <= len LS-'Index(Gij,LS) by NAT_1:13;
      then
A186: Index(p,co) <= len LS-'Index(Gij,LS)-1 by XREAL_1:19;
A187: co = mid(LS,Gij..LS,len LS) by A39,JORDAN1J:37;
      p in L~LS by A55,A180;
      then p in east_halfline E-max C /\ L~Cage(C,n) by A146,A179,
XBOOLE_0:def 4;
      then
A188: p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
A189: Index(Gij,LS)+1 = Gij..LS by A34,A39,JORDAN1J:56;
      0+Index(Gij,LS) < len LS by A9,JORDAN3:8;
      then len LS-Index(Gij,LS) > 0 by XREAL_1:20;
      then Index(p,co) <= len LS-Index(Gij,LS)-1 by A186,XREAL_0:def 2;
      then Index(p,co) <= len LS-Gij..LS by A189;
      then Index(p,co) <= len LS-'Gij..LS by XREAL_0:def 2;
      then
A190: Index(p,co) < len LS-'(Gij..LS)+1 by NAT_1:13;
A191: 1<=Index(p,co) by A180,JORDAN3:8;
A192: Gij..LS<=len LS by A39,FINSEQ_4:21;
      Gij..LS <> len LS by A31,A39,FINSEQ_4:19;
      then
A193: Gij..LS < len LS by A192,XXREAL_0:1;
A194: 1+1 <= len LS by A25,XXREAL_0:2;
      then
A195: 2 in dom LS by FINSEQ_3:25;
      set tt = Index(p,co)+(Gij..LS)-'1;
      set RC = Rotate(Cage(C,n),Emax);
A196: E-max C in right_cell(RC,1) by JORDAN1I:7;
A197: GoB RC = GoB Cage(C,n) by REVROT_1:28
        .= Ga by JORDAN1H:44;
A198: L~RC = L~Cage(C,n) by REVROT_1:33;
      consider jj2 be Nat such that
A199: 1 <= jj2 and
A200: jj2 <= width Ga and
A201: Emax = Ga*(len Ga,jj2) by JORDAN1D:25;
A202: len Ga >= 4 by JORDAN8:10;
      then len Ga >= 1 by XXREAL_0:2;
      then
A203: [len Ga,jj2] in Indices Ga by A199,A200,MATRIX_0:30;
A204: len RC = len Cage(C,n) by FINSEQ_6:179;
      LS = RC-:Wmin by JORDAN1G:18;
      then
A205: LSeg(LS,1) = LSeg(RC,1) by A194,SPPOL_2:9;
A206: Emax in rng Cage(C,n) by SPRECT_2:46;
      RC is_sequence_on Ga by A140,REVROT_1:34;
      then consider ii,jj be Nat such that
A207: [ii,jj+1] in Indices Ga and
A208: [ii,jj] in Indices Ga and
A209: RC/.1 = Ga*(ii,jj+1) and
A210: RC/.(1+1) = Ga*(ii,jj) by A87,A198,A204,A206,FINSEQ_6:92,JORDAN1I:23;
A211: jj+1+1 <> jj;
A212: 1 <= jj by A208,MATRIX_0:32;
      RC/.1 = E-max L~RC by A198,A206,FINSEQ_6:92;
      then
A213: ii = len Ga by A198,A207,A209,A201,A203,GOBOARD1:5;
      then ii-1 >= 4-1 by A202,XREAL_1:9;
      then
A214: ii-1 >= 1 by XXREAL_0:2;
      then
A215: 1 <= ii-'1 by XREAL_0:def 2;
A216: jj <= width Ga by A208,MATRIX_0:32;
      then
A217: Ga*(len Ga,jj)`1 = Ebo by A11,A212,JORDAN1A:71;
A218: jj+1 <= width Ga by A207,MATRIX_0:32;
      ii+1 <> ii;
      then
A219: right_cell(RC,1) = cell(Ga,ii-'1,jj) by A87,A204,A197,A207,A208,A209,A210
,A211,GOBOARD5:def 6;
A220: ii <= len Ga by A208,MATRIX_0:32;
A221: 1 <= ii by A208,MATRIX_0:32;
A222: ii <= len Ga by A207,MATRIX_0:32;
A223: 1 <= jj+1 by A207,MATRIX_0:32;
      then
A224: Ebo = Ga*(len Ga,jj+1)`1 by A11,A218,JORDAN1A:71;
A225: 1 <= ii by A207,MATRIX_0:32;
      then
A226: ii-'1+1 = ii by XREAL_1:235;
      then
A227: ii-'1 < len Ga by A222,NAT_1:13;
      then
A228: Ga*(ii-'1,jj+1)`2 = Ga*(1,jj+1)`2 by A223,A218,A215,GOBOARD5:1
        .= Ga*(ii,jj+1)`2 by A225,A222,A223,A218,GOBOARD5:1;
A229: (E-max C)`2 = p`2 by A179,TOPREAL1:def 11;
      then
A230: p`2 <= Ga*(ii-'1,jj+1)`2 by A196,A222,A218,A212,A219,A226,A214,JORDAN9:17
;
A231: Ga*(ii-'1,jj)`2 = Ga*(1,jj)`2 by A212,A216,A215,A227,GOBOARD5:1
        .= Ga*(ii,jj)`2 by A221,A220,A212,A216,GOBOARD5:1;
      Ga*(ii-'1,jj)`2 <= p`2 by A229,A196,A222,A218,A212,A219,A226,A214,
JORDAN9:17;
      then p in LSeg(RC/.1,RC/.(1+1)) by A188,A209,A210,A213,A230,A231,A228
,A217,A224,GOBOARD7:7;
      then
A232: p in LSeg(LS,1) by A87,A205,A204,TOPREAL1:def 3;
      1<=Gij..LS by A39,FINSEQ_4:21;
      then
A233: LSeg(mid(LS,Gij..LS,len LS),Index(p,co)) = LSeg(LS,Index(p,co)+(
      Gij..LS)-'1) by A193,A191,A190,JORDAN4:19;
      1<=Index(Gij,LS) by A9,JORDAN3:8;
      then
A234: 1+1 <= Gij..LS by A189,XREAL_1:7;
      then Index(p,co)+Gij..LS >= 1+1+1 by A191,XREAL_1:7;
      then Index(p,co)+Gij..LS-1 >= 1+1+1-1 by XREAL_1:9;
      then
A235: tt >= 1+1 by XREAL_0:def 2;
      now
        per cases by A235,XXREAL_0:1;
        suppose
          tt > 1+1;
          then LSeg(LS,1) misses LSeg(LS,tt) by TOPREAL1:def 7;
          hence contradiction by A232,A181,A187,A233,XBOOLE_0:3;
        end;
        suppose
A236:     tt = 1+1;
          then 1+1 = Index(p,co)+(Gij..LS)-1 by XREAL_0:def 2;
          then 1+1+1 = Index(p,co)+(Gij..LS);
          then
A237:     Gij..LS = 2 by A191,A234,JORDAN1E:6;
          LSeg(LS,1) /\ LSeg(LS,tt) = {LS/.2} by A25,A236,TOPREAL1:def 6;
          then p in {LS/.2} by A232,A181,A187,A233,XBOOLE_0:def 4;
          then
A238:     p = LS/.2 by TARSKI:def 1;
          then
A239:     p in rng LS by A195,PARTFUN2:2;
          p..LS = 2 by A195,A238,FINSEQ_5:41;
          then p = Gij by A39,A237,A239,FINSEQ_5:9;
          then Gij`1 = Ebo by A238,JORDAN1G:32;
          then Gij`1 = Ga*(len Ga,j)`1 by A1,A11,A13,JORDAN1A:71;
          hence contradiction by A2,A3,A16,A69,JORDAN1G:7;
        end;
      end;
      hence contradiction;
    end;
  end;
  then east_halfline E-max C c= (L~godo)` by SUBSET_1:23;
  then consider W be Subset of TOP-REAL 2 such that
A240: W is_a_component_of (L~godo)` and
A241: east_halfline E-max C c= W by GOBOARD9:3;
  W is not bounded by A241,JORDAN2C:121,RLTOPSP1:42;
  then W is_outside_component_of L~godo by A240,JORDAN2C:def 3;
  then W c= UBD L~godo by JORDAN2C:23;
  then
A242: east_halfline E-max C c= UBD L~godo by A241;
  E-max C in east_halfline E-max C by TOPREAL1:38;
  then E-max C in UBD L~godo by A242;
  then E-max C in LeftComp godo by GOBRD14:36;
  then LA meets L~godo by A132,A133,A134,A142,A153,JORDAN1J:36;
  then
A243: LA meets (L~go \/ L~pion1) or LA meets L~co by A143,XBOOLE_1:70;
A244: LA c= C by JORDAN6:61;
  per cases by A243,XBOOLE_1:70;
  suppose
    LA meets L~go;
    then LA meets L~Cage(C,n) by A48,A145,XBOOLE_1:1,63;
    hence contradiction by A244,JORDAN10:5,XBOOLE_1:63;
  end;
  suppose
    LA meets L~pion1;
    hence contradiction by A8,A83,A150;
  end;
  suppose
    LA meets L~co;
    then LA meets L~Cage(C,n) by A55,A146,XBOOLE_1:1,63;
    hence contradiction by A244,JORDAN10:5,XBOOLE_1:63;
  end;
end;
