reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  for G being Subset of PARTITIONS(Y), A,B,C,D,E being a_partition of Y,
z,u being Element of Y, h being Function st G is independent & G={A,B,C,D,E} &
  A<>B & A<>C & A<>D & A<>E & B<>C & B<>D & B<>E & C<>D & C<>E & D<>E holds
  EqClass(u,B '/\' C '/\' D '/\' E) meets EqClass(z,A)
proof
  let G be Subset of PARTITIONS(Y);
  let A,B,C,D,E be a_partition of Y;
  let z,u be Element of Y;
  let h be Function;
  assume that
A1: G is independent and
A2: G={A,B,C,D,E} and
A3: A<>B & A<>C & A<>D & A<>E & B<>C & B<>D & B<>E & C<>D & C<>E & D<>E;
  set h = (B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (D .--> EqClass(u,
  D)) +* (E .--> EqClass(u,E)) +* (A .--> EqClass(z,A));
A4: h.B = EqClass(u,B) by A3,Th26;
A5: h.D = EqClass(u,D) by A3,Th26;
A6: h.C = EqClass(u,C) by A3,Th26;
A7: h.E = EqClass(u,E) by A3,Th26;
A8: rng h = {h.A,h.B,h.C,h.D,h.E} by Th28;
  rng h c= bool Y
  proof
    let t be object;
    assume
A9: t in rng h;
    now
      per cases by A8,A9,ENUMSET1:def 3;
      case
        t=h.A;
        then t=EqClass(z,A) by A3,Th26;
        hence thesis;
      end;
      case
        t=h.B;
        hence thesis by A4;
      end;
      case
        t=h.C;
        hence thesis by A6;
      end;
      case
        t=h.D;
        hence thesis by A5;
      end;
      case
        t=h.E;
        hence thesis by A7;
      end;
    end;
    hence thesis;
  end;
  then reconsider FF=rng h as Subset-Family of Y;
A10: dom h = G by A2,Th27;
  for d being set st d in G holds h.d in d
  proof
    let d be set;
    assume
A11: d in G;
    now
      per cases by A2,A11,ENUMSET1:def 3;
      case
A12:    d=A;
        h.A=EqClass(z,A) by A3,Th26;
        hence thesis by A12;
      end;
      case
A13:    d=B;
        h.B=EqClass(u,B) by A3,Th26;
        hence thesis by A13;
      end;
      case
A14:    d=C;
        h.C=EqClass(u,C) by A3,Th26;
        hence thesis by A14;
      end;
      case
A15:    d=D;
        h.D=EqClass(u,D) by A3,Th26;
        hence thesis by A15;
      end;
      case
A16:    d=E;
        h.E=EqClass(u,E) by A3,Th26;
        hence thesis by A16;
      end;
    end;
    hence thesis;
  end;
  then (Intersect FF)<>{} by A1,A10,BVFUNC_2:def 5;
  then consider m being object such that
A17: m in Intersect FF by XBOOLE_0:def 1;
  A in dom h by A2,A10,ENUMSET1:def 3;
  then
A18: h.A in rng h by FUNCT_1:def 3;
  then
A19: m in meet FF by A17,SETFAM_1:def 9;
  then
A20: m in h.A by A18,SETFAM_1:def 1;
  D in dom h by A2,A10,ENUMSET1:def 3;
  then h.D in rng h by FUNCT_1:def 3;
  then
A21: m in h.D by A19,SETFAM_1:def 1;
  C in dom h by A2,A10,ENUMSET1:def 3;
  then h.C in rng h by FUNCT_1:def 3;
  then
A22: m in h.C by A19,SETFAM_1:def 1;
  B in dom h by A2,A10,ENUMSET1:def 3;
  then h.B in rng h by FUNCT_1:def 3;
  then m in h.B by A19,SETFAM_1:def 1;
  then m in EqClass(u,B) /\ EqClass(u,C) by A4,A6,A22,XBOOLE_0:def 4;
  then
A23: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) by A5,A21,XBOOLE_0:def 4
;
  E in dom h by A2,A10,ENUMSET1:def 3;
  then h.E in rng h by FUNCT_1:def 3;
  then m in h.E by A19,SETFAM_1:def 1;
  then
A24: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) by A7
,A23,XBOOLE_0:def 4;
  set GG=EqClass(u,B '/\' C '/\' D '/\' E);
  GG = EqClass(u,B '/\' C '/\' D) /\ EqClass(u,E) by Th1;
  then
A25: GG = EqClass(u,B '/\' C) /\ EqClass(u,D) /\ EqClass(u,E) by Th1;
  h.A = EqClass(z,A) by A3,Th26;
  then m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) /\
  EqClass(z,A) by A20,A24,XBOOLE_0:def 4;
  then EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) meets
  EqClass(z,A) by XBOOLE_0:4;
  hence thesis by A25,Th1;
end;
