reserve

  k,n,m,i,j for Element of NAT,
  K for Field;
reserve L for non empty addLoopStr;
reserve G for non empty multLoopStr;

theorem
  for A being Matrix of n,K holds A=0.(K,n) iff for i,j being Element of
  NAT st 1<=i & i<=n & 1<=j & j<=n holds A*(i,j)=0.K
proof
  let A be Matrix of n,K;
  thus A=0.(K,n) implies for i,j being Element of NAT st 1<=i & i<=n & 1<=j &
  j<=n holds A*(i,j)=0.K
  proof
    set A2=0.(K,n),B2=0.(K,n);
    set A3=0.(K,n,n);
    assume
A1: A=0.(K,n);
    let i,j be Element of NAT;
    assume 1<=i & i<=n & 1<=j & j<=n;
    then [i,j] in Indices A2 by MATRIX_0:31;
    then A3=A2 & (A2+B2)*(i,j)=A2*(i,j)+B2*(i,j) by MATRIX_3:def 1,def 3;
    then A2*(i,j)=A2*(i,j)+A2*(i,j) by MATRIX_3:4;
    then A2*(i,j) - A2*(i,j) = A2*(i,j) +(A2*(i,j) - A2*(i,j)) by RLVECT_1:28
      .=A2*(i,j) +0.K by RLVECT_1:15
      .=A2*(i,j) by RLVECT_1:4;
    hence thesis by A1,RLVECT_1:15;
  end;
A2: len A=n by MATRIX_0:24;
A3: Indices A=[: Seg n,Seg n :] by MATRIX_0:24;
A4: width A=n by MATRIX_0:24;
  assume
A5: for i,j being Element of NAT st 1<=i & i<=n & 1<=j & j<=n holds A*(i
  ,j)=0.K;
  for i,j being Nat st [i,j] in Indices A holds A*(i,j) = A*(i,j) + A*(i, j)
  proof
    let i,j be Nat;
    reconsider i0=i,j0=j as Element of NAT by ORDINAL1:def 12;
    assume
A6: [i,j] in Indices A;
    then j in Seg n by A4,ZFMISC_1:87;
    then
A7: 1<=j & j<=n by FINSEQ_1:1;
    i in Seg n by A3,A6,ZFMISC_1:87;
    then 1<=i & i<=n by FINSEQ_1:1;
    then A*(i0,j0)=0.K by A5,A7;
    hence thesis by RLVECT_1:4;
  end;
  then A=A+A by A2,MATRIX_3:def 3;
  then A = 0.(K,len A,width A) by MATRIX_4:6;
  hence thesis by A2,A4,MATRIX_3:def 1;
end;
