reserve A,B,C for non empty set,
  f for Function of [:A,B:],C;
reserve K for non empty doubleLoopStr;
reserve V for non empty ModuleStr over K;
reserve W for non empty RightModStr over K;
reserve J for Function of K,K;
reserve K,L for Ring;
reserve J for Function of K,L;
reserve x,y for Scalar of K;
reserve K,L for add-associative right_zeroed right_complementable non empty
  doubleLoopStr;
reserve J for Function of K,L;
reserve K for add-associative right_zeroed right_complementable non empty
  doubleLoopStr;
reserve L for add-associative right_zeroed right_complementable well-unital
  non empty doubleLoopStr;
reserve J for Function of K,L;

theorem Th27:
  J is linear iff opp(J) is antilinear
proof
  set J9 = opp(J), L9 = opp(L);
A1: now
    assume A2: J is linear;
A3: for x,y being Scalar of K holds J9.(x*y) = J9.y*J9.x
    proof
      let x,y be Scalar of K;
      thus J9.(x*y) = J.x*J.y by A2,GROUP_6:def 6
        .= J9.y*J9.x by Lm3;
    end;
    J9.(1_K) = 1_L by A2,GROUP_1:def 13
      .= 1_L9;
    then J9 is additive antimultiplicative unity-preserving by Lm12,A3,A2;
    hence J9 is antilinear;
  end;
  now
    assume
A4: J9 is antilinear;
A5: for x,y being Scalar of K holds J.(x+y) = J.x+J.y
    proof
      let x,y be Scalar of K;
      thus J.(x+y) = J9.x+J9.y by A4,VECTSP_1:def 20
        .= J.x+J.y;
    end;
A6: for x,y being Scalar of K holds J.(x*y) = J.x*J.y
    proof
      let x,y be Scalar of K;
      thus J.(x*y) = J9.y*J9.x by A4,Def6
        .= J.x*J.y by Lm3;
    end;
    J.(1_K) = 1_L9 by A4,GROUP_1:def 13
      .= 1_L;
    then J is additive multiplicative unity-preserving by A5,A6;
    hence J is linear;
  end;
  hence thesis by A1;
end;
