reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);
reserve D for non empty set,
  bD for FinSequence of D,
  b,f,g for FinSequence of K,
  MD for Matrix of D;

theorem Th28:
  len f = len g implies (ColVec2Mx f) + (ColVec2Mx g) = ColVec2Mx (f + g)
proof
  set Cf=ColVec2Mx f;
  set Cg=ColVec2Mx g;
A1: len Cf=len f by MATRIX_0:def 2;
  assume
A2: len f = len g;
  then reconsider F=f,G=g as Element of (len f)-tuples_on the carrier of K by
FINSEQ_2:92;
A3: len Cg=len f by A2,MATRIX_0:def 2;
  set FG=F+G;
  set Cfg=ColVec2Mx FG;
A4: len Cfg=len FG by MATRIX_0:def 2;
A5: len FG=len f & width (Cf+Cg)=width Cf by CARD_1:def 7,MATRIX_3:def 3;
A6: len (Cf+Cg)=len Cf by MATRIX_3:def 3;
  per cases;
  suppose
A7: len f=0;
    then Cf+Cg={} by A6,MATRIX_0:def 2;
    hence thesis by A4,A7;
  end;
  suppose
A8: len f>0; then
A10: width Cf= 1 by MATRIX_0:23; then
    1 in Seg width Cf;
    then Col(Cf+Cg,1) = Col(Cf,1)+Col(Cg,1) by A1,A3,MATRIX_4:60
      .= f+Col(Cg,1) by A8,Th26
      .= f+g by A2,A8,Th26;
    hence thesis by A5,A8,A10,Th26;
  end;
end;
