reserve X for set;
reserve a,b,c,k,m,n for Nat;
reserve i for Integer;
reserve r for Real;
reserve p for Prime;

theorem
  {n where n is Nat: 13 divides 2|^n-3} is infinite
  proof
    set A = {n where n is Nat: 13 divides 2|^n-3};
    deffunc F(Nat) = 12*$1+4;
    consider f being ManySortedSet of NAT such that
A1: for d being Element of NAT holds f.d = F(d) from PBOOLE:sch 5;
A2: dom f = NAT by PARTFUN1:def 2;
A3: rng f c= A
    proof
      let y be object;
      assume y in rng f;
      then consider k being object such that
A4:   k in dom f and
A5:   f.k = y by FUNCT_1:def 3;
      reconsider k as Element of NAT by A4,PARTFUN1:def 2;
A6:   2|^(12*k),1 are_congruent_mod 13 by Th8;
A7:   2|^(12*k)*2|^4 = 2|^(12*k+4) by NEWTON:8;
      16,3 are_congruent_mod 13;
      then 2|^(12*k)*2|^4,1*3 are_congruent_mod 13 by A6,Lm4,INT_1:18;
      then F(k) in A by A7;
      hence thesis by A1,A5;
    end;
    f is one-to-one
    proof
      let x1,x2 be object such that
A8:   x1 in dom f & x2 in dom f and
A9:   f.x1 = f.x2;
      reconsider x1,x2 as Element of NAT by A8,PARTFUN1:def 2;
      f.x1 = F(x1) & f.x2 = F(x2) by A1;
      then 12*x1+4 = 12*x2+4 by A9;
      hence thesis;
    end;
    hence thesis by A2,A3,CARD_1:59;
  end;
