reserve a,b,c,h for Integer;
reserve k,m,n for Nat;
reserve i,j,z for Integer;
reserve p for Prime;

theorem Th28:
  for a1,a2 being Integer
  for n1,n2 being Nat st n1,n2 are_coprime & n1 > 0 & n2 > 0 holds
  { x where x is positive Nat: x solves_CRT a1,n1,a2,n2 } is infinite
  proof
    let a1,a2 be Integer;
    let n1,n2 be Nat such that
A1: n1,n2 are_coprime and
A2: n1 > 0 & n2 > 0;
    set X = { x where x is positive Nat: x solves_CRT a1,n1,a2,n2 };
    CRT(a1,n1,a2,n2) solves_CRT a1,n1,a2,n2 by A1,A2,Def2;
    then CRT(a1,n1,a2,n2) + 1*n1*n2 solves_CRT a1,n1,a2,n2 by Th26;
    then
A3: CRT(a1,n1,a2,n2) + n1*n2 in X by A2;
A4: X is natural-membered
    proof
      let a be object;
      assume a in X;
      then ex x being positive Nat st a = x & x solves_CRT a1,n1,a2,n2;
      hence thesis;
    end;
    for a being Nat st a in X ex b being Nat st b > a & b in X
    proof
      let a be Nat;
      assume a in X;
      then consider x being positive Nat such that
A5:   a = x and
A6:   x solves_CRT a1,n1,a2,n2;
      take b = x + 1*n1*n2;
      x + n1*n2 > x + 0 by A2,XREAL_1:8;
      hence b > a by A5;
      b solves_CRT a1,n1,a2,n2 by A6,Th26;
      hence b in X;
    end;
    hence thesis by A3,A4,NUMBER04:1;
  end;
