reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;
reserve C for compact non vertical non horizontal non empty Subset of TOP-REAL
  2,
  l, m, i1, i2, j1, j2 for Nat;

theorem Th28:
  for n being Nat ex i st 1 <= i & i+1 <= len Gauge(C,n) & N-min C
  in cell(Gauge(C,n),i,width Gauge(C,n)-'1) & N-min C <> Gauge(C,n)*(i,width
  Gauge(C,n)-'1)
proof
  let n be Nat;
  set G = Gauge(C,n);
  defpred P[Nat] means 1 <= $1 & $1 < len G & G*($1,(width G)-'1)`1 < (N-min C
  )`1;
A1: for k be Nat st P[k] holds k <= len G;
A2: len G = width G by JORDAN8:def 1;
  (NW-corner C)`1 <= (N-min C)`1 by PSCOMP_1:38;
  then
A3: W-bound C <= (N-min C)`1 by EUCLID:52;
A4: len G >= 4 by JORDAN8:10;
  then
A5: (len G)-'1 <= len G & 2 <= len G by NAT_D:35,XXREAL_0:2;
A6: 1 < len G by A4,XXREAL_0:2;
  then
A7: 1 <= (len G)-'1 by NAT_D:49;
A8: n in NAT & len G = width G by JORDAN8:def 1,ORDINAL1:def 12;
  then G*(2,(width G)-'1)`1 = W-bound C by A7,JORDAN8:11,NAT_D:35;
  then G*(1,(width G)-'1)`1 < W-bound C by A2,A7,A5,GOBOARD5:3;
  then G*(1,(width G)-'1)`1 < (N-min C)`1 by A3,XXREAL_0:2;
  then
A9: ex k be Nat st P[k] by A6;
  ex i being Nat st P[i] & for n be Nat st P[n] holds n <= i from NAT_1:
  sch 6(A1,A9);
  then consider i being Nat such that
A10: 1 <= i and
A11: i < len G and
A12: G*(i,(width G)-'1)`1 < (N-min C)`1 and
A13: for n be Nat st P[n] holds n <= i;
  reconsider i as Nat;
A14: 1 <= i+1 & i < i+1 by NAT_1:12,13;
A15: (N-min C)`2 = N-bound C by EUCLID:52;
A16: i+1 <= len G by A11,NAT_1:13;
  then
A17: (N-min C)`2 = G* (i+1,(width G)-'1)`2 by A8,A15,JORDAN8:14,NAT_1:12;
  now
    assume i+1 = len G;
    then len G-'1 = i by NAT_D:34;
    then
A18: G*(i,(width G)-'1)`1 = E-bound C by A8,A7,JORDAN8:12,NAT_D:35;
    (NE-corner C)`1 >= (N-min C)`1 by PSCOMP_1:38;
    hence contradiction by A12,A18,EUCLID:52;
  end;
  then i+1 < len G by A16,XXREAL_0:1;
  then
A19: (N-min C)`1 <= G*(i+1,(width G)-'1)`1 by A13,A14;
  G*(i,(width G)-'1)`2 = (N-min C)`2 by A8,A10,A11,A15,JORDAN8:14;
  then
A20: N-min C in LSeg(G*(i,(width G)-'1),G*(i+1,(width G)-'1)) by A12,A17,A19,
GOBOARD7:8;
  take i;
  thus 1 <= i & i+1 <= len G by A10,A11,NAT_1:13;
  LSeg(G*(i,(width G)-'1),G*(i+1,(width G)-'1)) c= cell(G,i,(width G)-'1)
  by A2,A7,A10,A11,GOBOARD5:22,NAT_D:35;
  hence N-min C in cell(G,i,(width G)-'1) by A20;
  thus thesis by A12;
end;
