reserve R for non empty RelStr,
  N for net of R,
  i for Element of N;

theorem Th28:
  for S being reflexive antisymmetric non empty RelStr, e being Element of S
  holds e = lim_inf Net-Str e
proof
  let S be reflexive antisymmetric non empty RelStr, e be Element of S;
  set N = Net-Str e, X = the set of all "/\"({N.i where i is Element of N:
  i >= j},S) where j is Element of N;
  reconsider e9 = e as Element of S;
A1: X c= {e9}
  proof
    let u be object;
    assume u in X;
    then consider j being Element of N such that
A2: u = "/\"({N.i where i is Element of N: i >= j},S);
    set Y = {N.i where i is Element of N: i >= j};
A3: Y c= {e9}
    proof
      let v be object;
      assume v in Y;
      then consider i being Element of N such that
A4:   v = N.i and i >= j;
      reconsider i9 = i as Element of N;
      N.i9 = e by Th26;
      hence thesis by A4,TARSKI:def 1;
    end;
    reconsider j9 = j as Element of N;
    j9 <= j9;
    then N.j in Y;
    then Y = {e9} by A3,ZFMISC_1:33;
    then u = e9 by A2,YELLOW_0:39;
    hence thesis by TARSKI:def 1;
  end;
  set j = the Element of N;
  "/\"({N.i where i is Element of N: i >= j},S) in X;
  then X = {e9} by A1,ZFMISC_1:33;
  hence thesis by YELLOW_0:39;
end;
