 reserve W for WA-Lattice;
 reserve a,b,c for Element of W;
 reserve W for pcs-Compatible pcs-tol-reflexive pcs-tol-symmetric WAP-Lattice;
 reserve a,b for Element of W;
 reserve L for WA_Lattice;

theorem Th32:
  dom LatOrder L = the carrier of L &
    rng LatOrder L = the carrier of L &
    field LatOrder L = the carrier of L
  proof
    now
      let x be object;
      thus x in the carrier of L implies
      ex y being object st [x,y] in LatOrder L
      proof
        assume x in the carrier of L;
        then reconsider p = x as Element of L;
        [p,p] in LatOrder L by Idem2;
        hence thesis;
      end;
      given y being object such that
A1:   [x,y] in LatOrder L;
      consider p,q being Element of L such that
A2:   [x,y] = [p,q] and
      p [= q by A1;
      x = p by A2,XTUPLE_0:1;
      hence x in the carrier of L;
    end;
    hence
A3: dom LatOrder L = the carrier of L by XTUPLE_0:def 12;
T1: now
      let x be object;
      thus x in the carrier of L implies
        ex y being object st [y,x] in LatOrder L
      proof
        assume x in the carrier of L;
        then reconsider p = x as Element of L;
        [p,p] in LatOrder L by Idem2;
        hence thesis;
      end;
      given y being object such that
A4:   [y,x] in LatOrder L;
      consider p,q being Element of L such that
A5:   [y,x] = [p,q] and
      p [= q by A4;
      x = q by A5,XTUPLE_0:1;
      hence x in the carrier of L;
    end;
    hence rng LatOrder L = the carrier of L by XTUPLE_0:def 13;
    thus field LatOrder L = (the carrier of L) \/ the carrier of L
      by A3,XTUPLE_0:def 13,T1
      .= the carrier of L;
  end;
