reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th28:
  for p,i st len f=n & i in Seg n holds mlt(Line(
  Matrix_of_Cofactor M,i),f) = LaplaceExpL(RLine(M,i,f),i)
proof
  let p,i such that
A1: len f=n and
A2: i in Seg n;
  reconsider N=n as Element of NAT by ORDINAL1:def 12;
  set KK=the carrier of K;
  set C=Matrix_of_Cofactor M;
  reconsider Tp=f,TL=Line(C,i) as Element of N-tuples_on KK by A1,FINSEQ_2:92
,MATRIX_0:24;
  set R=RLine(M,i,f);
  set LL=LaplaceExpL(R,i);
  set MLT=mlt(TL,Tp);
A3: len LL=n by Def7;
A4: now
A5: dom LL=Seg n by A3,FINSEQ_1:def 3;
A6: n=width M by MATRIX_0:24;
    let j be Nat such that
A7: 1<=j and
A8: j<=n;
A9: j in Seg n by A7,A8;
    n=width C by MATRIX_0:24;
    then
A10: Line(C,i).j=C*(i,j) by A9,MATRIX_0:def 7;
    Indices M=[:Seg n,Seg n:] by MATRIX_0:24;
    then [i,j] in Indices M by A2,A9,ZFMISC_1:87;
    then
A11: R*(i,j)=f.j by A1,A6,MATRIX11:def 3;
    Indices C=[:Seg n,Seg n:] by MATRIX_0:24;
    then [i,j] in Indices C by A2,A9,ZFMISC_1:87;
    then Line(C,i).j=Cofactor(M,i,j) by A10,Def6;
    then
A12: MLT.j=Cofactor(M,i,j)*(R*(i,j)) by A9,A11,FVSUM_1:61;
    Cofactor(M,i,j)=Cofactor(R,i,j) by A2,A9,Th15;
    hence MLT.j=LL.j by A9,A5,A12,Def7;
  end;
  len MLT=n by CARD_1:def 7;
  hence thesis by A3,A4;
end;
