
theorem
  for I being finite non empty set for A being PLS-yielding
ManySortedSet of I st for i being Element of I holds A.i is strongly_connected
  for f being Collineation of Segre_Product A ex s being Permutation of I, B
being Function-yielding ManySortedSet of I st for i being Element of I holds (B
  .i is Function of A.i,A.(s.i) & for m being Function of A.i,A.(s.i) st m=B.i
  holds m is isomorphic) & for p being Point of Segre_Product A for a being
  ManySortedSet of I st a=p for b being ManySortedSet of I st b=f.p for m being
  Function of A.i,A.(s.i) st m=B.i holds b.(s.i)=m.(a.i)
proof
  let I be finite non empty set;
  let A be PLS-yielding ManySortedSet of I such that
A1: for i being Element of I holds A.i is strongly_connected;
  let f be Collineation of Segre_Product A;
  set s=permutation_of_indices(f);
  take s;
  defpred P[object,object] means
    for i being Element of I st i=$1 holds $2= canonical_embedding(f,i);
A2: for i being object st i in I ex j being object st P[i,j]
  proof
    let i be object;
    assume i in I;
    then reconsider i1=i as Element of I;
    P[i1,canonical_embedding(f,i1)];
    hence thesis;
  end;
  consider B being ManySortedSet of I such that
A3: for i being object st i in I holds P[i,B.i] from PBOOLE:sch 3(A2);
  now
    let x be object;
    assume x in dom B;
    then reconsider y=x as Element of I;
    B.y = canonical_embedding(f,y) by A3;
    hence B.x is Function;
  end;
  then reconsider B as Function-yielding ManySortedSet of I by FUNCOP_1:def 6;
  take B;
  let i be Element of I;
A4: B.i = canonical_embedding(f,i) by A3;
  thus B.i is Function of A.i,A.(s.i) & for m being Function of A.i,A.(s.i) st
  m=B.i holds m is isomorphic
  proof
    thus B.i is Function of A.i,A.(s.i) by A4;
    let m be Function of A.i,A.(s.i);
    assume
A5: m=B.i;
    consider L being Segre-like non trivial-yielding ManySortedSubset of
    Carrier A such that
A6: indx(L)=i & product L is Segre-Coset of A by Th8;
    B.i=canonical_embedding(f,L) by A1,A4,A6,Def5;
    hence thesis by A1,A5,A6,Def4;
  end;
  let p be Point of Segre_Product A;
  let a be ManySortedSet of I such that
A7: a=p;
  consider b1 being Segre-like non trivial-yielding ManySortedSubset of
  Carrier A such that
A8: indx(b1)=i & product b1 is Segre-Coset of A and
A9: a in product b1 by A7,Th9;
  let b be ManySortedSet of I such that
A10: b=f.p;
  let m be Function of A.i,A.(s.i);
  assume m=B.i;
  then m=canonical_embedding(f,b1) by A1,A4,A8,Def5;
  hence thesis by A1,A7,A10,A8,A9,Def4;
end;
