reserve X for non empty set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S,
  F,G for Functional_Sequence of X,ExtREAL,
  I for ExtREAL_sequence,
  f,g for PartFunc of X,ExtREAL,
  seq, seq1, seq2 for ExtREAL_sequence,
  p for ExtReal,
  n,m for Nat,
  x for Element of X,
  z,D for set;

theorem Th28:
  F is additive implies dom((Partial_Sums F).n) = meet{dom(F.k)
  where k is Element of NAT : k <= n}
proof
  deffunc DOM1(Nat) = {dom(F.k) where k is Element of NAT : k <= $1};
  set PF = Partial_Sums F;
  defpred P[Nat] means dom(PF.$1) = meet {dom(F.k) where k is Element of NAT :
  k <= $1};
A1: dom(PF.0) = dom(F.0) by Def4;
  now
    let V be object;
    assume V in DOM1(0);
    then consider k be Element of NAT such that
A2: V = dom(F.k) and
A3: k <= 0;
    k = 0 by A3;
    hence V in {dom(F.0)} by A2,TARSKI:def 1;
  end;
  then
A4: DOM1(0) c= {dom(F.0)};
  assume
A5: F is additive;
A6: for m be Nat st P[m] holds P[m+1]
  proof
    let m be Nat;
A7: PF.(m+1) = PF.m + F.(m+1) by Def4;
A8: (PF.m)"{+infty} /\ (F.(m+1))"{-infty} = {} by A5,Th27;
A9: dom(F.0) in DOM1(m+1);
    now
      let V be object;
      assume
A10:  V in meet DOM1(m) /\ dom(F.(m+1));
      then
A11:  V in dom(F.(m+1)) by XBOOLE_0:def 4;
A12:  V in meet DOM1(m) by A10,XBOOLE_0:def 4;
      for W be set holds W in DOM1(m+1) implies V in W
      proof
        let W be set;
        assume W in DOM1(m+1);
        then consider i be Element of NAT such that
A13:    W = dom(F.i) and
A14:    i <= m+1;
        now
          assume i <= m;
          then W in DOM1(m) by A13;
          hence thesis by A12,SETFAM_1:def 1;
        end;
        hence thesis by A11,A13,A14,NAT_1:8;
      end;
      hence V in meet DOM1(m+1) by A9,SETFAM_1:def 1;
    end;
    then
A15: meet DOM1(m) /\ dom(F.(m+1)) c= meet DOM1(m+1);
A16: dom(F.0) in DOM1(m);
    now
      now
        let V be object;
        assume V in DOM1(m);
        then consider i be Element of NAT such that
A17:    V = dom(F.i) and
A18:    i <= m;
        i <= m+1 by A18,NAT_1:12;
        hence V in DOM1(m+1) by A17;
      end;
      then DOM1(m) c= DOM1(m+1);
      then
A19:  meet DOM1(m+1) c= meet DOM1(m) by A16,SETFAM_1:6;
      let V be object;
      assume
A20:  V in meet DOM1(m+1);
      dom(F.(m+1)) in DOM1(m+1);
      then V in dom(F.(m+1)) by A20,SETFAM_1:def 1;
      hence V in meet DOM1(m) /\ dom(F.(m+1)) by A20,A19,XBOOLE_0:def 4;
    end;
    then
A21: meet DOM1(m+1) c= meet DOM1(m) /\ dom(F.(m+1));
    (PF.m)"{-infty} /\ (F.(m+1))"{+infty} = {} by A5,Th27;
    then
A22: dom(PF.(m+1)) = (dom(PF.m)/\dom(F.(m+1))) \ ({}\/{}) by A8,A7,
MESFUNC1:def 3;
    assume P[m];
    hence thesis by A22,A21,A15,XBOOLE_0:def 10;
  end;
  now
    let V be object;
    assume V in {dom(F.0)};
    then V = dom(F.0) by TARSKI:def 1;
    hence V in DOM1(0);
  end;
  then {dom(F.0)} c= DOM1(0);
  then DOM1(0) = {dom(F.0)} by A4,XBOOLE_0:def 10;
  then
A23: P[ 0 ] by A1,SETFAM_1:10;
  for k be Nat holds P[k] from NAT_1:sch 2(A23,A6);
  hence thesis;
end;
