
theorem Th10:
  for X being non empty LinearTopSpace,
      x being Point of X,
      O being local_base of X,
      B being Subset-Family of X st
  B = {x+U where U is Subset of X:U in O & U is a_neighborhood of 0.X} holds
  B is basis of BOOL2F NeighborhoodSystem x
  proof
    let X be non empty LinearTopSpace,
    x be Point of X, O be local_base of X,B be Subset-Family of X;
    assume
A1: B={x+U where U is Subset of X:U in O & U is a_neighborhood of 0.X};
    set F=BOOL2F NeighborhoodSystem x;
A2: F c= <.B.]
    proof
      now
        let t be object;
        assume t in F;
        then t in NeighborhoodSystem x by CARDFIL2:def 20;
        then t in the set of all A where
        A is a_neighborhood of x by YELLOW19:def 1;
        then consider A be a_neighborhood of x such that
A3:     t=A;
        x in Int(A) by CONNSP_2:def 1;
        then -x+Int(A) is a_neighborhood of 0.X by RLTOPSP1:9,CONNSP_2:3;
        then consider V being a_neighborhood of 0.X such that
A4:     V in O and
A5:     V c= -x+Int(A) by YELLOW13:def 2;
        set U = x+V;
A6:     U in B by A1,A4;
        U c= x+(-x+Int(A)) by A5,RLTOPSP1:8;
        then U c= x+(-x)+Int(A) by RLTOPSP1:6;
        then U c= 0.X+Int(A) by RLVECT_1:5;
        then Int(A) c= A & U c= Int(A) by RLTOPSP1:5,TOPS_1:16;
        then U c= A;
        hence t in <.B.] by A3,A6,CARDFIL2:def 8;
      end;
      hence thesis;
    end;
    <.B.] c= F
    proof
      now
        let t be object;
        assume
A7:     t in <.B.];
        then reconsider t1=t as Subset of X;
        consider b be Element of B such that
A8:     b c= t1 by A7,CARDFIL2:def 8;
        set v0 = the Element of O;
        B is non empty by A1,Lm2;
        then b in B;
        then consider U1 be Subset of X such that
A9:     b=x+U1 and
        U1 in O and
A10:    U1 is a_neighborhood of 0.X by A1;
        reconsider t2=b as Element of B;
A11:    x+0.X in x+Int(U1) by Lm1, A10,CONNSP_2:def 1;
        x+Int(U1) c= Int(x+U1) by RLTOPSP1:37;
        then t2 is a_neighborhood of x by A9,A11,CONNSP_2:def 1;
        then t2 in the set of all A where
        A is a_neighborhood of x;
        then t2 in NeighborhoodSystem x by YELLOW19:def 1;
        then t2 in F by CARDFIL2:def 20;
        hence t in F by A8,CARD_FIL:def 1;
      end;
      hence thesis;
    end;
    hence thesis by CARDFIL2:22,A2,XBOOLE_0:def 10;
  end;
