reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem Th28:
  for F, G being set st F <> {} & G <> {} holds union F \/ union G
  = union UNION (F,G)
proof
  let F, G be set;
  assume that
A1: F <> {} and
A2: G <> {};
  thus union F \/ union G c= union UNION (F,G)
  proof
    let x be object;
    assume
A3: x in union F \/ union G;
    per cases by A3,XBOOLE_0:def 3;
    suppose
A4:   x in union F;
      consider W being object such that
A5:   W in G by A2,XBOOLE_0:def 1;
      consider Y being set such that
A6:   x in Y and
A7:   Y in F by A4,TARSKI:def 4;
      reconsider Y,W as set by TARSKI:1;
      set YW = Y \/ W;
      Y c= YW & YW in UNION (F,G) by A7,A5,SETFAM_1:def 4,XBOOLE_1:7;
      hence thesis by A6,TARSKI:def 4;
    end;
    suppose
A8:   x in union G;
      consider W being object such that
A9:   W in F by A1,XBOOLE_0:def 1;
      consider Y being set such that
A10:  x in Y and
A11:  Y in G by A8,TARSKI:def 4;
      reconsider Y,W as set by TARSKI:1;
      set YW = W \/ Y;
      Y c= YW & YW in UNION (F,G) by A11,A9,SETFAM_1:def 4,XBOOLE_1:7;
      hence thesis by A10,TARSKI:def 4;
    end;
  end;
  thus thesis by Th27;
end;
