
theorem Th28: :: 1.6. COROLLARY, p. 181
  for S,T being complete LATTICE, g being infs-preserving Function of S,T
  st g is one-to-one for X being Scott TopAugmentation of T
  for Y being Scott TopAugmentation of S
  for d being Function of X,Y st d = LowerAdj g holds
  g is directed-sups-preserving iff d is open
proof
  let S,T be complete LATTICE, g be infs-preserving Function of S,T such that
A1: g is one-to-one;
  let X be Scott TopAugmentation of T;
  let Y be Scott TopAugmentation of S;
  [g, LowerAdj g] is Galois by Def1;
  then LowerAdj g is onto by A1,WAYBEL_1:27;
  then
A2: rng LowerAdj g = the carrier of S by FUNCT_2:def 3;
A3: the RelStr of Y = the RelStr of S by YELLOW_9:def 4;
A4: the RelStr of X = the RelStr of T by YELLOW_9:def 4;
A5: [#]Y = the carrier of Y;
  let d be Function of X,Y such that
A6: d = LowerAdj g;
A7: Y|rng d = the TopStruct of Y by A2,A3,A5,A6,TSEP_1:93;
  thus g is directed-sups-preserving implies d is open
  proof
    assume g is directed-sups-preserving;
    then for V being open Subset of X holds
    uparrow ((LowerAdj g).:V) is open Subset of Y by Th21;
    then
A8: d is relatively_open by A6,Th26;
    let V be Subset of X;
    assume V is open;
    then d.:V is open Subset of Y|rng d by A8;
    hence d.:V in the topology of Y by A7,PRE_TOPC:def 2;
  end;
  assume
A9: for V being Subset of X st V is open holds d.:V is open;
  now
    let X9 be Scott TopAugmentation of T;
    let Y9 be Scott TopAugmentation of S;
    let V9 be open Subset of X9;
A10: the RelStr of X9 = the RelStr of T by YELLOW_9:def 4;
A11: the RelStr of Y9 = the RelStr of S by YELLOW_9:def 4;
    reconsider V = V9 as Subset of X by A4,A10;
    reconsider V as open Subset of X by A4,A10,YELLOW_9:50;
    reconsider d9 = d as Function of X9,Y9 by A3,A4,A10,A11;
    d.:V is open by A9;
    then
A12: d9.:V9 is open Subset of Y9 by A3,A11,YELLOW_9:50;
    then d9.:V9 is upper by WAYBEL11:def 4;
    then
A13: uparrow (d9.:V9) c= d9.:V9 by WAYBEL_0:24;
    d9.:V9 c= uparrow (d9.:V9) by WAYBEL_0:16;
    then uparrow (d9.:V9) = d9.:V9 by A13;
    hence uparrow ((LowerAdj g).:V9) is open Subset of Y9
    by A6,A11,A12,WAYBEL_0:13;
  end;
  hence thesis by Th21;
end;
