reserve X for TopSpace;
reserve C for Subset of X;
reserve A, B for Subset of X;
reserve X for non empty TopSpace;

theorem Th28:
  X is extremally_disconnected iff for A, B being Subset of X st A
  is open & B is open holds A misses B implies Cl A misses Cl B
proof
  thus X is extremally_disconnected implies for A, B being Subset of X st A is
  open & B is open holds A misses B implies Cl A misses Cl B
  proof
    assume
A1: X is extremally_disconnected;
    let A, B be Subset of X;
    assume that
A2: A is open and
A3: B is open;
    assume A misses B;
    then
A4: A misses Cl B by A2,TSEP_1:36;
    Cl B is open by A1,A3;
    hence thesis by A4,TSEP_1:36;
  end;
  assume
A5: for A, B being Subset of X st A is open & B is open holds A misses B
  implies Cl A misses Cl B;
  now
    let A be Subset of X;
    A c= Cl A by PRE_TOPC:18;
    then
A6: A misses (Cl A)` by SUBSET_1:24;
    assume A is open;
    then (Cl A) misses Cl (Cl A)` by A5,A6;
    then Cl A c= (Cl (Cl A)`)` by SUBSET_1:23;
    then
A7: Cl A c= Int Cl A by TOPS_1:def 1;
    Int Cl A c= Cl A by TOPS_1:16;
    hence Cl A is open by A7,XBOOLE_0:def 10;
  end;
  hence thesis;
end;
