reserve m,k,j,j1,i,i1,i2,n for Nat,
  r,s for Real,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p for Point of TOP-REAL 2;

theorem Th28:
  for G being Go-board st 1 <= i & i <= len G holds SgmX(RealOrd,
  proj1.:Values G).i = G*(i,1)`1
proof
  let G be Go-board;
  assume 1 <= i & i <= len G;
  then i in dom G by FINSEQ_3:25;
  then
A1: i in Seg len G by FINSEQ_1:def 3;
  0 <> width G by MATRIX_0:def 10;
  then
A2: 1 <= width G by NAT_1:14;
  reconsider A = proj1.:Values G as finite Subset of REAL;
  deffunc F(Nat)=In(G*($1,1)`1,REAL);
  consider f being FinSequence of REAL such that
A3: len f = len G and
A4: for i be Nat st i in dom f holds f.i = F(i) from FINSEQ_2:sch 1;
A5: dom f = Seg len G by A3,FINSEQ_1:def 3;
A6: rng f = A
  proof
A7: Values G = { G*(m,n): [m,n] in Indices G } by MATRIX_0:39;
    thus rng f c= A
    proof
      let x be object;
      assume
A8:   x in rng f;
      then reconsider x as Element of REAL;
      consider y being object such that
A9:   y in dom f and
A10:  x = f.y by A8,FUNCT_1:def 3;
      reconsider y as Nat by A9;
      1 <= y & y <= len G by A3,A9,FINSEQ_3:25;
      then [y,1] in Indices G by A2,MATRIX_0:30;
      then
A11:  G*(y,1) in Values G by A7;
      x = F(y) by A4,A9,A10
        .= proj1.(G*(y,1)) by PSCOMP_1:def 5;
      hence thesis by A11,FUNCT_2:35;
    end;
    let x be object;
    assume
A12: x in A;
    then reconsider x as Element of REAL;
    consider p being Element of TOP-REAL 2 such that
A13: p in Values G and
A14: x = proj1.p by A12,FUNCT_2:65;
    consider m,n such that
A15: p = G*(m,n) and
A16: [m,n] in Indices G by A7,A13;
A17: 1 <= n & n <= width G by A16,MATRIX_0:32;
A18: 1 <= m & m <= len G by A16,MATRIX_0:32;
    then
A19: m in Seg len G by FINSEQ_1:1;
A20: m in dom f by A3,A18,FINSEQ_3:25;
    x = p`1 by A14,PSCOMP_1:def 5
      .= F(m) by A15,A17,A18,GOBOARD5:2
      .= f.m by A4,A5,A19;
    hence thesis by A20,FUNCT_1:def 3;
  end;
  for n,m be Nat st n in dom f & m in dom f & n < m holds f/.n
  <> f/.m & [f/.n, f/.m] in RealOrd
  proof
    let n,m be Nat such that
A21: n in dom f & m in dom f and
A22: n < m;
A23: 1 <= n & m <= len G by A3,A21,FINSEQ_3:25;
    reconsider n9=n,m9=m as Nat;
A24: f/.n = f.n & f/.m = f.m by A21,PARTFUN1:def 6;
A25: f.n = F(n9) & f.m = F(m9) by A4,A21;
    hence f/.n <> f/.m by A2,A22,A23,A24,GOBOARD5:3;
    f.n9 < f.m9 by A2,A22,A25,A23,GOBOARD5:3;
    hence thesis by A24;
  end;
  then f = SgmX(RealOrd, proj1.:Values G) by A6,PRE_POLY:9;
  then  SgmX(RealOrd, proj1.:Values G).i = F(i) by A4,A5,A1;
  hence thesis;
end;
