reserve S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem LM150:
  for f be PartFunc of T, W,
  I be LinearOperator of S, T
  st I is one-to-one onto &
  I is isometric holds
  for x be Point of S holds
  f*I is_differentiable_in x iff f is_differentiable_in I.x
  proof
    let f be PartFunc of T, W,
    I be LinearOperator of S, T;
    assume that
    AS2: I is one-to-one onto and
    AS3: I is isometric;
    P0: dom I = the carrier of S by FUNCT_2:def 1;
    set g = f*I;
    let x be Point of S;
    hereby
      assume P1: g is_differentiable_in x;
      consider J be LinearOperator of T, S such that
      P2: J = I" & J is one-to-one onto isometric by LM020,AS2,AS3;
      Q4: J is_differentiable_in I.x by LM090,P2;
      P3: J.(I.x) = x by AS2,P2,P0,FUNCT_1:34;
      g*J = f*(I*I") by P2,RELAT_1:36
      .= f*id (the carrier of T) by AS2,FUNCT_2:29
      .= f by FUNCT_2:17;
      hence f is_differentiable_in I.x by NDIFF_2:13,P3,P1,Q4;
    end;
    assume P2: f is_differentiable_in I.x;
     I is Lipschitzian LinearOperator of S, T by AS3;
    then
    reconsider I0 = I as Point of R_NormSpace_of_BoundedLinearOperators(S,T)
    by LOPBAN_1:def 9;
    I0 = I;
    hence thesis by P2,LM120,AS3;
  end;
